build.gradle

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

sourceCompatibility = 1.8
group = 'com.notronix'
version = '1.0.7' //System.getenv("BUILD_NUMBER") ?: 'SNAPSHOT-' + getDate()

repositories {
    mavenCentral()
}

dependencies {
    compile 'com.notronix:AlbacoreDeed:2.0.5'
    compile 'com.google.http-client:google-http-client-gson:1.30.2'
    compile 'org.apache.commons:commons-lang3:3.9'

    testCompile 'junit:junit:4.11'
}

wrapper {
    gradleVersion = '6.5'
}

jar {
    manifest {
        attributes 'Implementation-Title': rootProject.name,
                'Implementation-Version': version,
                'Implementation-Vendor': 'Notronix'
    }
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from tasks.javadoc.destinationDir
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar

    archives javadocJar
    archives sourcesJar
}

signing {
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            pom.project {
                name rootProject.name
                packaging 'jar'
                description 'A Java implementation of the Linnworks API'
                url 'https://github.com/Notronix/JaLAPI/'

                scm {
                    url 'scm:git@github.com:Notronix/' + rootProject.name + '.git'
                    connection 'scm:git@github.com:Notronix/' + rootProject.name + '.git'
                    developerConnection 'scm:git@github.com:Notronix/' + rootProject.name + '.git'
                }

                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }

                developers {
                    developer {
                        id 'clint.munden'
                        name 'Clint Munden'
                    }
                }
            }
        }
    }
}

//def getDate() {
//    def date = new Date()
//    def formattedDate = date.format('yyyyMMddHHmmss')
//    return formattedDate
//}