build.gradle

plugins {
    id 'org.springframework.boot' version '3.2.2'
    id 'io.spring.dependency-management' version '1.1.4'
    id 'io.freefair.lombok' version '8.6'
    id 'java'
}

group 'com.vergiliusproject'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    mavenLocal()
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
}

dependencies {
    compileOnly 'org.springframework.boot:spring-boot-devtools'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'mysql:mysql-connector-java:8.0.33'

    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation('org.springframework:spring-core') {
        exclude module: 'commons-logging'
    }

    implementation 'de.neuland-bfi:pug4j:2.2.1-SNAPSHOT'
    implementation 'de.neuland-bfi:spring-pug4j:3.2.0'
    implementation 'org.apache.commons:commons-lang3:3.14.0'
    implementation 'org.apache.commons:commons-text:1.11.0'

    implementation 'org.yaml:snakeyaml:2.2'

    implementation 'org.hibernate.orm:hibernate-jcache:6.5.2.Final'
    implementation 'org.ehcache:ehcache:3.10.8:jakarta'

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.1'
    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.10.1'
    testImplementation 'org.junit.jupiter:junit-jupiter-params:5.10.1'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform {
        includeEngines 'junit-jupiter'
    }
}

bootRun {
    systemProperty "GIT_HASH", getCheckedOutGitCommitHash()
}

def getCheckedOutGitCommitHash() {  
    'git rev-parse --verify --short HEAD'.execute([], project.projectDir).text.trim()
}