forked from thargor6/mb3d
-
Notifications
You must be signed in to change notification settings - Fork 0
/
MemStream.pas
362 lines (313 loc) · 9.46 KB
/
MemStream.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
////////////////////////////////////////////////////////////////////////////////
//
// MemStream.pas - Seekable memory stream
// --------------------------------------
// Changed: 2003-06-11
// Maintain: Michael Vinther | mv@logicnet·dk
//
// Contains:
// (TBaseStream)
// (TSeekableStream)
// TMemStream
// TChunkWriteStream
// TMemBlockStream
// TChunkReadStream
//
// The memory buffer is a dynamic allocated linked list.
// It allows seek and write to the beginning of the stream without truncating it.
//
// Last changes:
// TMemBlockStream and TMemChunkStream added
unit MemStream;
interface
uses
Streams, SysUtils, Monitor;
resourcestring
rs_SeekMemError = 'Error moving stream pointer';
var
MemBlockSize : Integer = 1024*4; // Size of each block in chain
type
PMemBlock = ^TMemBlock;
TMemBlock = packed record
Size : Integer;
Next : PMemBlock;
Data : TByteArray;
end;
TMemStream = class(TSeekableStream)
protected
First, CurBlock : PMemBlock;
BlockPos : Integer;
fSize, fPosition : Integer;
procedure FreeChain(var Start: PMemBlock);
function GetPos: Integer; override;
function GetSize: Integer; override;
public
constructor Create;
destructor Destroy; override;
function Write(var Buf; Count: Integer): Integer; override;
function Read(var Buf; Count: Integer): Integer; override;
procedure Seek(Loc: Integer); override;
function Available: Integer; override;
// Reset stream, Size=0
procedure Reset;
// Truncate stream, Size=Position
procedure Truncate; override;
end;
TMemBlockStream = class(TSeekableStream)
protected
FSize, FPosition : Integer;
FData : PByteArray;
FOwnsData : Boolean;
function GetPos: Integer; override;
function GetSize: Integer; override;
public
constructor Create(Data: Pointer; Size: Integer=MaxInt; OwnsData: Boolean=False);
destructor Destroy; override;
function Write(var Buf; Count: Integer): Integer; override;
function Read(var Buf; Count: Integer): Integer; override;
procedure Seek(Loc: Integer); override;
function Available: Integer; override;
// Truncate stream, Size=Position
procedure Truncate; override;
property CanRead: boolean read fCanRead write fCanRead;
property CanWrite: boolean read fCanWrite write fCanWrite;
end;
// Stream for reading/writing a chunk in another stream
type
TChunkReadStream = class(TMemBlockStream)
public
// Read 32 bit size from Source if not specified
constructor Create(Source: TBaseStream; Size: Integer=-1);
end;
TChunkWriteStream = class(TMemStream)
protected
FDestStream : TBaseStream;
FIncludeSize : Boolean;
public
// Write size do Destination if IncludeSize=True
constructor Create(Destination: TBaseStream; IncludeSize: Boolean);
destructor Destroy; override;
end;
implementation
//=========================================================================================================
// TChunkReadStream
//=========================================================================================================
constructor TChunkReadStream.Create(Source: TBaseStream; Size: Integer=-1);
var
Data : Pointer;
begin
if Size=-1 then // Read size from Source
if Source.Read(Size,4)<>4 then raise EInOutError.CreateFmt(rs_ReadError,[ClassName]);
GetMem(Data,Size);
inherited Create(Data,Size,True);
if Source.Read(Data^,Size)<>Size then raise EInOutError.CreateFmt(rs_ReadError,[ClassName]);
end;
//=========================================================================================================
// TChunkWriteStream
//=========================================================================================================
constructor TChunkWriteStream.Create(Destination: TBaseStream; IncludeSize: Boolean);
begin
inherited Create;
FDestStream:=Destination;
FIncludeSize:=IncludeSize;
end;
destructor TChunkWriteStream.Destroy;
begin
if FIncludeSize then // Write size to FDestStream
FDestStream.Write(FSize,4);
Position:=0;
FDestStream.CopyFrom(Self);
inherited;
end;
//=========================================================================================================
// TMemStream
//=========================================================================================================
var NullBlock : TMemBlock;
constructor TMemStream.Create;
begin
inherited Create;
fCanRead:=True; fCanWrite:=True;
CurBlock:=@NullBlock;
end;
procedure TMemStream.FreeChain(var Start: PMemBlock);
var Block, P : PMemBlock;
begin
Block:=Start;
while Block<>nil do
begin
P:=Block;
Block:=Block^.Next;
FreeMem(P);
end;
Start:=nil;
end;
destructor TMemStream.Destroy;
begin
FreeChain(First);
inherited;
end;
function TMemStream.Available: integer;
begin
Available:=fSize-fPosition;
end;
function TMemStream.Read(var Buf; Count: Integer): Integer;
var Get : Integer;
begin
Result:=0;
while (Count>0) and (fPosition<fSize) do
begin
if BlockPos=CurBlock^.Size then // Go to next block
begin
if CurBlock^.Next=nil then Break // End of chain
else CurBlock:=CurBlock^.Next;
BlockPos:=0;
end;
Get:=Count;
if fPosition+Get>fSize then Get:=fSize-fPosition;
if Get>CurBlock^.Size-BlockPos then Get:=CurBlock^.Size-BlockPos;
Move(CurBlock^.Data[BlockPos],TByteArray(Buf)[Result],Get);
Inc(BlockPos,Get); Inc(Result,Get); Dec(Count,Get);
Inc(fPosition,Get);
end;
if NoDataExcept and (Count>0) then raise EInOutError.CreateFmt(rs_ReadError,[ClassName]);
end;
function TMemStream.Write(var Buf; Count: Integer): Integer;
var
Put, NewSize : Integer;
NewB : PMemBlock;
begin
Result:=0;
while Count>0 do
begin
if BlockPos=CurBlock^.Size then
begin
NewSize:=MemBlockSize;
if NewSize<Count then NewSize:=Count;
if CurBlock^.Next=nil then // Make new block
begin
GetMem(NewB,SizeOf(Integer)+SizeOf(PMemBlock)+NewSize);
NewB^.Size:=NewSize;
NewB^.Next:=nil;
if First=nil then First:=NewB // First block
else CurBlock^.Next:=NewB; // Add to end of chain
CurBlock:=NewB;
end
else // Reuse next block
begin
CurBlock:=CurBlock^.Next;
end;
BlockPos:=0;
end;
Put:=Count;
if Put>CurBlock^.Size-BlockPos then Put:=CurBlock^.Size-BlockPos;
Move(TByteArray(Buf)[Result],CurBlock^.Data[BlockPos],Put);
Inc(BlockPos,Put); Inc(Result,Put); Dec(Count,Put);
end;
Inc(fPosition,Result);
if fSize<fPosition then fSize:=fPosition;
end;
procedure TMemStream.Seek(Loc: Integer);
var Get : Integer;
begin
if Loc=fPosition then Exit;
if (Loc<0) or (Loc>fSize) then raise EInOutError.Create(rs_SeekMemError);
if Loc<fPosition then
begin
// Search from start
fPosition:=0;
CurBlock:=First; BlockPos:=0;
end;
// Search first block
if BlockPos=CurBlock^.Size then // Go to next block
begin
if CurBlock^.Next=nil then raise Exception.Create('Error in MemStream.Seek');
CurBlock:=CurBlock^.Next;
BlockPos:=0;
end;
Get:=Loc-fPosition;
if Get>CurBlock^.Size-BlockPos then Get:=CurBlock^.Size-BlockPos;
Inc(BlockPos,Get); Inc(fPosition,Get);
while fPosition<Loc do
begin
if CurBlock^.Next=nil then raise Exception.Create('Error in MemStream.Seek 2');
CurBlock:=CurBlock^.Next;
BlockPos:=Loc-fPosition;
if BlockPos>CurBlock^.Size then BlockPos:=CurBlock^.Size;
Inc(fPosition,BlockPos);
end;
end;
procedure TMemStream.Reset;
begin
FreeChain(First);
fSize:=0; fPosition:=0; CurBlock:=@NullBlock; BlockPos:=0;
end;
procedure TMemStream.Truncate;
begin
FreeChain(CurBlock.Next);
fSize:=fPosition;
end;
function TMemStream.GetPos: Integer;
begin
Result:=fPosition;
end;
function TMemStream.GetSize: Integer;
begin
Result:=fSize;
end;
//=========================================================================================================
// TMemBlockStream
//=========================================================================================================
constructor TMemBlockStream.Create(Data: Pointer; Size: Integer; OwnsData: Boolean);
begin
inherited Create;
fCanRead:=True; fCanWrite:=True;
FSize:=Size;
FOwnsData:=OwnsData;
FData:=Data;
end;
destructor TMemBlockStream.Destroy;
begin
inherited;
if Assigned(FData) and FOwnsData then FreeMem(FData);
end;
function TMemBlockStream.Available: Integer;
begin
Available:=fSize-fPosition;
end;
function TMemBlockStream.Read(var Buf; Count: Integer): Integer;
begin
Result:=FSize-FPosition;
if Result>Count then Result:=Count;
Move(FData^[FPosition],Buf,Result);
Inc(FPosition,Result);
if NoDataExcept and (Result<>Count) then raise EInOutError.CreateFmt(rs_ReadError,[ClassName]);
end;
function TMemBlockStream.Write(var Buf; Count: Integer): Integer;
begin
Result:=Count;
if Result>FSize-FPosition then raise EInOutError.CreateFmt(rs_WriteError,[ClassName]);
Move(Buf,FData^[FPosition],Result);
Inc(FPosition,Result);
end;
procedure TMemBlockStream.Seek(Loc: Integer);
begin
if (Loc<0) or (Loc>fSize) then raise EInOutError.Create(rs_SeekMemError);
FPosition:=Loc;
end;
procedure TMemBlockStream.Truncate;
begin
fSize:=fPosition;
end;
function TMemBlockStream.GetPos: Integer;
begin
Result:=fPosition;
end;
function TMemBlockStream.GetSize: Integer;
begin
Result:=fSize;
end;
//=========================================================================================================
initialization
NullBlock.Next:=nil;
NullBlock.Size:=0;
end.