-
Notifications
You must be signed in to change notification settings - Fork 0
/
avs_utils.avsi
362 lines (260 loc) · 9.89 KB
/
avs_utils.avsi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
####################################
### ###
### DonCanjas presents: ###
### Don's Utils ###
### 05-05-2024 - r1 ###
### ###
####################################
### avs_utils version 05-04-2023
### Meme hearders aside, these are a collection of functions I either use or think that might be useful.
### Everything is written with avs+ in mind.
### avs_utils version 01-11-2023
### Fixed pack3rgb() that would use only clip c
### avs_utils version 02-11-2023
### packrgb() was upgraded in order to deprecate and delete pack3rgb()
### avs_utils version 25-04-2024 - Carnation Revolution update
### mirrorborders() isn't limited to a single value for all borders anymore
### s_addborders() was added
### padmod() was added
### avs_utils version 29-04-2024
### Fixed identations
### fixtvgamma() was added
### avs_utils version 30-04-2024 - r1
### changed fixtvgamma() to operate at 32 bit
### sfillborders() was added
### avs_utils version 30-04-2024 - r2
### added addborder param to sfillborders()
### fixed typos
### avs_utils version 05-05-2024 - r1
### linearscaling() was added
### add TODO to fixtvgamma()
### Included Functions
###
### scrop()
###
### sborders()
###
### sfillborders()
###
### padmod()
###
### mirrorborders()
###
### limitRGBPS()
###
### packrgb()
###
### fixtvgamma()
###
### linearscaling()
#######################
# scrop()
#
# A wrapper for avs' internal function Crop(). S stands for Sane, Schizo, or whatever else you decide.
# It was written to drop the need for negative numbers and change the param order to make it function like vapoursynth's std.Crop().
Function scrop(clip c, int "left", int "right", int "top", int "bottom", bool "align")
{
left = Default(left, 0)
right = Default(right, 0)
top = Default(top, 0)
bottom = Default(bottom, 0)
c.crop(left, top, -right, -bottom, align)
}
# sborders()
#
# A wrapper for avs' internal function AddBorders(). S stands for Sane, Schizo, or whatever else you decide.
# It was written to change the param order to make it function like scrop().
Function sborders(clip c, int "left", int "right", int "top", int "bottom", int "color")
{
left = Default(left, 0)
right = Default(right, 0)
top = Default(top, 0)
bottom = Default(bottom, 0)
color = Default(color, $000000)
c.AddBorders(left, top, right, bottom, color)
}
# sfillborders()
#
# Wrapper for FillBorders. It'll add borders by default, unless addborder=false.
# Changes param order to make it function like sborders().
#
# Dependencies:
# FillBorders: https://github.com/Asd-g/AviSynth-FillBorders
Function sfillborders(clip c, int "left", int "right", int "top", int "bottom", int "mode", bool "addborder", int "y", int "u", int "v")
{
left = Default(left, 0)
right = Default(right, 0)
top = Default(top, 0)
bottom = Default(bottom, 0)
mode = Default(mode, 0)
addborder = Default(addborder, true)
y = Default(y, 3)
u = Default(u, 3)
v = Default(v, 3)
borders = addborder ? c.AddBorders(left, top, right, bottom) : c
borders.FillBorders(left=left, top=top, right=right, bottom=bottom, mode=mode, y=y, u=u, v=v)
}
# padmod()
#
# Pads clip to mod x by mirroring borders.
# #Based on: https://github.com/Vodes/vodesfunc/blob/master/vodesfunc/scale.py#L308-L320 - 25/04/2024
#
# min: minimum ammount to pad (default: 0)
# mod: desired output resolution's module (default: 4)
#
# Dependencies:
# avsresize
Function padmod(clip c, int "min", int "mod")
{
min = Default(min, 0)
mod = Default(mod, 4)
og_w = Width(c)
og_h = Height(c)
w = og_w + min * 2
h = og_h + min * 2
ph = mod - ((w - 1) % mod + 1)
pv = mod - ((h - 1) % mod + 1)
left = ( floor(ph / 2) ) + min
right = ( ph - left ) + min
top = ( floor(pv / 2) ) + min
bottom = ( pv - top ) + min
width = og_w + left + right
height = og_h + top + bottom
c.z_PointResize(width, height, src_left=-left, src_top=-top, src_width=width, src_height=height)
}
# mirrorborders()
#
# Mirrors borders by user defined value.
# ex: 408x408 clip
# clip.mirrorborders(left=2, right=2, top=2, bottom=2) will output an 412x412 clip with 2px thick mirrored borders.
#
# Dependencies:
# avsresize
Function mirrorborders(clip c, int "left", int "right", int "top", int "bottom")
{
left = Default(left, 0)
right = Default(right, 0)
top = Default(top, 0)
bottom = Default(bottom, 0)
w = Width(c)
h = Height(c)
width = w + left + right
height = h + top + bottom
c.z_PointResize(width, height, src_left=-left, src_top=-top, src_width=width, src_height=height)
}
# limitRGBPS()
#
# Clamps RGBPS clip to legal values.
Function limitRGBPS(clip c)
{
bits = BitsPerComponent(c)
if (!isPlanarRGB(c) || bits != 32)
{
Assert(false, "Only RGBPS supported")
}
else
{
Expr(c, "x 0 1 clip")
}
}
# packrgb()
#
# Packs your clip(s) to RGBP.
Function packrgb(clip "r", clip "g", clip "b")
{
bits = Defined(r) ? BitsPerComponent(r) : Defined(g) ? BitsPerComponent(g) : BitsPerComponent(b)
if (bits == 32 )
{
pix_fmt = "RGBPS"
}
else
{
pix_fmt = "RGBP"+String(bits)
pix_fmt = String(pix_fmt)
}
CombinePlanes(r, g, b, planes="RGB", source_planes="YYY", pixel_type=pix_fmt)
}
# fixtvgamma()
#
# Fixes gamma bug in Y or YUV clips at 32 bit depth. If input is lower than 32 bit, it'll convert.
#
# TODO:
# Let user choose between 16 and 32 bit outputs, defaulting to 16 bit if input isn't 32 bit.
function fixtvgamma(clip c, bool "dither")
{
dither = Default(dither, false)
bits = BitsPerComponent(c)
yuv = isYUV(c)
gray = isY(c)
if (!yuv)
{
Assert(false, "Only Y or YUV supported")
}
if (bits < 32)
{
c = c.ConvertBits(32)
}
if (gray == False)
{
y = c.ExtractY()
y = y.Levels(0, 0.88, 1, 0, 1, false, dither)
u = c.ExtractU()
v = c.ExtractV()
gammafix = CombinePlanes(Y, U, V, planes="YUV", source_planes="YYY", sample_clip=c)
}
else
{
gammafix = c.Levels(0, 0.88, 1, 0, 1, false, dither)
}
return gammafix
}
# linearscaling()
#
# Uses avsresize to do linear light scaling. Y and RGB convert directly to linear 32 bit. YUV will convert to linear RGBPS. It uses frames props in order to get an automatic conversion.
#
# Dependencies:
# avsresize
#
# TODO:
# replace scaler_uv with scaler_uv for linear conversion and scaler_uv for gamma conversion
# add possibility to parse own colorspace_op and chromaloc_op
# add possibility to output at any pixel format
# add kernels as scaler_param presets (ex: Robidoux, RobidouxSharp, etc)
Function linearscaling(clip c, int "width", int "height", string "scaler", float "scaler_param_a", float "scaler_param_b", string "scaler_uv", float "scaler_param_a_uv", float "scaler_param_b_uv")
{
pix_fmt = PixelType(c)
gray = isY(c)
#defaults
width = Default(width, Width(c))
height = Default(height, Height(c))
scaler = Default(scaler, "bicubic")
scaler_param_a = Default(scaler_param_a, 1.00/3.00)
scaler_param_b = Default(scaler_param_b, 1.00/3.00)
scaler_uv = Default(scaler_uv, scaler)
scaler_param_a_uv = Default(scaler_param_a_uv, scaler_param_a)
scaler_param_b_uv = Default(scaler_param_b_uv, scaler_param_b)
#frame props
matrix_idx = propGetAny(c, "_Matrix")
transfer_idx = propGetAny(c, "_ColorRange")
primaries_idx = propGetAny(c, "_Primaries")
range_idx = propGetAny(c, "_ColorRange")
chromaloc_idx = propGetAny(c, "_ChromaLocation")
matrix = Select(matrix_idx, "rgb", "709", "unspec", "fcc", "470bg", "170m", "240", "ycgco", "2020ncl", "2020cl", "chromancl", "chromacl", "ictcp")
transfer = Select(transfer_idx, "", "709", "unspec", "470m", "470bg", "601", "240m", "linear", "log100", "log316", "xvycc", "srgb", "2020_10", "2020_12", "st2084", "std-b67", "prophoto")
primaries = Select(primaries_idx, "", "709", "unspec", "470m", "470bg", "170m", "240m", "film", "2020", "st428", "st431-2", "st432-1", "jedec-p22", "prophoto")
range = Select(range_idx, "full", "limited")
chromaloc = gray ? nop() : Select(chromaloc_idx, "left", "center", "topleft", "top", "bottomleft", "bottom")
if (gray == True)
{
linear = c.z_ConvertFormat(pixel_type="Y32", colorspace_op=matrix+":"+transfer+":"+primaries+":"+range+"""=>"""+matrix+":linear:"+primaries+":full")
scaled_linear = linear.z_ConvertFormat(width=width, height=height, resample_filter=scaler, filter_param_a=scaler_param_a, filter_param_b=scaler_param_b)
scaled_gamma = scaled_linear.z_ConvertFormat(pixel_type=pix_fmt, colorspace_op=matrix+":linear:"+primaries+":full=>"+matrix+":"+transfer+":"+primaries+":"+range+"")
}
else
{
linear = c.z_ConvertFormat(pixel_type="RGBPS", colorspace_op=matrix+":"+transfer+":"+primaries+":"+range+"""=>RGB:linear:"""+primaries+":full", chromaloc_op=chromaloc+"=>center", resample_filter_uv=scaler_uv, filter_param_a_uv=scaler_param_a_uv, filter_param_b_uv=scaler_param_b_uv)
scaled_linear = linear.z_ConvertFormat(width=width, height=height, resample_filter=scaler, filter_param_a=scaler_param_a, filter_param_b=scaler_param_b)
scaled_gamma = scaled_linear.z_ConvertFormat(pixel_type=pix_fmt, colorspace_op="RGB:linear:"+primaries+":full=>"+matrix+":"+transfer+":"+primaries+":"+range+"", chromaloc_op="center=>"+chromaloc, resample_filter_uv=scaler_uv, filter_param_a_uv=scaler_param_a_uv, filter_param_b_uv=scaler_param_b_uv)
}
return scaled_gamma
}