build.gradle

plugins {
	id 'fabric-loom'
	id 'checkstyle'
	id 'com.diffplug.spotless'
}


version = rootProject.mod_version
group = rootProject.maven_group

base {
	archivesName = project.archives_base_name
}


checkstyle {
	configFile = file("${rootDir}/checkstyle.xml")
	toolVersion = project.checkstyle_version
}

spotless {
	java {
		removeUnusedImports()
		importOrder("java", "javax", "", "net.minecraft", "com.github.reviversmc")
		indentWithTabs()
		trimTrailingWhitespace()
	}
}


repositories {
	if (project.use_third_party_mods == 'true') {
		maven {
			name = 'Modrinth'
			url = 'https://api.modrinth.com/maven'
			content {
				includeGroup 'maven.modrinth'
			}
		}
		maven {
			url = 'https://cursemaven.com'
			content {
				includeGroup 'curse.maven'
			}
		}
	}
	maven {
		name "Siphalor's Maven"
		url 'https://maven.siphalor.de/'
	}
	maven {
		name = 'TerraformersMC'
		url = 'https://maven.terraformersmc.com/releases'
	}
	maven {
		url = 'https://maven.shedaniel.me/'
	}
	mavenCentral()
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"

	// Fabric
	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"
	modImplementation fabricApi.module('fabric-api-base', project.fabric_api_version)
	modImplementation fabricApi.module('fabric-lifecycle-events-v1', project.fabric_api_version)
	modImplementation fabricApi.module('fabric-key-binding-api-v1', project.fabric_api_version)

	// Other mods
	modCompileOnly "de.siphalor:amecsapi-1.20:${project.amecs_api_version}"
	modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"

	modImplementation("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}") {
		exclude(group: 'net.fabricmc.fabric-api')
	}


	if (project.use_third_party_mods == 'true') {
		configurations {
			modRuntimeOnly {
				transitive = true
				exclude module: 'fabric-loader'
				exclude module: 'fabric-lifecycle-events-v1'
				exclude module: 'fabric-key-binding-api-v1'
			}
		}

		// Comment out the following line to check vanilla compatibility
		modRuntimeOnly "de.siphalor:amecsapi-1.20:${project.amecs_api_version}"

		// Use full Fabric API bundle while debugging, since transitive deps aren't always declared correctly
		modRuntimeOnly "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

		modRuntimeOnly "maven.modrinth:sodium:${project.sodium_version}"
		modRuntimeOnly "maven.modrinth:lithium:${project.lithium_version}"
		modRuntimeOnly "maven.modrinth:ferrite-core:${project.ferritecore_version}"
		modRuntimeOnly "maven.modrinth:threadtweak:${project.threadtweak_version}"
		modRuntimeOnly "maven.modrinth:fadeless:${project.fadeless_version}"
	}
}


processResources {
	inputs.property 'version', project.version

	filesMatching('fabric.mod.json') {
		expand 'version': project.version
	}

	from("${rootDir}/assets/icon.png") {
		into 'assets/toomanybinds/'
	}
}

tasks.withType(JavaCompile).configureEach {
	// Ensure that the encoding is set to UTF-8, no matter what the system default is.
	// This fixes some edge cases with special characters not displaying correctly,
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html.
	// If Javadoc is generated, this must be specified in that task too.
	it.options.encoding = 'UTF-8'

	// Minecraft 1.18-pre2 upwards uses Java 17.
	it.options.release = 17
}

java {
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17

	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present. If you remove this line, sources will not be generated.
	withSourcesJar()

	// If this mod is going to be a library, then it should also generate Javadocs in order to aid
	// with development. Uncomment this line to generate them.
	// withJavadocJar()
}