Remove VFS functionality (which we never used) and replace it with the explicit Swift module JSON file supported by Swift 5.6 (but not enabled on any toolchain yet).

This file is actually supported in earlier versions of Swift, but 5.6 is the first version where it doesn't require *all* modules (i.e., system modules) to be specified explicitly as well.

PiperOrigin-RevId: 456822150

Author: allevato

swift/internal/BUILD

@@ -43,12 +43,12 @@ bzl_library(
     deps = [
         ":action_names",
         ":actions",
+        ":explicit_module_map_file",
         ":feature_names",
         ":features",
         ":module_maps",
         ":providers",
         ":utils",
-        ":vfsoverlay",
         ":wmo",
         "@bazel_skylib//lib:paths",
         "@bazel_skylib//lib:sets",
@@ -67,6 +67,11 @@ bzl_library(
     ],
 )
 
+bzl_library(
+    name = "explicit_module_map_file",
+    srcs = ["explicit_module_map_file.bzl"],
+)
+
 bzl_library(
     name = "feature_names",
     srcs = ["feature_names.bzl"],
@@ -186,11 +191,6 @@ bzl_library(
     ],
 )
 
-bzl_library(
-    name = "vfsoverlay",
-    srcs = ["vfsoverlay.bzl"],
-)
-
 bzl_library(
     name = "wmo",
     srcs = ["wmo.bzl"],

swift/internal/compiling.bzl

@@ -23,6 +23,7 @@ load(
     "SWIFT_ACTION_PRECOMPILE_C_MODULE",
 )
 load(":actions.bzl", "is_action_enabled", "run_toolchain_action")
+load(":explicit_module_map_file.bzl", "write_explicit_swift_module_map_file")
 load(
     ":feature_names.bzl",
     "SWIFT_FEATURE_EMIT_C_MODULE",
@@ -31,7 +32,7 @@ load(
     "SWIFT_FEATURE_OPT",
     "SWIFT_FEATURE_OPT_USES_WMO",
     "SWIFT_FEATURE_SUPPORTS_LIBRARY_EVOLUTION",
-    "SWIFT_FEATURE_VFSOVERLAY",
+    "SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP",
     "SWIFT_FEATURE__NUM_THREADS_1_IN_SWIFTCOPTS",
     "SWIFT_FEATURE__WMO_IN_SWIFTCOPTS",
 )
@@ -57,13 +58,8 @@ load(
     "owner_relative_path",
     "struct_fields",
 )
-load(":vfsoverlay.bzl", "write_vfsoverlay")
 load(":wmo.bzl", "find_num_threads_flag_value", "is_wmo_manually_requested")
 
-# VFS root where all .swiftmodule files will be placed when
-# SWIFT_FEATURE_VFSOVERLAY is enabled.
-_SWIFTMODULES_VFS_ROOT = "/__build_bazel_rules_swift/swiftmodules"
-
 def _module_name_safe(string):
     """Returns a transformation of `string` that is safe for module names."""
     result = ""
@@ -275,30 +271,29 @@ def compile(
                 sets.make(swift_module.defines),
             )
 
-    # We need this when generating the VFS overlay file and also when
-    # configuring inputs for the compile action, so it's best to precompute it
-    # here.
     if is_feature_enabled(
         feature_configuration = feature_configuration,
-        feature_name = SWIFT_FEATURE_VFSOVERLAY,
+        feature_name = SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP,
     ):
-        vfsoverlay_file = actions.declare_file(
-            "{}.vfsoverlay.yaml".format(target_name),
+        # Generate the JSON file that contains the manifest of Swift
+        # dependencies.
+        explicit_swift_module_map_file = actions.declare_file(
+            "{}.swift-explicit-module-map.json".format(target_name),
         )
-        write_vfsoverlay(
+        write_explicit_swift_module_map_file(
             actions = actions,
-            swiftmodules = transitive_swiftmodules,
-            vfsoverlay_file = vfsoverlay_file,
-            virtual_swiftmodule_root = _SWIFTMODULES_VFS_ROOT,
+            explicit_swift_module_map_file = explicit_swift_module_map_file,
+            module_contexts = transitive_modules,
         )
     else:
-        vfsoverlay_file = None
+        explicit_swift_module_map_file = None
 
     prerequisites = struct(
         additional_inputs = additional_inputs,
         bin_dir = feature_configuration._bin_dir,
         cc_compilation_context = merged_compilation_context,
         defines = sets.to_list(defines_set),
+        explicit_swift_module_map_file = explicit_swift_module_map_file,
         genfiles_dir = feature_configuration._genfiles_dir,
         is_swift = True,
         module_name = module_name,
@@ -307,8 +302,6 @@ def compile(
         transitive_modules = transitive_modules,
         transitive_swiftmodules = transitive_swiftmodules,
         user_compile_flags = copts,
-        vfsoverlay_file = vfsoverlay_file,
-        vfsoverlay_search_path = _SWIFTMODULES_VFS_ROOT,
         # Merge the compile outputs into the prerequisites.
         **struct_fields(compile_outputs)
     )

swift/internal/explicit_module_map_file.bzl

@@ -0,0 +1,50 @@
+# Copyright 2022 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+"""Generates the JSON manifest used to pass Swift modules to the compiler."""
+
+def write_explicit_swift_module_map_file(
+        *,
+        actions,
+        explicit_swift_module_map_file,
+        module_contexts):
+    """Generates the JSON-formatted explicit module map file.
+
+    This file is a manifest that contains the path information for all the
+    Swift modules from dependencies that are needed to compile a particular
+    module.
+
+    Args:
+        actions: The object used to register actions.
+        explicit_swift_module_map_file: A `File` to which the generated JSON
+            will be written.
+        module_contexts: A list of module contexts that provide the Swift
+            dependencies for the compilation.
+    """
+    module_descriptions = []
+
+    for module_context in module_contexts:
+        if not module_context.swift:
+            continue
+
+        swift_context = module_context.swift
+        module_description = {"moduleName": module_context.name}
+        if swift_context.swiftmodule:
+            module_description["modulePath"] = swift_context.swiftmodule.path
+        module_descriptions.append(module_description)
+
+    actions.write(
+        content = json.encode(module_descriptions),
+        output = explicit_swift_module_map_file,
+    )

swift/internal/feature_names.bzl

@@ -129,6 +129,10 @@ SWIFT_FEATURE_REWRITE_GENERATED_HEADER = "swift.rewrite_generated_header"
 # them.
 SWIFT_FEATURE_USE_C_MODULES = "swift.use_c_modules"
 
+# If enabled, Swift modules for dependencies will be passed to the compiler
+# using a JSON file instead of `-I` search paths.
+SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP = "swift.use_explicit_swift_module_map"
+
 # If enabled, Swift compilation actions will use the same global Clang module
 # cache used by Objective-C compilation actions. This is disabled by default
 # because under some circumstances Clang module cache corruption can cause the
@@ -149,13 +153,6 @@ SWIFT_FEATURE_USE_OLD_DRIVER = "swift.use_old_driver"
 # using a sufficiently recent version of Swift (4.2 or higher).
 SWIFT_FEATURE_USE_RESPONSE_FILES = "swift.use_response_files"
 
-# If enabled, Swift compilation actions will create a virtual file system
-# overlay containing all its dependencies' `.swiftmodule` files and use that
-# overlay as its sole search path. This improves build performance by avoiding
-# worst-case O(N^2) search (N modules, each in its own subdirectory), especially
-# when access to those paths involves traversing a networked file system.
-SWIFT_FEATURE_VFSOVERLAY = "swift.vfsoverlay"
-
 # If enabled, builds using the "dbg" compilation mode will explicitly disable
 # swiftc from producing swiftmodules containing embedded file paths, which are
 # inherently non-portable across machines.

swift/internal/vfsoverlay.bzl

@@ -45,9 +45,9 @@ load(
     "SWIFT_FEATURE_SUPPORTS_SYSTEM_MODULE_FLAG",
     "SWIFT_FEATURE_SYSTEM_MODULE",
     "SWIFT_FEATURE_USE_C_MODULES",
+    "SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP",
     "SWIFT_FEATURE_USE_GLOBAL_MODULE_CACHE",
     "SWIFT_FEATURE_USE_OLD_DRIVER",
-    "SWIFT_FEATURE_VFSOVERLAY",
     "SWIFT_FEATURE__NUM_THREADS_1_IN_SWIFTCOPTS",
     "SWIFT_FEATURE__WMO_IN_SWIFTCOPTS",
 )
@@ -451,22 +451,24 @@ def compile_action_configs(
         ),
     ]
 
-    #### Search paths for Swift module dependencies
+    #### Search paths/explicit module map for Swift module dependencies
     action_configs.extend([
         ActionConfigInfo(
-            actions = [
-                SWIFT_ACTION_COMPILE,
-                SWIFT_ACTION_SYMBOL_GRAPH_EXTRACT,
-            ],
-            configurators = [_dependencies_swiftmodules_configurator],
-            not_features = [SWIFT_FEATURE_VFSOVERLAY],
+            actions = [SWIFT_ACTION_COMPILE],
+            configurators = [_explicit_swift_module_map_configurator],
+            features = [SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP],
         ),
         ActionConfigInfo(
             actions = [SWIFT_ACTION_COMPILE],
-            configurators = [
-                _dependencies_swiftmodules_vfsoverlay_configurator,
-            ],
-            features = [SWIFT_FEATURE_VFSOVERLAY],
+            configurators = [_dependencies_swiftmodules_configurator],
+            not_features = [SWIFT_FEATURE_USE_EXPLICIT_SWIFT_MODULE_MAP],
+        ),
+
+        # swift-symbolgraph-extract doesn't yet support explicit Swift module
+        # maps.
+        ActionConfigInfo(
+            actions = [SWIFT_ACTION_SYMBOL_GRAPH_EXTRACT],
+            configurators = [_dependencies_swiftmodules_configurator],
         ),
     ])
 
@@ -1050,20 +1052,19 @@ def _dependencies_swiftmodules_configurator(prerequisites, args):
         inputs = prerequisites.transitive_swiftmodules,
     )
 
-def _dependencies_swiftmodules_vfsoverlay_configurator(prerequisites, args):
-    """Provides a single `.swiftmodule` search path using a VFS overlay."""
-    swiftmodules = prerequisites.transitive_swiftmodules
-
-    # Bug: `swiftc` doesn't pass its `-vfsoverlay` arg to the frontend.
-    # Workaround: Pass `-vfsoverlay` directly via `-Xfrontend`.
-    args.add(
-        "-Xfrontend",
-        "-vfsoverlay{}".format(prerequisites.vfsoverlay_file.path),
+def _explicit_swift_module_map_configurator(prerequisites, args):
+    """Adds the explicit Swift module map file to the command line."""
+    args.add_all(
+        [
+            "-explicit-swift-module-map-file",
+            prerequisites.explicit_swift_module_map_file,
+        ],
+        before_each = "-Xfrontend",
     )
-    args.add("-I{}".format(prerequisites.vfsoverlay_search_path))
-
     return ConfigResultInfo(
-        inputs = swiftmodules + [prerequisites.vfsoverlay_file],
+        inputs = prerequisites.transitive_swiftmodules + [
+            prerequisites.explicit_swift_module_map_file,
+        ],
     )
 
 def _module_name_configurator(prerequisites, args):