-
Notifications
You must be signed in to change notification settings - Fork 0
/
FineDehalo.avsi
244 lines (193 loc) · 10.3 KB
/
FineDehalo.avsi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
# FineDehalo
# 1.1 mod9
#
# This program is free software. It comes without any warranty, to
# the extent permitted by applicable law. You can redistribute it
# and/or modify it under the terms of the Do What The Fuck You Want
# To Public License, Version 2, as published by Sam Hocevar.
Function FineDehalo (clip src, float "rx", float "ry", float "thmi", float "thma", float "thlimi", float "thlima", float "darkstr", float "brightstr", int "showmask", float "contra", bool "excl", float "edgeproc", val "exdehalo", clip "exedgesm", clip "edgemask")
{
rx = Default (rx, 2)
ry = Default (ry, rx)
thmi = Default (thmi, 80)
thma = Default (thma, 128)
thlimi = Default (thlimi, 50)
thlima = Default (thlima, 100)
darkstr = Default (darkstr, 0.0)
brightstr = Default (brightstr, 1.0)
showmask = Default (showmask, 0)
contra = Default (contra, 0.0)
excl = Default (excl, true)
edgeproc = Default (edgeproc, 0.0)
rx_i = Round (rx)
ry_i = Round (ry)
src
### Dehaloing ###
dehaloed = defined(exdehalo) ? isclip(exdehalo) ? exdehalo : eval("last." + exdehalo) : DeHalo_alpha (rx=rx, ry=ry, darkstr=darkstr, brightstr=brightstr)
# Contrasharpening
dehaloed = (contra > 0)
\ ? dehaloed.FineDehalo_contrasharp (src, contra, false)
\ : dehaloed
edgesm = defined(exedgesm) ? exedgesm : FineDehaloedges(rx=rx, ry=ry, thmi=thmi, thma=thma, thlimi=thlimi, thlima=thlima, showmask=showmask, excl=excl, edgeproc=edgeproc, edgemask=edgemask)
### Masking ###
(showmask != 0) ? edgesm
\ : mt_merge (last, dehaloed, edgesm, y=3, u=2, v=2)
}
# level == 1.0 : normal contrasharp
Function FineDehalo_contrasharp (clip dehaloed, clip src, float level, bool "chroma")
{
chroma = Default (chroma, true)
sisavs26 = !(VersionNumber() < 2.6)
bb = dehaloed.RemoveGrain (11, chroma ? undefined : -1)
bb2 = bb.Repair (bb.Repair (bb.Medianblur (2, -256, -256), 1, chroma ? undefined : -1), 1, chroma ? undefined : -1)
xd = mt_makediff (bb, bb2, u=chroma ? 3 : undefined, v=chroma ? 3 : undefined)
xd = !sisavs26 ? xd.mt_lut ("x 128 - 2.49 * "+String(level)+" * 128 +", u=chroma ? 3 : undefined, v=chroma ? 3 : undefined)
\ : xd.mt_lut ("x range_half - 2.49 * "+String(level)+" * range_half +", use_expr=2, u=chroma ? 3 : undefined, v=chroma ? 3 : undefined)
xdd = !sisavs26 ? mt_lutxy (
\ xd,
\ mt_makediff (src, dehaloed, u=chroma ? 3 : undefined, v=chroma ? 3 : undefined),
\ "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", u=chroma ? 3 : undefined, v=chroma ? 3 : undefined
\ ) : mt_lutxy (
\ xd,
\ mt_makediff (src, dehaloed, u=chroma ? 3 : undefined, v=chroma ? 3 : undefined),
\ "x range_half - y range_half - * 0 < range_half x range_half - abs y range_half - abs < x y ? ?", use_expr=2, u=chroma ? 3 : undefined, v=chroma ? 3 : undefined
\ )
dehaloed.mt_adddiff (xdd, y=3, u=chroma ? 3 : 2, v=chroma ? 3 : 2)
}
# moved FineDehalo edges mask in stand-alone Function
Function FineDehaloedges (clip src, float "rx", float "ry", float "thmi", float "thma", float "thlimi", float "thlima", int "showmask", bool "excl", float "edgeproc", clip "edgemask")
{
sisavs26 = !(VersionNumber() < 2.6)
rx = Default (rx, 2)
ry = Default (ry, rx)
thmi = Default (thmi, 80)
thma = Default (thma, 128)
thlimi = Default (thlimi, 50)
thlima = Default (thlima, 100)
showmask = Default (showmask, 0)
excl = Default (excl, true)
edgeproc = Default (edgeproc, 0.0)
rx_i = Round (rx)
ry_i = Round (ry)
src
### Main edges ###
# Basic edge detection, thresholding will be applied later.
edges = defined(edgemask) ? edgemask : mt_edge (mode="prewitt", thY1=0, thY2=255)
# Keeps only the sharpest edges (line edges)
strong = !sisavs26 ? edges.mt_lut (expr="x "+String(thmi)+" - "+String(thma-thmi)+" / 255 *")
\ : edges.mt_lut (expr="x "+String(thmi)+" scalef - "+String(thma-thmi)+" scalef / range_max *", scale_inputs="floatf", clamp_float=true, use_expr=2)
# Extends them to include the potential halos
large = strong.mt_expand_multi (sw=rx_i, sh=ry_i)
### Exclusion zones ###
# When two edges are close from each other (both edges of a single
# line or multiple parallel color bands), the halo removal
# oversmoothes them or makes seriously bleed the bands, producing
# annoying artifacts. Therefore we have to produce a mask to exclude
# these zones from the halo removal.
# Includes more edges than previously, but ignores simple details
light = !sisavs26 ? edges.mt_lut (expr="x "+String(thlimi)+" - "+String(thlima-thlimi)+" / 255 *")
\ : edges.mt_lut (expr="x "+String(thlimi)+" scalef - "+String(thlima-thlimi)+" scalef / range_max *", scale_inputs="floatf", clamp_float=true, use_expr=2)
# To build the exclusion zone, we make grow the edge mask, then shrink
# it to its original shape. During the growing stage, close adjacent
# edge masks will join and merge, forming a solid area, which will
# remain solid even after the shrinking stage.
# Mask growing
shrink = light.mt_expand_multi (sw=rx_i, sh=ry_i, mode="ellipse")
# At this point, because the mask was made of a shades of grey, we may
# end up with large areas of dark grey after shrinking. To avoid this,
# we amplify and saturate the mask here (actually we could even
# binarize it).
shrink = !sisavs26 ? shrink.mt_lut ("x 4 *")
\ : shrink.mt_lut ("x 4 *", clamp_float=true, use_expr=2)
# Mask shrinking
shrink = shrink.mt_inpand_multi (sw=rx_i, sh=ry_i, mode="ellipse")
# This mask is almost binary, which will produce distinct
# discontinuities once applied. Then we have to smooth it.
shrink = shrink.RemoveGrain (20, -1)
shrink = shrink.RemoveGrain (20, -1)
### Final mask building ###
# Previous mask may be a bit weak on the pure edge side, so we ensure
# that the main edges are really excluded. We do not want them to be
# smoothed by the halo removal.
shr_med = (excl) ? mt_logic (strong, shrink, mode="max") : strong
# Substracts masks and amplifies the difference to be sure we get 255
# on the areas to be processed.
outside = !sisavs26 ? mt_lutxy (large, shr_med, "x y - 2 *")
\ : mt_lutxy (large, shr_med, "x y - 2 *", clamp_float=true, use_expr=1)
# If edge processing is required, adds the edgemask
outside = (edgeproc > 0) ? !sisavs26 ? mt_lutxy(outside, strong, "x y "+String(edgeproc * 0.66)+" * +") : mt_lutxy(outside, strong, "x y "+String(edgeproc * 0.66)+" * +", clamp_float=true, use_expr=1) : outside
# Smooth again and amplify to grow the mask a bit, otherwise the halo
# parts sticking to the edges could be missed.
!sisavs26 ? outside.RemoveGrain (20, -1).mt_lut ("x 2 *")
\ : outside.RemoveGrain (20, -1).mt_lut ("x 2 *", clamp_float=true, use_expr=1)
(showmask == 1) ? outside.GreyScale ()
\ : (showmask == 2) ? shrink.GreyScale ()
\ : (showmask == 3) ? edges.GreyScale ()
\ : (showmask == 4) ? strong.GreyScale ()
\ : last
}
# Try to remove 2nd order halos.
Function FineDehalo2 (clip src, string "hconv", string "vconv", int "showmask")
{
sisavs26 = !(VersionNumber() < 2.6)
hconv = Default (hconv, "-1 -2 0 0 40 0 0 -2 -1")
vconv = Default (vconv, "-2 -1 0 0 40 0 0 -1 -2")
showmask = Default (showmask, 0)
src
fix_h = mt_convolution (horizontal="1", vertical=vconv, y=3, u=2, v=2)
fix_v = mt_convolution (horizontal=hconv, vertical="1", y=3, u=2, v=2)
edges_h = mt_edge (mode="1 2 1 0 0 0 -1 -2 -1", thY1=0, thY2=255)
edges_v = mt_edge (mode="1 0 -1 2 0 -2 1 0 -1", thY1=0, thY2=255)
mask_h = edges_h #.mt_lut (expr="x 2 *")
mask_v = edges_v #.mt_lut (expr="x 2 *")
temp_h = !sisavs26 ? mt_lutxy (mask_h, mask_v, expr="x 3 * y -")
\ : mt_lutxy (mask_h, mask_v, expr="x 3 * y -", clamp_float=true, use_expr=1)
temp_v = !sisavs26 ? mt_lutxy (mask_v, mask_h, expr="x 3 * y -")
\ : mt_lutxy (mask_v, mask_h, expr="x 3 * y -", clamp_float=true, use_expr=1)
mask_h = temp_h
mask_v = temp_v
mask_h = mask_h.FineDehalo2_grow_mask ("vertical")
mask_v = mask_v.FineDehalo2_grow_mask ("horizontal")
src
mt_merge (last, fix_h, mask_h, y=3, u=2, v=2)
mt_merge (last, fix_v, mask_v, y=3, u=2, v=2)
(showmask == 1) ? mt_logic (mask_h, mask_v, mode="max").GreyScale ()
\ : last
}
Function FineDehalo2_grow_mask (clip mask, string mode)
{
sisavs26 = !(VersionNumber() < 2.6)
Assert ((mode == "horizontal" || mode == "vertical"), "Wrong mode")
mask
mt_expand (mode=mode).mt_inpand (mode=mode)
mask_1 = mt_expand (mode=mode)
mask_2 = mask_1.mt_expand (mode=mode).mt_expand (mode=mode)
!sisavs26 ? mt_lutxy (mask_2, mask_1, expr="x y -")
\ : mt_lutxy (mask_2, mask_1, expr="x y -", clamp_float=true, use_expr=1)
!sisavs26 ? RemoveGrain (12, -1).mt_lut (expr="x 1.8 *")
\ : RemoveGrain (12, -1).mt_lut (expr="x 1.8 *", clamp_float=true, use_expr=2)
}
# new Functions added to the mod ver.
Function FineDehaloanalog (clip src, int "dhhradius", float "arx", float "ary", string "exdehalo", clip "fexedgesm", clip "linesm", bool "remasked", float "darkstr", float "brightstr")
{
rx = Default (arx, 2) # DeHalo_alpha rx
ry = Default (ary, rx) # DeHalo_alpha ry
edgm = Defined(linesm) ? linesm : src.slinesm()
rad = Default(dhhradius, 2)
remasked = Default(remasked, true)
blurmix = remasked ? 0.5 : 0.8
rx_i = Round (rx)
ry_i = Round (ry)
exdehalo = Default(exdehalo, "VHSHaloremover("+String(rx_i)+","+String(ry_i)+",200,100,"+String(blurmix)+")")
useldh = !defined(darkstr) && !defined(brightstr) && !defined(arx) && !defined(ary)
src
lightdh = DeHalo_alpha_mt(rx=rx_i,ry=ry_i,darkstr=0.2,brightstr=0.8)
FDedges = Defined(fexedgesm) ? fexedgesm : lightdh.FineDehaloedges(rx=rx_i,ry=ry_i)
alphadh = remasked ? lightdh : \
FineDehalo(rx=rx,ry=ry,exdehalo=useldh ? lightdh : \
undefined(),darkstr=darkstr,brightstr=brightstr,exedgesm=FDedges)
hfil = alphadh.FineDehalo(rx=rx,ry=ry,exdehalo=DeHaloHmod(rad,exdehalo=exdehalo,extmask=edgm), exedgesm=FDedges)
RM2 = remasked ? spasses(edgm.mt_inflate(),rad,"mt_expand()").mt_inflate() : nop()
DeRinging = mt_Merge(hfil, src, edgm.mt_inflate(155,155),u=remasked ? 1 : 4,v=remasked ? 1 : 4)
remasked ? mt_Merge(src, DeRinging, RM2, u=2, v=2) : DeRinging
}