Add examples of alternative HTTP clients in the documentation

[ream88]

Not sure if we should add it directly to the code base, maybe mentioning in the README.md is enough. 😊

This is an alternative implementation of Sentry.HTTPClient based on finch, instead of hackney. req, finch and mint are kinda the new kids on the block, and I tend to use them more often nowadays and having multiple HTTP libraries in one code base is somewhat a code smell imo:

# config/config.exs
config :sentry, client: Sentry.FinchClient

# lib/sentry/finch_client.ex
defmodule Sentry.FinchClient do
  @behaviour Sentry.HTTPClient

  def child_spec() do
    Supervisor.child_spec({Finch, name: __MODULE__}, id: __MODULE__)
  end

  def post(url, headers, body) do
    request = Finch.build(:post, url, headers, body)

    case Finch.request(request, __MODULE__) do
      {:ok, %Finch.Response{status: status, headers: headers, body: body}} ->
        {:ok, status, headers, body}

      {:error, error} ->
        {:error, error}
    end
  end
end

EDIT: Updated the example, thx for the help @arcanemachine!

[arcanemachine]

For anyone else who is new to Sentry, you can configure Sentry to use this client by adding the following to your config/config.exs:

config :sentry,
  client: Sentry.FinchClient

Thanks @ream88!

EDIT: I'm still pretty new to Elixir/Phoenix, so I'm not sure if adding it to the config.exs (which I understand is a compile-time configuration) is the best. However, I believe that this way should work fine since the configuration does not change after compiling the project (e.g. in a Mix release). Happy to hear suggestions on the matter if I am wrong.

[arcanemachine]

@ream88 Everything seems to working fine, but I'm getting a Dialyzer error in the child_spec() function with your Finch client implementation:

The inferred return type of child_spec/0 
         ({'Elixir.Finch', [{'name', 'Elixir.Sentry.FinchClient'}, ...]}) has nothing in common with 
          {_,
           {atom(), atom(), 'undefined' | [any()]},
           'permanent' | 'temporary' | 'transient',
           'brutal_kill' | 'infinity' | non_neg_integer(),
           'supervisor' | 'worker',
           'dynamic' | [atom()]} |
          #{'id' := _,
            'start' := {atom(), atom(), 'undefined' | [any()]},
            'modules' => 'dynamic' | [atom()],
            'restart' => 'permanent' | 'temporary' | 'transient',
            'shutdown' => 'brutal_kill' | 'infinity' | non_neg_integer(),
            'significant' => boolean(),
            'type' => 'supervisor' | 'worker'}, which is the expected return type for the callback of the 'Elixir.Sentry.HTTPClient' behaviour (ElixirLS Dialyzer)

I am about to go on a deep dive of some interesting Elixir features, but right now I'm not familiar with supervisors, implementing behaviors, child_spec(), etc... Do you know if your implementation of the child_spec() is correct, or do you think it something that needs some refinement in the future?

Thanks

[ream88]

Does this fix the problem?

def child_spec() do
  Supervisor.child_spec({Finch, name: __MODULE__}, id: __MODULE__)
end

[arcanemachine]

Well, it made the Dialyzer error go away, and I hope that prevents any issues that could arise (I'm still learning). Thanks a lot!

[ruslandoga]

👋 @ream88 @arcanemachine

Note that there are some issues with that kind of Finch client implementations right now: #514