-
Notifications
You must be signed in to change notification settings - Fork 0
/
build_java11.gradle
244 lines (217 loc) · 8.47 KB
/
build_java11.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
// Copyright (c) 2003-2018 Broad Institute, Inc., Massachusetts Institute of Technology, and Regents
// of the University of California. All rights reserved.
apply plugin: 'java'
import org.apache.tools.ant.filters.ReplaceTokens
ext.moduleName = 'org.gsea_msigdb.xmlbrowser'
ext.mainClassName = 'xapps.browser.gsea.MSigDB_XML_Browser'
// Put the Java 11 build into a special dir to avoid accidental collisions.
// Despite this, it is recommended that Java 8 vs. 11 builds be run in different locations.
buildDir = 'build_java11'
sourceSets {
main {
java {
srcDirs = ['src/main/java', 'src/main/java11']
}
}
}
configurations {
jidePatchModuleLibs
}
dependencies {
compile fileTree(dir: 'modules', include: '*.jar')
jidePatchModuleLibs fileTree(dir: 'lib', include: '*.jar')
}
task wrapper(type: Wrapper) {
gradleVersion = '4.10.2'
}
// Gradle bug prevents us from generating Java 11 bytecode: https://github.com/gradle/gradle/issues/5120
// Workaround is to target Java 10 for now.
sourceCompatibility = 10
targetCompatibility = 10
processResources {
// Set the current timestamp for release builds; pass in a blank property to enable (i.e. -Ptimestamp="" at CLI)
if (timestamp.equals("")) { timestamp = new Date().format("EEE, d MMM yyyy HH:mm:ss Z") }
filesMatching('edu/mit/broad/msigdb_browser/genome/resources/build.properties') {
filter (ReplaceTokens,
tokens: [ VERSION: version, VERSION_MAJOR: versionMajor, VERSION_MINOR: versionMinor, VERSION_PATCH: versionPatch,
BUILD: buildNumber, TIMESTAMP: timestamp ])
}
}
jar {
archiveName = "msigdb-xml-browser-minimal-${version}.jar"
manifest {
attributes(
"Permissions": "all-permissions",
"Application-Name": "MSigDB_XML_Browser",
"Built-By": System.getProperty('user.name'),
"MSigDB_XML_Browser-Build-Date": timestamp,
"Main-Class": mainClassName,
)
}
}
compileJava {
inputs.property("moduleName", moduleName)
doFirst {
options.compilerArgs = [
'--module-path', classpath.asPath,
'--patch-module=jide.common=' + configurations.jidePatchModuleLibs.asPath,
"--add-exports=jide.common/com.jidesoft.grid=${moduleName}",
"--add-exports=jide.common/com.jidesoft.docking=${moduleName}",
"--add-exports=jide.common/com.jidesoft.status=${moduleName}"
]
classpath = files()
}
}
task createDist(type: Copy, dependsOn: jar) {
from ("src/main/resources/edu/mit/broad/msigdb_browser/genome/resources/icon_64x64.png")
from ('scripts/java11') {
include 'msigdb-xml-browser*'
include 'readme.txt'
}
with copySpec {
from ("${buildDir}/libs")
from ("modules")
into "modules"
}
with copySpec {
from ("lib") into "lib"
}
into "${buildDir}/MSigDB_XML_Browser-dist"
}
task createDistZip(type: Zip, dependsOn: createDist) {
baseName = "MSigDB_XML_Browser"
archiveName = createDistZip.baseName + "_${version}.zip"
destinationDir = file("${buildDir}/distZip")
from "${buildDir}/MSigDB_XML_Browser-dist"
into createDistZip.baseName + "_${version}"
doLast {
project.exec { commandLine('chmod', '775', createDistZip.archivePath ) }
}
}
task createLinuxDistZip(type: Zip, dependsOn: createDist) {
baseName = "MSigDB_XML_Browser_Linux"
archiveName = createLinuxDistZip.baseName + "_${version}.zip"
destinationDir = file("${buildDir}/distZip")
if (!jdkBundleLinux.equals("")) {
with copySpec { from jdkBundleLinux into "jdk-11" }
}
from ("${buildDir}/MSigDB_XML_Browser-dist") {
exclude "*.bat"
exclude "*.command"
}
into createLinuxDistZip.baseName + "_${version}"
doLast {
project.exec { commandLine('chmod', '775', createLinuxDistZip.archivePath ) }
}
}
task createMacDistZip(type: Zip, dependsOn: createDist) {
baseName = "MSigDB_XML_Browser_Mac"
archiveName = createMacDistZip.baseName + "_${version}.zip"
destinationDir = file("${buildDir}/distZip")
if (!jdkBundleMac.equals("")) {
with copySpec { from jdkBundleMac into "jdk-11" }
}
from ("${buildDir}/MSigDB_XML_Browser-dist") {
exclude "*.bat"
exclude "*_hidpi.sh"
}
into createMacDistZip.baseName + "_${version}"
doLast {
project.exec { commandLine('chmod', '775', createMacDistZip.archivePath ) }
}
}
task createMacAppDist(type: Copy, dependsOn: createDist) {
if (!jdkBundleMac.equals("")) {
with copySpec { from jdkBundleMac into "MSigDB_XML_Browser_${version}.app/Contents/jdk-11" }
}
with copySpec {
from ("scripts/mac.app") {
exclude "Contents/Info.plist.template"
exclude "Contents/MacOS/JavaAppLauncher"
}
into "MSigDB_XML_Browser_${version}.app"
}
with copySpec {
from ("scripts/java11/Info.plist.template")
filter (ReplaceTokens, tokens: [ VERSION: version ])
rename "Info.plist.template", "Info.plist"
into "MSigDB_XML_Browser_${version}.app/Contents"
}
with copySpec {
from ("scripts/java11/MSigDB_XML_Browser_mac.app.command")
rename "MSigDB_XML_Browser_mac.app.command", "MSigDB_XML_Browser"
into "MSigDB_XML_Browser_${version}.app/Contents/MacOS"
}
with copySpec {
from ("src/main/resources/edu/mit/broad/msigdb_browser/genome/resources/icon_64x64.png")
into "MSigDB_XML_Browser_${version}.app/Contents/Resources"
}
with copySpec {
from ("${buildDir}/MSigDB_XML_Browser-dist/") include 'msigdb-xml-browser.args'
into "MSigDB_XML_Browser_${version}.app/Contents/Java/"
}
with copySpec {
from ("${buildDir}/MSigDB_XML_Browser-dist/modules") include '*.jar'
into "MSigDB_XML_Browser_${version}.app/Contents/Java/modules"
}
with copySpec {
from ("${buildDir}/MSigDB_XML_Browser-dist/lib") include '*.jar'
into "MSigDB_XML_Browser_${version}.app/Contents/Java/lib"
}
into "${buildDir}/MSigDB_XML_Browser-MacApp-dist"
doLast {
project.exec { commandLine('chmod', '775', "${buildDir}/MSigDB_XML_Browser-MacApp-dist/MSigDB_XML_Browser_${version}.app" ) }
}
}
task createMacAppDistZip(type: Zip, dependsOn: createMacAppDist) {
archiveName = "MSigDB_XML_Browser_${version}.app.zip"
destinationDir = file("${buildDir}/distZip")
from "${buildDir}/MSigDB_XML_Browser-MacApp-dist"
doLast {
project.exec { commandLine('chmod', '775', createMacAppDistZip.archivePath ) }
}
}
task createWinDist(type: Copy, dependsOn: createDist) {
if (!jdkBundleWindows.equals("")) {
with copySpec { from jdkBundleWindows into "MSigDB_XML_Browser_${version}/jdk-11" }
}
with copySpec {
from("${buildDir}/MSigDB_XML_Browser-dist") {
exclude "*.sh"
exclude "*.command"
}
from ("scripts/nsis") { include "XMLBrowser_Icon.ico" }
into "MSigDB_XML_Browser_${version}"
}
with copySpec {
// Create a build-specific NSIS installer script.
from ("scripts/nsis/installer.nsi")
filter (ReplaceTokens, tokens: [ VERSION: version ])
}
from ("scripts/nsis") { include "LICENSE_WIN.txt" }
into "${buildDir}/MSigDB_XML_Browser-WinExe-dist"
}
task createWinExeDist(type: Exec, dependsOn: createWinDist) {
commandLine(makensisCommand, "-O${buildDir}/tmp/nsis-build.log",
"${buildDir}/MSigDB_XML_Browser-WinExe-dist/installer.nsi")
doLast {
if (makensisCommand.equals("")) {
throw new GradleException("Required property not set: makensisCommand");
}
}
}
task signWinExeDist(type: Exec, dependsOn: createWinExeDist) {
standardInput = new ByteArrayInputStream( keyPassword.getBytes() );
commandLine(signcodeCommand, "-spc", spcFile, "-v", pvkFile, "-a", "sha1",
"-\$", "commercial", "-n", "MSigDB_XML_Browser ${version}", "-i", "http://www.gsea-msigdb.org/",
"-t", tsaurl, "-tr", "10", "${buildDir}/MSigDB_XML_Browser-WinExe-dist/MSigDB_XML_Browser_${version}-installer.exe")
doLast {
if (signcodeCommand.equals("")) {
throw new GradleException("Required property not set: signcodeCommand");
}
}
}
build.dependsOn createDistZip,createLinuxDistZip,createMacDistZip,createMacAppDistZip
if (!makensisCommand.equals("") && !signcodeCommand.equals("")) {
build.dependsOn signWinExeDist
}