build.gradle.kts

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

val kotlinVersion = "1.2.70"
val log4jVersion = "2.17.2"

plugins {
    id("com.atlassian.performance.tools.gradle-release").version("0.10.0")
    kotlin("jvm").version("1.4.32")
    `java-library`
}

tasks.withType<KotlinCompile> {
    kotlinOptions {
        jvmTarget = "1.8"
        languageVersion = "1.4"
        languageVersion = "1.2" // the maximum, which still produces 1.1.x metadata required by 1.2.70 kotlin clients
    }
}

configurations.all {
    if (name.startsWith("kotlin") || name.startsWith("dokka")) {
        return@all
    }
    resolutionStrategy {
        activateDependencyLocking()
        failOnVersionConflict()
        eachDependency {
            when (requested.module.toString()) {
                "com.google.guava:guava" -> useVersion("25.0-jre") // conflict between infrastructure, virtual-users and jira-actions
                "org.apache.httpcomponents:httpclient" -> useVersion("4.5.13")
                "com.fasterxml.jackson.core:jackson-core" -> useVersion("2.9.4")
                "org.slf4j:slf4j-api" -> useVersion("1.8.0-alpha2")
                "org.apache.httpcomponents:httpcore" -> useVersion("4.4.9")
                "commons-logging:commons-logging" -> useVersion("1.2")
                "org.codehaus.plexus:plexus-utils" -> useVersion("3.1.0")
                "com.google.code.gson:gson" -> useVersion("2.8.2")
                "org.jsoup:jsoup" -> useVersion("1.10.2")
                "com.jcraft:jzlib" -> useVersion("1.1.3")
            }
            when (requested.group) {
                "org.jetbrains.kotlin" -> useVersion(kotlinVersion)
                "org.apache.logging.log4j" -> useVersion(log4jVersion)
            }
        }
    }
}

dependencies {
    api("com.atlassian.performance.tools:infrastructure:[4.19.0, 5.0.0)")
    api("com.atlassian.performance.tools:aws-resources:[1.17.0, 2.0.0)") // 1.17 avoids javax:activation dependency (and its license problem)
    api("com.atlassian.performance.tools:jira-actions:[2.0.0, 4.0.0)")
    api("com.atlassian.performance.tools:ssh:[2.4.1, 3.0.0)")
    api("com.atlassian.performance.tools:virtual-users:[3.3.0, 4.0.0)")
    api("com.amazonaws:aws-java-sdk-ec2:1.11.817")

    implementation("com.atlassian.performance.tools:jvm-tasks:[1.3.0, 2.0.0)") // 1.3.0 gives TaskScope and EventBus
    implementation("com.atlassian.performance.tools:workspace:[2.0.0, 3.0.0)")
    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlinVersion")
    implementation("org.glassfish:javax.json:1.1")
    implementation("com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.9.4")
    implementation("com.atlassian.performance.tools:concurrency:[1.2.0, 2.0.0)")
    listOf("api", "core", "slf4j-impl").forEach { implementation("org.apache.logging.log4j:log4j-$it:$log4jVersion") }

    testImplementation("junit:junit:4.12")
    testImplementation("org.assertj:assertj-core:3.11.1")
    testImplementation("org.hamcrest:hamcrest-library:1.3")
}

tasks.test {
    filter {
        exclude("**/*IT.class")
    }
}

val testIntegration = task<Test>("testIntegration") {
    filter {
        include("**/*IT.class")
    }
    maxParallelForks = 5
}

tasks.check {
    dependsOn(testIntegration)
}

tasks.wrapper {
    gradleVersion = "7.6.3"
    distributionType = Wrapper.DistributionType.ALL
}