-
-
Notifications
You must be signed in to change notification settings - Fork 79
/
scatterplot.jl
163 lines (143 loc) · 6.68 KB
/
scatterplot.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
"""
scatterplot(x, y; kw...)
scatterplot!(p, args...; kw...)
# Description
Draws the given points on a new canvas.
The first (optional) vector `x` should contain the horizontal positions for all the points.
The second vector `y` should then contain the corresponding vertical positions respectively.
This means that the two vectors must be of the same length and ordering.
# Usage
scatterplot([x], y; $(keywords(; add = (:canvas,))))
# Arguments
$(arguments(
(
marker = "choose a marker from $(keys(MARKERS)), a `Char`, a unit length `String` or a `Vector` of these",
color = "`Vector` of colors, or scalar - $(DESCRIPTION[:color])",
); add = (:x, :y, :canvas)
))
Author(s)
- Christof Stocker (github.com/Evizero)
# Examples
```julia-repl
julia> scatterplot(randn(50), randn(50), title = "My Scatterplot")
⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀My Scatterplot⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀
┌────────────────────────────────────────┐
3 │⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠄⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠈⠀⠀⠠⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠁⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠠⠀⠀⠂⡀⠀⠀⠀⠀⠀⠄⠀⠀⠀⠀⠀⠀│
│⠈⠀⠀⠀⠀⠠⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠌⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠠⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠄⠀⠀⠀⠀⠀⠀⡇⠁⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠠⠀⡀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡀⠀⠀⠀⠀⠀⠀⠀⠀⡀⡏⠀⠉⠀⠀⠂⠀⠠⠀⠄⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠤⠤⠤⠤⠤⠤⠤⠴⠤⢤⠤⠤⠤⠤⠤⠤⠬⠤⢤⠤⡧⠤⢤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤⠤│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠠⠀⠀⠀⠀⠀⠂⠀⠀⡇⠀⠀⠀⠂⠠⡀⠀⡀⠀⠀⠀⡀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠄⠀⠀⠀⠀⠀⠀⠄⠀⠀⠀⠈⠀⠀⡇⠀⠀⠀⠀⠈⠀⠀⠀⠁⠀⠀⠀⠀⠐⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⢀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠐⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡀⠀⠀⠀⡇⠀⠠⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠐⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
│⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
-3 │⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⡇⠀⠀⠀⠀⠀⠀⠀⠀⠐⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀│
└────────────────────────────────────────┘
⠀-2⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀⠀2⠀
```
# See also
[`Plot`](@ref), [`lineplot`](@ref), [`stairs`](@ref),
[`BrailleCanvas`](@ref), [`BlockCanvas`](@ref),
[`AsciiCanvas`](@ref), [`DotCanvas`](@ref)
"""
function scatterplot(
x::AbstractVector,
y::AbstractVector,
z::Union{AbstractVector,Nothing} = nothing;
canvas::Type = KEYWORDS.canvas,
kw...,
)
pkw, okw = split_plot_kw(kw)
scatterplot!(Plot(x, y, z, canvas; pkw...), x, y, z; okw...)
end
scatterplot(y::AbstractVector; kw...) = scatterplot(axes(y, 1), y; kw...)
@doc (@doc scatterplot) function scatterplot!(
plot::Plot{<:Canvas},
x::AbstractVector,
y::AbstractVector,
z::Union{AbstractVector,Nothing} = nothing;
color::Union{UserColorType,AbstractVector} = KEYWORDS.color,
marker::Union{MarkerType,AbstractVector} = :pixel,
name = KEYWORDS.name,
kw...,
)
color = color ≡ :auto ? next_color!(plot) : color
col_vec = color isa AbstractVector
isempty(name) || label!(plot, :r, string(name), col_vec ? first(color) : color)
if marker ∈ (:pixel, :auto)
if col_vec
@inbounds for i ∈ eachindex(color)
points!(plot, x[i], y[i], z ≡ nothing ? z : z[i]; color = color[i])
end
else
points!(plot, x, y, z; color)
end
else
z ≡ nothing || throw(ArgumentError("unsupported scatter with 3D data"))
for (xi, yi, mi, ci) ∈ zip(x, y, iterable(marker), iterable(color))
annotate!(plot, xi, yi, char_marker(mi); color = ci, kw...)
end
end
plot.series[] += 1
plot
end
scatterplot!(plot::Plot{<:Canvas}, y::AbstractVector; kw...) =
scatterplot!(plot, axes(y, 1), y; kw...)
# ---------------------------------------------------------------------------- #
# multiple series
function scatterplot(x::AbstractVector, y::AbstractMatrix; kw...)
names, colors, markers = multiple_series_defaults(y, kw, 1)
plot = scatterplot(
x,
y[:, begin];
ylim = extrema(y),
name = first(names),
color = first(colors),
marker = first(markers),
filter(k -> k.first ∉ (:name, :color, :marker), kw)...,
)
for (i, (name, color, marker, ys)) ∈ enumerate(zip(names, colors, markers, eachcol(y)))
i == 1 && continue
scatterplot!(plot, x, ys; name, color, marker)
end
plot
end
function scatterplot!(plot::Plot{<:Canvas}, x::AbstractVector, y::AbstractMatrix; kw...)
names, colors, markers = multiple_series_defaults(y, kw, plot.series[] + 1)
for (name, color, marker, ys) ∈ zip(names, colors, markers, eachcol(y))
scatterplot!(plot, x, ys; name, color, marker)
end
plot
end
# ---------------------------------------------------------------------------- #
# Unitful
function scatterplot(
x::AbstractVector{<:RealOrRealQuantity},
y::AbstractVector{<:Quantity};
unicode_exponent::Bool = KEYWORDS.unicode_exponent,
xlabel = KEYWORDS.xlabel,
ylabel = KEYWORDS.ylabel,
kw...,
)
x, ux = number_unit(x, unicode_exponent)
y, uy = number_unit(y, unicode_exponent)
scatterplot(
ustrip.(x),
ustrip.(y);
xlabel = unit_label(xlabel, ux),
ylabel = unit_label(ylabel, uy),
unicode_exponent,
kw...,
)
end
scatterplot!(
plot::Plot{<:Canvas},
x::AbstractVector{<:RealOrRealQuantity},
y::AbstractVector{<:Quantity};
kw...,
) = scatterplot!(plot, ustrip.(x), ustrip.(y); kw...)