Prefer Pragmas to Pseudo Comments (#446)

* new check

* new check

* documentation

* exempting SLIN

* Adding example

Author: lucasborin

.cspell.json

@@ -51,7 +51,8 @@
     "msgid",
     "msgty",
     "msgno",
-    "UNDETEC"
+    "UNDETEC",
+    "SLIN"
   ],
   // flagWords - list of words to be always considered incorrect
   // This is useful for offensive words and common spelling errors.

changelog.txt

@@ -14,6 +14,7 @@ Whenever you upgrade code pal for ABAP, it is highly recommended to execute the
 
 2021-08-XX v.1.16.0
 ------------------
++ Prefer Pragmas to Pseudo Comments (#421)
 + COLLECT restriction (#441)
 * RAP needs CREATE OBJECT ... FOR TESTING (#444)
 

docs/check_documentation.md

@@ -47,6 +47,7 @@
 - [Prefer IS NOT to NOT IS](checks/prefer-is-not-to-not-is.md)
 - [Prefer LINE_EXISTS or LINE_INDEX to READ TABLE or LOOP AT](checks/prefer-line-exists.md)
 - [Prefer NEW to CREATE OBJECT](checks/prefer-new-to-create-object.md)
+- [Prefer Pragma to Pseudo Comment](checks/prefer-pragmas-to-pseudo-comments.md)
 - [Pseudo Comment Usage](checks/pseudo-comment-usage.md)
 - [Omit Optional EXPORTING](checks/omit-optional-exporting.md)
 - [Optional Parameters](checks/optional-parameters.md)

docs/checks/prefer-pragmas-to-pseudo-comments.md

@@ -0,0 +1,39 @@
+[code pal for ABAP](../../README.md) > [Documentation](../check_documentation.md) > [Prefer Pragmas to Pseudo Comments](prefer-pragmas-to-pseudo-comments.md)
+
+## Prefer Pragmas to Pseudo Comments
+
+### What is the Intent of the Check?
+
+Based on the [Clean ABAP](https://github.com/SAP/styleguides/blob/main/clean-abap/CleanABAP.md#prefer-pragmas-to-pseudo-comments):
+> Prefer pragmas to pseudo comments to suppress irrelevant warnings and errors identified by the ATC. Pseudo comments have mostly become obsolete and have been replaced by pragmas
+
+:bulb: Only the Pseudo Comments and Pragmas available in the `SLIN_DESC` table are in scope.
+
+:wan: Code Pal does not support Pragmas.
+
+### How to solve the issue?
+
+Change the `"#EC ` (Pseudo Comment) to `##` (Pragma).
+
+### What to do in case of exception?
+
+This Check cannot be exempt.
+
+### Example
+
+Before the check:
+
+```abap
+  DATA a TYPE string.   "#EC NEEDED
+```
+
+After the check:
+
+```abap
+  DATA a TYPE string.   ##NEEDED
+```
+
+### Further Readings & Knowledge
+
+* [Clean ABAP: Prefer pragmas to pseudo comments](https://github.com/SAP/styleguides/blob/main/clean-abap/CleanABAP.md#prefer-pragmas-to-pseudo-comments)
+* [ABAP - Keyword Documentation: Pseudo Comments for the Extended Program Check](https://help.sap.com/doc/abapdocu_752_index_htm/7.52/en-US/abenpseudo_comment_slin.htm)

src/checks/y_check_prefer_pragmas.clas.abap

@@ -0,0 +1,98 @@
+CLASS y_check_prefer_pragmas DEFINITION PUBLIC INHERITING FROM y_check_base CREATE PUBLIC .
+  PUBLIC SECTION.
+    METHODS constructor.
+
+  PROTECTED SECTION.
+    METHODS inspect_tokens REDEFINITION.
+
+  PRIVATE SECTION.
+    TYPES: BEGIN OF mapping,
+             pragma TYPE slin_desc-pragma,
+             pseudo_com TYPE slin_desc-pseudo_com,
+           END OF mapping.
+
+    CLASS-DATA mappings TYPE TABLE OF mapping.
+
+    METHODS extract_pseudo_comment IMPORTING statement TYPE sstmnt
+                                   RETURNING value(result)  TYPE string.
+
+    METHODS to_pragma IMPORTING pseudo_comment TYPE string
+                      RETURNING value(result)  TYPE string.
+
+ENDCLASS.
+
+
+
+CLASS y_check_prefer_pragmas IMPLEMENTATION.
+
+
+  METHOD constructor.
+    super->constructor( ).
+
+    settings-ignore_pseudo_comments = abap_true.
+    settings-disable_threshold_selection = abap_true.
+    settings-threshold = 0.
+    settings-documentation = |{ c_docs_path-checks }prefer-pragmas-to-pseudo-comments.md|.
+
+    IF mappings IS INITIAL.
+      SELECT pragma, pseudo_com FROM slin_desc INTO CORRESPONDING FIELDS OF TABLE @mappings.
+    ENDIF.
+
+    set_check_message( 'Change the &1 to &2' ).
+  ENDMETHOD.
+
+
+  METHOD inspect_tokens.
+    DATA(pseudo_comment) = extract_pseudo_comment( statement ).
+
+    IF pseudo_comment IS INITIAL.
+      RETURN.
+    ENDIF.
+
+    DATA(pragma) = to_pragma( pseudo_comment ).
+
+    IF pragma IS INITIAL.
+      RETURN.
+    ENDIF.
+
+    DATA(configuration) = detect_check_configuration( statement ).
+
+    IF configuration IS INITIAL.
+      RETURN.
+    ENDIF.
+
+    pragma = |##{ pragma }|.
+
+    raise_error( statement_level     = statement-level
+                 statement_index     = index
+                 statement_from      = statement-from
+                 error_priority      = configuration-prio
+                 parameter_01        = pseudo_comment
+                 parameter_02        = pragma ).
+  ENDMETHOD.
+
+
+  METHOD extract_pseudo_comment.
+    LOOP AT ref_scan_manager->tokens ASSIGNING FIELD-SYMBOL(<token>)
+    FROM statement-from TO statement-to
+    WHERE type = scan_token_type-comment.
+      IF <token>-str CS '"#EC'.
+        result = <token>-str.
+        RETURN.
+      ENDIF.
+    ENDLOOP.
+  ENDMETHOD.
+
+
+  METHOD to_pragma.
+    TRY.
+        DATA(text) = pseudo_comment.
+        REPLACE '"#EC' IN text WITH ''.
+        CONDENSE text.
+        result = mappings[ pseudo_com = text ]-pragma.
+      CATCH cx_sy_itab_line_not_found.
+        RETURN.
+    ENDTRY.
+  ENDMETHOD.
+
+ENDCLASS.

src/checks/y_check_prefer_pragmas.clas.testclasses.abap

@@ -0,0 +1,39 @@
+CLASS ltc_pseudo_comment DEFINITION INHERITING FROM y_unit_test_base FOR TESTING RISK LEVEL HARMLESS DURATION SHORT.
+  PROTECTED SECTION.
+    METHODS get_cut REDEFINITION.
+    METHODS get_code_with_issue REDEFINITION.
+    METHODS get_code_without_issue REDEFINITION.
+    METHODS get_code_with_exemption REDEFINITION.
+ENDCLASS.
+
+CLASS ltc_pseudo_comment IMPLEMENTATION.
+
+  METHOD get_cut.
+    result ?= NEW y_check_prefer_pragmas( ).
+  ENDMETHOD.
+
+  METHOD get_code_with_issue.
+    result = VALUE #(
+      ( ' REPORT y_example. ' )
+      ( '   START-OF-SELECTION.      ' )
+      ( '     DATA a TYPE string.   "#EC NEEDED ' )
+      ( '     DATA b TYPE string. ' )
+      ( '     a = b. ' )
+    ).
+  ENDMETHOD.
+
+  METHOD get_code_without_issue.
+    result = VALUE #(
+      ( ' REPORT y_example. ' )
+      ( '   START-OF-SELECTION.      ' )
+      ( '     DATA a TYPE string.   ##needed ' )
+      ( '     DATA b TYPE string. ' )
+      ( '     a = b. ' )
+    ).
+  ENDMETHOD.
+
+  METHOD get_code_with_exemption.
+    result = VALUE #( ).
+  ENDMETHOD.
+
+ENDCLASS.

src/checks/y_check_prefer_pragmas.clas.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="utf-8"?>
+<abapGit version="v1.0.0" serializer="LCL_OBJECT_CLAS" serializer_version="v1.0.0">
+ <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
+  <asx:values>
+   <VSEOCLASS>
+    <CLSNAME>Y_CHECK_PREFER_PRAGMAS</CLSNAME>
+    <LANGU>E</LANGU>
+    <DESCRIPT>Prefer Pragmas to Pseudo Comments</DESCRIPT>
+    <STATE>1</STATE>
+    <CLSCCINCL>X</CLSCCINCL>
+    <FIXPT>X</FIXPT>
+    <UNICODE>X</UNICODE>
+    <WITH_UNIT_TESTS>X</WITH_UNIT_TESTS>
+   </VSEOCLASS>
+  </asx:values>
+ </asx:abap>
+</abapGit>

src/examples/y_demo_failures.clas.abap

@@ -122,6 +122,7 @@ CLASS y_demo_failures DEFINITION PUBLIC FINAL CREATE PUBLIC.
     METHODS prefer_returning EXPORTING result TYPE string.
     METHODS text_assembly.
     METHODS collect.
+    METHODS prefer_pragmas.
 
   PRIVATE SECTION.
     DATA attribute_7 TYPE string.
@@ -511,4 +512,12 @@ CLASS Y_DEMO_FAILURES IMPLEMENTATION.
      COLLECT seats INTO seats_tab.
   ENDMETHOD.
 
+
+  METHOD prefer_pragmas.
+    TRY.
+        DATA(div_by_zero) = 1 / 0.
+      CATCH cx_root.               "#EC CATCH_ALL
+    ENDTRY.
+  ENDMETHOD.
+
 ENDCLASS.