build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

repositories {
	maven {
        name "Mobius Repo"
        url "http://mobiusstrip.eu/maven"
    }
    maven {
        name 'CB Maven FS'
        url "http://chickenbones.net/maven/"
    }
    maven {
        name 'ForgeFS'
        url 'http://files.minecraftforge.net/maven'
    }
	maven {
		url "http://dvs1.progwml6.com/files/maven"
    } 
	maven {
		url "http://maven.amadornes.com/"
	}
    maven {
		url "http://tehnut.info/maven"
	}
	maven {
        name = "forestry"
        url = "http://maven.ic2.player.to/"
    }
}

apply plugin: 'net.minecraftforge.gradle.forge'

ext.configFile = file "build.properties"

configFile.withReader {
    def prop = new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
    project.ext.modVersion = "${config.minecraft_version}-${config.mod_version}." + (System.env.BUILD_NUMBER ?: "localBuild")
}

ext.modInfo = file "mod.properties"

modInfo.withReader {
    def prop = new Properties()
    prop.load(it)
    project.ext.mod = new ConfigSlurper().parse prop
}

version = modVersion
group= mod.group // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = mod.fileName

sourceCompatibility = 1.8
targetCompatibility = 1.8

minecraft {
    version = config.minecraft_version + "-" + config.forge_version
    runDir = "run"
	
	replaceIn mod.mainClass
    replace "#ELECCORE_VER#", config.eleccore_version
	replace "#FORGE_VER#", config.forge_version
	
	mappings = config.mappings
	
	useDepAts = true
}

dependencies {
    deobfCompile "mcp.mobius.waila:Hwyla:${config.waila_version}"
	deobfCompile "mezz.jei:jei_${config.jei_version}"
	deobfCompile "MCMultiPart2:MCMultiPart:${config.mcmp_version}"
	deobfCompile("net.sengir.forestry:forestry_${config.forestry_version}") {
        transitive = false
    }
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", modVersion
    inputs.property "mcversion", config.minecraft_version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':modVersion, 'mcversion':config.minecraft_version, 'modid': mod.modid
    }
        
    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}