Jenkinsfile.github

/*
 MIT License

 (C) Copyright 2023 Hewlett Packard Enterprise Development LP

 Permission is hereby granted, free of charge, to any person obtaining a
 copy of this software and associated documentation files (the "Software"),
 to deal in the Software without restriction, including without limitation
 the rights to use, copy, modify, merge, publish, distribute, sublicense,
 and/or sell copies of the Software, and to permit persons to whom the
 Software is furnished to do so, subject to the following conditions:

 The above copyright notice and this permission notice shall be included
 in all copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
 THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR
 OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
 ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
 OTHER DEALINGS IN THE SOFTWARE.
 */
@Library('csm-shared-library') _

def pythonImage = 'artifactory.algol60.net/csm-docker/stable/csm-docker-sle-python'

// Disable pr-merge builds; not used.
if (env.BRANCH_NAME ==~ ~"^PR-\\d+") {
    currentBuild.result = 'SUCCESS'
    echo "Pull-Request builds are skipped."
    return
} else if (env.BRANCH_NAME ==~ ~"^dependabot/github_actions") {
    currentBuild.result = 'SUCCESS'
    echo "Dependabot GitHub action builds are skipped."
    return
}

// Only consider X.Y.Z and X.Y.Z.postN tags as stable.
// Never consider X.Y.Z{[a|b|rc} or X.Y.Z.* tags (that are not post-releases) as stable.
// The ==~ operator performs an exact match.
def stableToken = ~/v?\d+\.\d+\.\d+(\.post\d+)?/
def isStable = (env.TAG_NAME != null & env.TAG_NAME ==~ stableToken) ? true : false
pipeline {
    agent {
        label "metal-gcp-builder"
    }

    options {
        buildDiscarder(logRotator(numToKeepStr: "10"))
        disableConcurrentBuilds()
        timeout(time: 20, unit: 'MINUTES')
        timestamps()
    }

    environment {
        NAME = getRepoName()
        VERSION = ''
        PRIMARY_NODE = "${env.NODE_NAME}"
    }

    stages {
        stage('Build & Publish') {

            matrix {

                axes {

                    axis {
                        name 'ARCH'
                        values 'x86_64', 'aarch64'
                    }

                    axis {
                        name 'DOCKER_TAG'
                        values '3.11-SLES15.6', '3.11-SLES15.5', '3.10', '3.9'
                    }

                }

                environment {
                    DOCKER_ARCH = sh(returnStdout: true, script: "[ ${ARCH} == 'x86_64' ] && echo -n 'amd64' || echo -n 'arm64'")
                    BUILD_DIR = "${env.WORKSPACE}/dist/rpmbuild/${ARCH}/${DOCKER_TAG}"
                    PYTHON_VERSION = sh(script: "echo \${DOCKER_TAG%%-*}", returnStdout: true).trim()
                }

                stages {
                    stage('Build: setup') {
                        steps {
                            lock('docker-image-pull') {
                                sh "docker pull --platform linux/${DOCKER_ARCH} ${pythonImage}:${DOCKER_TAG}"
                                sh "docker tag ${pythonImage}:${DOCKER_TAG} ${pythonImage}:${DOCKER_TAG}-${DOCKER_ARCH}"
                            }
                        }
                    }

                    stage('Prepare: RPMs') {
                        agent {
                            docker {
                                label "${PRIMARY_NODE}"
                                reuseNode true
                                args "-v /home/jenkins/.ssh:/home/jenkins/.ssh --platform linux/${DOCKER_ARCH}"
                                image "${pythonImage}:${DOCKER_TAG}-${DOCKER_ARCH}"
                            }
                        }

                        environment {
                            VERSION = sh(returnStdout: true, script: "python3 -m setuptools_scm | tr -s '-' '~' | sed 's/^v//'").trim()
                        }

                        steps {
                            script {
                                sh "make prepare"
                                // Inject distro-specific metadata (e.g. which distro and service pack).
                                dir("${env.BUILD_DIR}/SPECS/") {
                                    runLibraryScript("addRpmMetaData.sh", "${env.NAME}.spec")
                                }
                            }
                        }
                    }

                    stage('Build: RPMs') {
                        agent {
                            docker {
                                label "${PRIMARY_NODE}"
                                reuseNode true
                                args "-v /home/jenkins/.ssh:/home/jenkins/.ssh --platform linux/${DOCKER_ARCH}"
                                image "${pythonImage}:${DOCKER_TAG}-${DOCKER_ARCH}"
                            }
                        }

                        environment {
                            VERSION = sh(returnStdout: true, script: "python3 -m setuptools_scm | tr -s '-' '~' | sed 's/^v//'").trim()
                        }

                        steps {
                            script {
                                sh 'PATH=/home/jenkins/.local/bin:$PATH make rpm'
                            }
                        }
                    }

                    stage('Publish: RPMs') {
                        agent {
                            docker {
                                label "${PRIMARY_NODE}"
                                reuseNode true
                                args "-v /home/jenkins/.ssh:/home/jenkins/.ssh --platform linux/${DOCKER_ARCH}"
                                image "${pythonImage}:${DOCKER_TAG}-${DOCKER_ARCH}"
                            }
                        }

                        steps {
                            script {
                                def sleVersion = sh(returnStdout: true, script: 'awk -F= \'/VERSION_ID/{gsub(/["]/,""); print \$NF}\' /etc/os-release').trim()
                                def sles_version_parts = "${sleVersion}".tokenize('.')
                                def sles_major = "${sles_version_parts[0]}"
                                def sles_minor = "${sles_version_parts[1]}"
                                publishCsmRpms(
                                        artifactoryRepo: 'fawkes-rpms',
                                        arch: "${ARCH}",
                                        component: env.NAME,
                                        isStable: isStable,
                                        os: "sle-${sles_major}sp${sles_minor}",
                                        pattern: "dist/rpmbuild/${ARCH}/${DOCKER_TAG}/RPMS/${ARCH}/*.rpm",
                                )
                                publishCsmRpms(
                                        artifactoryRepo: 'fawkes-rpms',
                                        arch: "src",
                                        component: env.NAME,
                                        isStable: isStable,
                                        os: "sle-${sles_major}sp${sles_minor}",
                                        pattern: "dist/rpmbuild/${ARCH}/${DOCKER_TAG}/SRPMS/*.rpm",
                                )
                            }
                        }
                    }
                }
            }
        }
    }
}