How to use custom SPI pins on ESP32-S3?

[S5NC]

I tried many things but none work. Documentation:

SPIClass spi(VSPI);
SPISettings spiSettings(2000000, MSBFIRST, SPI_MODE0);
SX1262 radio = new Module(cs, irq, rst, gpio, spi, spiSettings);

void setup() {
  spi.begin();
  (...)
  radio.begin();
}

I want to use the normal SPI, and keep normal SPI settings. I can leave the spiSettings field empty for it to default to RADIOLIB_DEFAULT_SPI_SETTINGS. I don't see where to put my own pins.

My code is

#include <RadioLib.h>
#include <SPI.h>

#define LORA_CS 14
#define LORA_SCK 21
#define LORA_MOSI 38
#define LORA_MISO 39
#define LORA_RESET 40
#define LORA_BUSY 41
#define LORA_DIO1 42

SPI.setPins???(LORA_SCK, LORA_MISO, LORA_MOSI, LORA_SS); // I don't know what to put here

SX1262 radio = new Module(LORA_CS, LORA_DIO1, LORA_RESET, LORA_BUSY);

void setup() {
  Serial.begin(115200);

  // initialize SX1262 with default settings
  Serial.print(F("[SX1262] Initializing ... "));
  int state = radio.begin();
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true);
  }
}

[HeadBoffin]

I don't want to use VSPI

Bad news, that's the Arduino default, but you could just blank the V out of your mind and you get SPI.

These should help:

https://espressif-docs.readthedocs-hosted.com/projects/arduino-esp32/en/latest/api/spi.html
and
https://randomnerdtutorials.com/esp32-spi-communication-arduino/

[S5NC]

#include <RadioLib.h>
#include <SPI.h>

#define LORA_CS 14
#define LORA_SCK 21
#define LORA_MOSI 38
#define LORA_MISO 39
#define LORA_RESET 40
#define LORA_BUSY 41
#define LORA_DIO1 42

#if CONFIG_IDF_TARGET_ESP32S2 || CONFIG_IDF_TARGET_ESP32S3
#define VSPI FSPI
#endif

//SPI.setPins???(LORA_SCK, LORA_MISO, LORA_MOSI, LORA_SS);

// uninitalised pointers to SPI objects
SPIClass * vspi = NULL; // What does this do? Is it needed?

SX1262 radio = new Module(LORA_CS, LORA_DIO1, LORA_RESET, LORA_BUSY, vspi);

void setup() {
  Serial.begin(115200);

  vspi = new SPIClass(VSPI);
  vspi->begin(LORA_SCK, LORA_MISO, LORA_MOSI, LORA_CS);

  // initialize SX1262 with default settings
  Serial.print(F("[SX1262] Initializing ... "));
  int state = radio.begin();
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true);
  }
}

error: no matching function for call to 'Module(int, int, int, int, SPIClass*&)'
error: invalid conversion from 'SPIClass*' to 'uint32_t' {aka 'unsigned int'} [-fpermissive]
error: invalid user-defined conversion from 'SPIClass*' to 'SPIClass&' [-fpermissive]
error: invalid conversion from 'SPIClass*' to 'uint8_t' {aka 'unsigned char'} [-fpermissive]
error: invalid conversion from 'SPIClass*' to 'uint8_t' {aka 'unsigned char'} [-fpermissive]
error: conversion to non-const reference type 'class SPIClass&' from rvalue of type 'SPIClass' [-fpermissive]

[S5NC]

#include <RadioLib.h>
#include <SPI.h>

#define LORA_CS 14
#define LORA_SCK 21
#define LORA_MOSI 38
#define LORA_MISO 39
#define LORA_RESET 40
#define LORA_BUSY 41
#define LORA_DIO1 42

SPIClass spi(SPI);
SX1262 radio = new Module(LORA_CS, LORA_DIO1, LORA_RESET, LORA_BUSY, spi);

void setup() {
  Serial.begin(115200);

  spi.begin();

  // initialize SX1262 with default settings
  Serial.print(F("[SX1262] Initializing ... "));
  int state = radio.begin();
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true);
  }
}

This compiles, but there is nowhere to specify the SPI pins.

[S5NC]

With SPIClass loraSPI(SPI); or SPIClass loraSPI(HSPI); it always gives -707 error code, with SPIClass loraSPI(VSPI); it doesn't compile because on ESP32-S3 VSPI is not defined, but with SPIClass loraSPI(FSPI); it works 5% of the time (95% -707, 5% success)

[StevenCellist]

The type of SPI does not (/hardly) matter! It is all down to your wiring and pin numbering. What board are you using?

[S5NC]

It's a custom design, but it works perfectly on Meshtastic, no SPI issues whatsoever. The pins are defined the same.

[StevenCellist]

This one's for Mr @jgromes, I am merely an off-the-shelf dude. Maybe something with TCXO or so..

[S5NC]

Ah yes I forgot about that! I will pass it into the begin().

[jgromes]

@S5NC I suggest slowing down a bit. How did you arrive at the conclusion that the SPI is broken? What is the error code? What is the debug output? If the only error you have seen so far is -707 then that can very well mean the SPI is working and you just have incorrect crystal (as the Troubleshooting guide shows.

Start by observing the symptoms before taking wild guesses ...

[jgromes]

I think a solution would be to only use the sets of calibration values provided in the SX1261/2 datasheet.

That's the way this was handled before I started messing about with LR11xx driver, which included the calculation that's implemented now. I will revert that change in SX126x - despite testing with couple different SX126x devices, it looks like there are some edge cases in which this calucation doesn't work. I will however keep this calibration available to users, it just won't be used by default.

[jgromes]

Pushed in the latest commit, now pre-defined bands will be used preferentially and the calculated coefficients will only be used if your frequency is outside those bands.

[S5NC]

I would guess that the frequency calibration must a different start and end value, like D7 and D8, not D8 and D8. Maybe some loose maths is done by the SX1262 to see if the frequency specified (869.525) is within the range, by only doing the sum with the first bytes of a float, but comparing the full memory address. The only reason I could think of which would give a result as observed (sometimes working, sometimes not) would be a random seed generated through environmental noise, but I don't think the SX1262 has any need for a random number, or using memory which isn't flushed between cycles, as running the same thing twice should give the same result on two separate boots, unless timing affects it (moving buffer to memory etc. leading to different data in unused RAM). In this case, having two different starting bytes (D7 vs D8) always ensures that whatever 869.525 is, or that D8 - D7 is positive. Maybe if this wild guess is true, when D8 - D8 is performed, sometimes due to lingering memory in the slots P, Q, R, S of 0xD8_PQ_ - 0x86_RS_ sometimes give negative results and mean the instruction can't be executed (error 5) because the check it performs raises an error. If we set D9, D8 in that order, do we get the same exact error as we are seeing?

SX1261/2 do have random number generators (RandomNumberGen[0:3], 0x0819:C), so maybe it is a truly random problem.

[S5NC]

We could use GetDeviceErrors command of opcode 0x17 and check bit 4 of the returned value which is IMG_CALIB_ERR to see if the image calibration was the problem.

[S5NC]

When the image calibration fails, it always takes slightly longer than when it succeeds.
My testing shows:

(D9, DB) -> stable
(D8, DB) -> unstable
(D7, DB) -> stable

(D9, DA) -> unstable
(D8, DA) -> unstable
(D7, DA) -> unstable

[HeadBoffin]

Can you put your 8 layer PCB design up on to your Git repro just in case there is something up with the routing.

[S5NC]

Here is the working code which I am using to set custom SPI pins on the ESP32-S3 and SX1262:

#include <RadioLib.h>
#include <SPI.h>

#define SX1262_CS 14
#define SX1262_SCK 21
#define SX1262_MOSI 38
#define SX1262_MISO 39
#define SX1262_RESET 40
#define SX1262_BUSY 41
#define SX1262_DIO1 42

#define SX1262_DIO2_AS_RF_SWITCH 1
#define SX1262_TXEN RADIOLIB_NC
#define SX1262_RXEN 10

SX1262 radio = new Module(SX1262_CS, SX1262_DIO1, SX1262_RESET, SX1262_BUSY);

void checkState(int16_t state) {
  if (state != RADIOLIB_ERR_NONE) {
    Serial.print(F("[SX1262] configuration failed with code "));
    Serial.println(state);
    while (true) {}
  }
}

void setup() {

  Serial.begin(115200);

  SPI.begin(SX1262_SCK, SX1262_MISO, SX1262_MOSI, SX1262_CS);
  Serial.printf("SPI.begin(SCK=%d, MISO=%d, MOSI=%d, CS=%d)\n", SX1262_SCK, SX1262_MISO, SX1262_MOSI, SX1262_CS);
  SPI.setFrequency(4000000);

  Serial.println(F("[SX1262] Initialising ... "));

  checkState(radio.begin(868.0, 250.0, 11, 5, 0x2B, 8, 16, 1.8, false));
  checkState(radio.setFrequency(869.525, false)); // you can remove this line and just put 869.525 instead of 868.0 in the line above once a release with the calibration range has been released.
  checkState(radio.setCurrentLimit(140));
  checkState(radio.setCRC(true));
  checkState(radio.setDio2AsRfSwitch(SX1262_DIO2_AS_RF_SWITCH));
  radio.setRfSwitchPins(SX1262_RXEN, SX1262_TXEN); // void
  checkState(radio.setRxBoostedGainMode(true));

  Serial.println(F("[SX1262] All settings succesfully changed!"));

}

void loop() {}

[HeadBoffin]

Thank you for sharing the solution, much appreciated