build.gradle

plugins {
    id "java"
    id "edu.wpi.first.GradleRIO" version "2024.3.2"
    id 'com.diffplug.spotless' version '6.25.0'
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

repositories {
    mavenCentral()
}

dependencies {
    implementation wpi.java.deps.wpilib()
    implementation wpi.java.vendor.java()

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.1'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
    ignoreFailures = true // Don't fail builds or deploys because of failing tests
}

defaultTasks 'clean'

spotless {
    enforceCheck = false // Don't fail builds because of incorrectly formatted code
    java {
        target fileTree('.') {
            include '**/*.java'
            exclude '**/build/**', '**/build-*/**', '**/bin/**', "src/generated/**"
        }
        toggleOffOn()
        removeUnusedImports()
        trimTrailingWhitespace()
        endWithNewline()
        indentWithSpaces()
        formatAnnotations()
    }
    groovyGradle {
        target fileTree('.') {
            include '**/*.gradle'
            exclude '**/build/**', '**/build-*/**', '**/bin/**'
        }
        greclipse()
        indentWithSpaces()
        trimTrailingWhitespace()
        endWithNewline()
    }
}