build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

group = 'org.aperlambda'
version = '1.8.1'
description = 'A library written in Java 8 with common features.'

ext.moduleName = 'org.aperlambda.lambdacommon'

compileJava.options.encoding = 'UTF-8'

repositories {
    mavenCentral()
}

dependencies {
    api 'com.google.code.gson:gson:2.8.5'
    api 'com.google.guava:guava:27.1-jre'
    api 'org.jetbrains:annotations:17.0.0'
}

java {
    sourceCompatibility = JavaVersion.VERSION_1_8

    withJavadocJar()
    withSourcesJar()
}

javadoc {
    inputs.property("moduleName", moduleName)
    doFirst {
        options.addStringOption('XDignore.symbol.file', '-html5')
        options.addStringOption('-module-path', classpath.asPath)
    }
}

jar {
    from 'LICENSE'
    inputs.property("moduleName", moduleName)
    manifest {
        attributes('Automatic-Module-Name': moduleName)
    }
}

/*signing {
    sign configurations.archives
}*/

publishing {
    publications {
        lambdajcommon(MavenPublication) {
            from components.java
            artifactId = 'lambdajcommon'
        }
    }
    repositories {
        maven {
            url = "$buildDir/repo"
        }
    }
}