webSIS.urs

(* Interacting with MIT's Web Student Information System *)

(* Goal: take a TSV file generated by WebSIS with student data and accordingly update a database table of users. *)
functor Make(M: sig
                 con others :: {Type}
                 constraint [Kerberos, MitId, UserName, IsStudent, IsListener, HasDropped, Units, SubjectNum, SectionNum, LastName, FirstName, MiddleInitial] ~ others

                 table user : ([Kerberos = string,
                                (* Kerberos username for MIT Athena *)
                                MitId = string,
                                (* Student ID *)
                                UserName = string,
                                (* Normal human name, in the form that will usually be displayed in the app *)
                                IsStudent = bool,
                                (* Currently enrolled in the class? *)
                                IsListener = bool,
                                (* Auditing? *)
                                HasDropped = bool,
                                (* Previously enrolled but since dropped? *)
                                Units = string,
                                (* Uninterpreted string from WebSIS, describing how many units of credit the student has signed up for *)
                                SubjectNum = string,
                                (* Uninterpreted string from WebSIS, describing which subject number the student is signed up via (matters for cross-listed subjects) *)
                                SectionNum = string,
                                (* Uninterpreted string from WebSIS, describing which section number the student is signed up for *)
                                LastName = string,
                                FirstName = string,
                                MiddleInitial = string
                                (* We need to echo these fields back to the Online Grades System eventually. *)]
                                   ++ others)

                 val defaults : $others
                 (* When importing a new student record, initialize remaining fields with these values. *)
                 val amAuthorized : transaction bool
                 (* Is the current user allowed to import records? *)
                 val expectedSubjectNumber : string
                 (* As a sanity check, we make sure the WebSIS data are for this subject number. *)

                 val fl : folder others
                 val inj : $(map sql_injectable others)
             end) : Ui.S0
(* The user interface is for copying and pasting the output of WebSIS's enrollment report that can be obtained from:
 * WebSIS front page (http://websis.mit.edu/)
 * -> for Instructors and Departmental Administrators
 * -> Registered Student Class Lists (or Pre-registration Class Lists, before the semester starts)
 * -> ClassList Download (which masquerades as an Excel file but is really just TSV) *)