prevent throwing null pointer exception

[dpsutton]

Got an issue popping up in CIDER with compliment throwing a null pointer exception by just typing ::/ and the autocomplete functionality throwing:

clojure-emacs/cider#1972

I've created the following test that "tests" it to demonstrate the error programatically and I'm starting to look into the codebase but i'm not too familiar with it.

(fact "keyword reading does not throw an error"
        (do (src/candidates "::/" *ns* nil)
            => (strip-tags (just #{""}))))

[dpsutton]

(defn aliased-candidates
  "Returns a list of alias-qualified double-colon keywords (like ::str/foo),
  where alias has to be registered in the given namespace."
  [prefix ns]
  (let [[_ alias prefix] (re-matches #"::([^/]+)/(.*)" prefix)
        alias-ns-name (str (resolve-namespace (symbol alias) ns))]
    (for [[kw _] (keywords-table)
          :when (= (namespace kw) alias-ns-name)
          :when (.startsWith (name kw) prefix)]
      (tagged-candidate (str "::" alias "/" (name kw))))))

Amazingly, it's this function. It has a double colon and a slash but this regex can still fail.

I've tentatively changed it to the following:

(defn aliased-candidates
  "Returns a list of alias-qualified double-colon keywords (like ::str/foo),
  where alias has to be registered in the given namespace."
  [prefix ns]
  (let [[_ alias prefix] (re-matches #"::([^/]+)/(.*)" prefix)]
    (if (and alias prefix)
      (let [alias-ns-name (str (resolve-namespace (symbol alias) ns))]
        (for [[kw _] (keywords-table)
              :when (= (namespace kw) alias-ns-name)
              :when (.startsWith (name kw) prefix)]
          (tagged-candidate (str "::" alias "/" (name kw)))))
      (tagged-candidate ""))))

except i'm not sure how at this point to return no completion candidates. But it's guarding against this regex failing or making the guards going into this (the cond over double-colon? and has-slash? a bit smarter, but that makes those predicates not really match what they say).

[alexander-yakushev]

Thanks for reporting! Your fix looks correct. You can just return nil or an empty list for no candidates. So it might look like:

(when-let [[_ alias prefix] (re-matches #"::([^/]+)/(.*)" prefix)]
  (let [alias-ns-name (str (resolve-namespace (symbol alias) ns))]
    (for [[kw _] (keywords-table)
          :when (= (namespace kw) alias-ns-name)
          :when (.startsWith (name kw) prefix)]
      (tagged-candidate (str "::" alias "/" (name kw))))))

Do you wish to create a pull request with this fix?

[dpsutton]

I'm at work and won't be able to do it until evening. If it's no big deal for you go ahead, otherwise i'll do it tonight.

About the when-let form, that was my first try and it seemed like the when-let form didn't allow destructuring but maybe i was a little hasty and missed an extra set of [].

[alexander-yakushev]

No hurry, create it whenever you have time. It's just that since you've discovered the bug and fixed it, it makes more sense that the commit comes from you :).

when-let allows destructuring, but the when part checks only the top-level (undestructured) value. Just something to keep in mind.

[alexander-yakushev]

Fixed by #47.