From d7e1784f32dd0ff7b6e23c67cc511c27b67d8cd1 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Simon=20=C5=BDlender?= <pub.git@zlender.si>
Date: Thu, 7 Dec 2023 22:27:37 +0100
Subject: [PATCH] redocly-cli: init at 1.5.0

(cherry picked from commit 92de1d2e263e0b0984c8497420fb4243784a9694)
---
 pkgs/by-name/re/redocly-cli/package.nix | 48 +++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/re/redocly-cli/package.nix

diff --git a/pkgs/by-name/re/redocly-cli/package.nix b/pkgs/by-name/re/redocly-cli/package.nix
new file mode 100644
index 0000000000000..18d853c58da9a
--- /dev/null
+++ b/pkgs/by-name/re/redocly-cli/package.nix
@@ -0,0 +1,48 @@
+{ lib
+, buildNpmPackage
+, fetchFromGitHub
+, makeWrapper
+}:
+
+buildNpmPackage rec {
+  pname = "redocly-cli";
+  version = "1.5.0";
+
+  src = fetchFromGitHub {
+    owner = "Redocly";
+    repo = "redocly-cli";
+    rev = "@redocly/cli@${version}";
+    hash = "sha256-Wi3IxPeNqD1s1Q0Pi9cCus6jCQM0noBTHIAp9HUSpZk=";
+  };
+
+  npmDepsHash = "sha256-BcjQ9z2i1YBt6lBqgkRcv29P/WZeuGjVSeVmekaFugM=";
+
+  npmBuildScript = "prepare";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  postInstall = ''
+    rm $out/lib/node_modules/@redocly/cli/node_modules/@redocly/{cli,openapi-core}
+    cp -R packages/cli $out/lib/node_modules/@redocly/cli/node_modules/@redocly/cli
+    cp -R packages/core $out/lib/node_modules/@redocly/cli/node_modules/@redocly/openapi-core
+
+    mkdir $out/bin
+    makeWrapper $out/lib/node_modules/@redocly/cli/node_modules/@redocly/cli/bin/cli.js $out/bin/redocly-cli --set REDOCLY_TELEMETRY off
+  '';
+
+  installCheckPhase = ''
+    runHook preInstallCheck
+    $out/bin/redocly-cli --version
+    runHook postInstallCheck
+  '';
+
+  doInstallCheck = true;
+
+  meta = {
+    description = "Redocly CLI makes OpenAPI easy. Lint/validate to any standard, generate beautiful docs, and more.";
+    homepage = "https://github.com/Redocly/redocly-cli";
+    license = lib.licenses.mit;
+    mainProgram = "redocly-cli";
+    maintainers = with lib.maintainers; [ szlend ];
+  };
+}