build.gradle

plugins {
	id 'java'
	id 'maven-publish'
	//id 'checkstyle'
	//id 'com.diffplug.gradle.spotless' version '4.5.1'
	id 'com.github.johnrengelman.shadow' version '4.0.4'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = '0.7.0'

def ENV = System.getenv()
version = version + (ENV.GITHUB_ACTIONS ? "" : "+local")

group = 'net.fabricmc'
archivesBaseName = 'tiny-remapper'

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.ow2.asm:asm:9.1'
	implementation 'org.ow2.asm:asm-commons:9.1'
	implementation 'org.ow2.asm:asm-tree:9.1'
	implementation 'org.ow2.asm:asm-util:9.1'

	testImplementation 'org.junit.jupiter:junit-jupiter:5.6.2'
}

task sourceJar(type:Jar) {
	classifier = "sources"
	from sourceSets.main.allSource
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"

	if (JavaVersion.current().isJava9Compatible()) {
		it.options.release = 8
	}
}

shadowJar {
	classifier = 'fat'
}

test {
	useJUnitPlatform()
	testLogging {
		showStandardStreams = true
		exceptionFormat = 'full'
		events = ['passed', 'failed', 'skipped']
	}
}

jar {
	manifest {
		attributes	'Implementation-Title': 'TinyRemapper',
					'Implementation-Version': version,
					'Main-Class': "net.fabricmc.tinyremapper.Main"
	}
}
/*
checkstyle {
	configFile = file("checkstyle.xml")
	toolVersion = '8.31'
}

spotless {
	ratchetFrom 'origin/master'

	java {
		licenseHeaderFile(rootProject.file('HEADER')).yearSeparator(', ')
	}
}
*/
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	repositories {
		if (ENV.MAVEN_URL) {
			maven {
				url ENV.MAVEN_URL
				credentials {
					username ENV.MAVEN_USERNAME
					password ENV.MAVEN_PASSWORD
				}
			}
		}
	}
}

// A task to ensure that the version being released has not already been released.
task checkVersion {
	doFirst {
		def xml = new URL("https://maven.fabricmc.net/net/fabricmc/tiny-remapper/maven-metadata.xml").text
		def metadata = new XmlSlurper().parseText(xml)
		def versions = metadata.versioning.versions.version*.text();
		if (versions.contains(version)) {
			throw new RuntimeException("${version} has already been released!")
		}
	}
}

publish.mustRunAfter checkVersion