Add crystal tool dependencies

src/compiler/crystal/command.cr

@@ -43,6 +43,7 @@ class Crystal::Command
         expand                   show macro expansion for given location
         format                   format project, directories and/or files
         hierarchy                show type hierarchy
+        dependencies             show file dependency tree
         implementations          show implementations for given call in location
         types                    show type of main variables
         --help, -h               show this help
@@ -181,6 +182,9 @@ class Crystal::Command
     when "hierarchy".starts_with?(tool)
       options.shift
       hierarchy
+    when "dependencies".starts_with?(tool)
+      options.shift
+      dependencies
     when "implementations".starts_with?(tool)
       options.shift
       implementations

src/compiler/crystal/compiler.cr

@@ -144,6 +144,8 @@ module Crystal
     # Whether to link statically
     property? static = false
 
+    property dependency_printer : DependencyPrinter? = nil
+
     # Program that was created for the last compilation.
     property! program : Program
 

src/compiler/crystal/program.cr

@@ -454,6 +454,22 @@ module Crystal
       recorded_requires << RecordedRequire.new(filename, relative_to)
     end
 
+    def run_requires(node : Require, filenames) : Nil
+      dependency_printer = compiler.try(&.dependency_printer)
+
+      filenames.each do |filename|
+        unseen_file = requires.add?(filename)
+
+        dependency_printer.try(&.enter_file(filename, unseen_file))
+
+        if unseen_file
+          yield filename
+        end
+
+        dependency_printer.try(&.leave_file)
+      end
+    end
+
     # Finds *filename* in the configured CRYSTAL_PATH for this program,
     # relative to *relative_to*.
     def find_in_path(filename, relative_to = nil) : Array(String)?

src/compiler/crystal/semantic/semantic_visitor.cr

@@ -69,25 +69,11 @@ abstract class Crystal::SemanticVisitor < Crystal::Visitor
 
     if filenames
       nodes = Array(ASTNode).new(filenames.size)
-      filenames.each do |filename|
-        if @program.requires.add?(filename)
-          parser = @program.new_parser(File.read(filename))
-          parser.filename = filename
-          parser.wants_doc = @program.wants_doc?
-          begin
-            parsed_nodes = parser.parse
-            parsed_nodes = @program.normalize(parsed_nodes, inside_exp: inside_exp?)
-            # We must type the node immediately, in case a file requires another
-            # *before* one of the files in `filenames`
-            parsed_nodes.accept self
-          rescue ex : CodeError
-            node.raise "while requiring \"#{node.string}\"", ex
-          rescue ex
-            raise Error.new "while requiring \"#{node.string}\"", ex
-          end
-          nodes << FileNode.new(parsed_nodes, filename)
-        end
+
+      @program.run_requires(node, filenames) do |filename|
+        nodes << require_file(node, filename)
       end
+
       expanded = Expressions.from(nodes)
     else
       expanded = Nop.new
@@ -98,6 +84,25 @@ abstract class Crystal::SemanticVisitor < Crystal::Visitor
     false
   end
 
+  private def require_file(node : Require, filename : String)
+    parser = @program.new_parser(File.read(filename))
+    parser.filename = filename
+    parser.wants_doc = @program.wants_doc?
+    begin
+      parsed_nodes = parser.parse
+      parsed_nodes = @program.normalize(parsed_nodes, inside_exp: inside_exp?)
+      # We must type the node immediately, in case a file requires another
+      # *before* one of the files in `filenames`
+      parsed_nodes.accept self
+    rescue ex : CodeError
+      node.raise "while requiring \"#{node.string}\"", ex
+    rescue ex
+      raise Error.new "while requiring \"#{node.string}\"", ex
+    end
+
+    FileNode.new(parsed_nodes, filename)
+  end
+
   def visit(node : ClassDef)
     check_outside_exp node, "declare class"
     pushing_type(node.resolved_type) do

src/compiler/crystal/tools/dependencies.cr

@@ -0,0 +1,60 @@
+require "set"
+require "colorize"
+require "../syntax/ast"
+
+class Crystal::Command
+  private def dependencies
+    dependency_printer = nil
+    option_parser = parse_with_crystal_opts do |opts|
+      opts.on("-f FORMAT", "--format FORMAT", "Format the output. Available options: flat, tree (default)") do |format|
+        case format
+        when "flat"
+          dependency_printer = DependencyPrinter.new(STDOUT, flat: true)
+        when "tree"
+          dependency_printer = DependencyPrinter.new(STDOUT, flat: false)
+        else
+          abort "Invalid format: #{format}"
+        end
+      end
+    end
+
+    config = create_compiler "tool dependencies", no_codegen: true
+    config.compiler.no_codegen = true
+
+    config.compiler.dependency_printer = dependency_printer || DependencyPrinter.new(STDOUT)
+    config.compile
+  end
+end
+
+module Crystal
+  class DependencyPrinter
+    @indent = 0
+
+    def initialize(@io : IO, @flat : Bool = false)
+    end
+
+    def enter_file(filename : String, unseen : Bool)
+      unless unseen
+        @indent += 1
+        return
+      end
+      print_indent
+      print_file(filename)
+
+      @indent += 1
+    end
+
+    def leave_file
+      @indent -= 1
+    end
+
+    private def print_indent
+      return if @flat
+      @io.print "  " * @indent.clamp(0..)
+    end
+
+    private def print_file(filename)
+      @io.puts ::Path[filename].relative_to?(Dir.current) || filename
+    end
+  end
+end