-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathseparation.v
207 lines (187 loc) · 7.76 KB
/
separation.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
Require Import Coq.Strings.String.
From mathcomp Require Import ssreflect ssrfun ssrbool ssrnat eqtype.
From deriving Require Import deriving.
From extructures Require Import ord fset fmap ffun fperm.
From CoqUtils Require Import nominal.
From memsafe Require Import basic structured.
Set Implicit Arguments.
Unset Strict Implicit.
Unset Printing Implicit Defensive.
Section Separation.
Local Open Scope fset_scope.
Local Open Scope state_scope.
Local Notation locals := {fmap string -> value}.
Local Notation heap := {fmap ptr -> value}.
Local Notation state := (locals * heap)%type.
Implicit Type (e : expr) (c : com) (ls : locals) (h : heap)
(s : state) (π : {fperm name}) (v : value)
(P Q R : state -> Prop).
Definition triple P c Q :=
forall s k, fsubset (vars_c c) (domm s.1) ->
P s ->
match eval_com c s k with
| Done rs' => pbindr fset0 Q rs'
| Error => False
| NotYet => True
end.
Definition separating_conjunction P Q s :=
exists ls h1 h2,
[/\ s = (ls, unionm h1 h2),
P (ls, h1),
Q (ls, h2) &
fdisjoint (names (domm h1)) (names (domm h2)) ].
Local Infix "*" := separating_conjunction.
Definition ind_vars (xs : {fset string}) P :=
forall s s', P s ->
(forall x, x \notin xs -> s.1 x = s'.1 x) ->
s.2 = s'.2 ->
P s'.
Lemma sc_lift P Q A ls h1 h2 :
pbindr fset0 P (hide A (Restr (ls, h1))) ->
pbindr fset0 Q (hide A (Restr (ls, h2))) ->
fdisjoint (names (domm h1)) (names (domm h2)) ->
pbindr fset0 (P * Q) (hide A (Restr (ls, unionm h1 h2))).
Proof.
move=> Ph1 Qh2 dis A12 /= s /restr_eqP /= [π ids_π [eA es]] _.
move: ids_π.
rewrite fsetDUl /= namesm_union_disjoint ?fdisjoint_names_domm //.
rewrite (fsetDUl (names h1)) -[names ls :\: A]fsetUid -fsetUA.
rewrite [in X in _ :|: X]fsetUC 2!fsetUA -fsetUA (fsetUC (names h2 :\: A)).
rewrite -2!fsetDUl -(namespE (ls, h1)) -(namespE (ls, h2)) fdisjointUr.
case/andP=> [dis_π1 dis_π2].
exists (rename π ls), (rename π h1), (rename π h2).
rewrite -es pair_eqvar unionm_eqvar; split=> //.
- apply: (Ph1 (rename π A)); last exact: fdisjoint0s.
rewrite -[LHS](@renameJ _ π) ?names_hider ?namesrE //.
by rewrite hide_eqvar Restr_eqvar pair_eqvar.
- apply: (Qh2 (rename π A)); last exact: fdisjoint0s.
rewrite -[LHS](@renameJ _ π) ?names_hider ?namesrE //.
by rewrite hide_eqvar Restr_eqvar pair_eqvar.
by rewrite -![domm (rename _ _)]domm_eqvar -fdisjoint_eqvar renameT.
Qed.
Lemma frame_rule P Q R c :
triple P c Q ->
ind_vars (mod_vars_c c) R ->
triple (P * R) c (Q * R).
Proof.
move=> t ind s k sub [ls [h1 [h2 [e ph1 ph2 dis]]]].
rewrite {}e {s} in sub *.
move/(_ (ls, h1) k sub ph1): t.
rewrite -{2}[ls]unionm0.
case ev: (eval_com c (ls, h1) k)=> [rs'| |] //=; first last.
by rewrite (@frame_loop _ (ls, h1) (emptym, h2)).
move=> Q_rs'; rewrite (@frame_ok _ (ls, h1) (emptym, h2) _ _ sub dis ev).
case: rs' / (restrP (names (ls, h1) :|: names ((emptym, h2) : state)) rs')
Q_rs' ev => /= A [ls' h1'] dis'' sub' Q_rs' ev.
move: dis''; rewrite fdisjointUl=> /andP [dis1 dis2].
rewrite maprE // /stateu unionm0.
rewrite namespE /= namesm_empty fset0U in dis2.
apply: sc_lift=> //.
move=> /= A' s2' /restr_eqP [π].
rewrite namespE fsetDUl /= (fsetDidPl dis2) fdisjointUr.
case/andP=> dis_ls' dis_h2.
rewrite pair_eqvar /= (renameJ dis_h2) => - [eA <-] _.
apply/ind; eauto=> /= x nin_x.
move: (mod_vars_cP ev nin_x); rewrite maprE ?fdisjoint0s //=.
move/(congr1 (@oexpose _)); rewrite oexposeE oexposeE0.
case: ifP=> // dis''' [<-].
rewrite renamemE renameT renameJ // fdisjointC.
rewrite fdisjointC in dis_ls'.
apply/fdisjoint_trans; eauto.
apply/fsubsetP=> /= i in_i; apply/fsetDP; split.
case e: getm in_i=> [v|]; try by rewrite in_fset0.
move=> in_i; apply/namesmP/@PMFreeNamesVal; eauto.
by move: i in_i; apply/fdisjointP; rewrite fdisjointC.
have := @eval_com_blocks _ (ls, h1) c k dis.
rewrite ev pbind_resE /=.
have: fdisjoint (names (domm h2)) A.
by apply: fdisjoint_trans dis2; eapply nom_finsuppP; finsupp.
move: (names (domm h2)) => A' disA'.
by rewrite pbindrE //= namesfsnE.
Qed.
Definition weak_triple P c Q :=
forall s k,
fsubset (vars_c c) (domm s.1) ->
P s ->
if eval_com c s k is Done rs' then
pbindr fset0 Q rs'
else True.
Definition strong_separating_conjunction P Q s :=
exists ls h1 h2,
[/\ s = (ls, unionm h1 h2),
P (ls, h1),
Q (ls, h2) &
fdisjoint (names (ls, h1)) (names (domm h2)) ].
Local Infix "*>" := strong_separating_conjunction (at level 20).
Lemma ssc_lift P Q A ls h1 h2 :
pbindr fset0 P (hide A (Restr (ls, h1))) ->
pbindr fset0 Q (hide A (Restr (ls, h2))) ->
fdisjoint (names (ls, h1)) (names (domm h2)) ->
pbindr fset0 (P *> Q) (hide A (Restr (ls, unionm h1 h2))).
Proof.
move=> Ph1 Qh2 dis A12 /= s /restr_eqP /= [π ids_π [eA es]] _.
move: ids_π.
rewrite fsetDUl /= namesm_union_disjoint ?fdisjoint_names_domm //; last first.
suffices h : fsubset (names (domm h1)) (names (ls, h1)).
by apply: fdisjoint_trans; eauto.
by rewrite fsubsetU //= [_ _ (names h1)]fsubsetU ?orbT ?fsubsetxx.
rewrite (fsetDUl (names h1)) -[names ls :\: A]fsetUid -fsetUA.
rewrite [in X in _ :|: X]fsetUC 2!fsetUA -fsetUA (fsetUC (names h2 :\: A)).
rewrite -2!fsetDUl -(namespE (ls, h1)) -(namespE (ls, h2)) fdisjointUr.
case/andP=> [dis_π1 dis_π2].
exists (rename π ls), (rename π h1), (rename π h2).
rewrite -es pair_eqvar unionm_eqvar; split=> //.
- apply: (Ph1 (rename π A)); last exact: fdisjoint0s.
rewrite -[LHS](@renameJ _ π) ?names_hider ?namesrE //.
by rewrite hide_eqvar Restr_eqvar pair_eqvar.
- apply: (Qh2 (rename π A)); last exact: fdisjoint0s.
rewrite -[LHS](@renameJ _ π) ?names_hider ?namesrE //.
by rewrite hide_eqvar Restr_eqvar pair_eqvar.
by rewrite -![domm (rename _ _)]domm_eqvar -fdisjoint_eqvar renameT.
Qed.
Lemma weak_frame_rule P Q R c :
weak_triple P c Q ->
ind_vars (mod_vars_c c) R ->
weak_triple (P *> R) c (Q *> R).
Proof.
move=> t ind s k sub [ls [h1 [h2 [e ph1 ph2 dis]]]].
rewrite {}e {s} in sub *.
move/(_ (ls, h1) k sub ph1): t.
rewrite -{2}[ls]unionm0.
have dis': fdisjoint (names (domm h1)) (names (domm h2)).
move: dis; rewrite fdisjointUl=> /andP [_] /=.
by rewrite fdisjointUl=> /andP [].
case ev: (eval_com c (ls, h1) k)=> [rs'| |] //=; first last.
- by rewrite (@frame_loop _ (ls, h1) (emptym, h2)).
- by rewrite (@frame_error _ (ls, h1) (emptym, h2)).
move=> Q_rs'; rewrite (@frame_ok _ (ls, h1) (emptym, h2) _ _ sub dis' ev).
case: rs' / (restrP (names (ls, h1) :|: names ((emptym, h2) : state)) rs')
Q_rs' ev => /= A [ls' h1'] dis'' sub' Q_rs' ev.
move: dis''; rewrite fdisjointUl=> /andP [dis1 dis2].
rewrite maprE // /stateu unionm0.
rewrite namespE /= namesm_empty fset0U in dis2.
apply: ssc_lift=> //.
move=> /= A' s2' /restr_eqP [π].
rewrite namespE fsetDUl /= (fsetDidPl dis2) fdisjointUr.
case/andP=> dis_ls' dis_h2.
rewrite pair_eqvar /= (renameJ dis_h2) => - [eA <-] _.
apply/ind; eauto=> /= x nin_x.
move: (mod_vars_cP ev nin_x); rewrite maprE ?fdisjoint0s //=.
move/(congr1 (@oexpose _)); rewrite oexposeE oexposeE0.
case: ifP=> // dis''' [<-].
rewrite renamemE renameT renameJ // fdisjointC.
rewrite fdisjointC in dis_ls'.
apply/fdisjoint_trans; eauto.
apply/fsubsetP=> /= i in_i; apply/fsetDP; split.
case e: getm in_i=> [v|]; try by rewrite in_fset0.
move=> in_i; apply/namesmP/@PMFreeNamesVal; eauto.
by move: i in_i; apply/fdisjointP; rewrite fdisjointC.
have: fsubset (names (eval_com c (ls, h1) k)) (names (ls, h1)).
eapply nom_finsuppP; finsupp.
rewrite ev namesresE names_hider namesrE fsubDset fsetUC => ?.
apply: fdisjoint_trans; first eauto.
rewrite fdisjointUl dis fdisjointC.
apply: fdisjoint_trans; eauto.
by eapply nom_finsuppP; finsupp.
Qed.
End Separation.