Add feature for partially explicit modules

As of Swift 5.6 and this PR swiftlang/swift#39887
the new json format used for entirely explicit module builds can be used
without entirely disabling implicit modules. This provides an
alternative to VFS overlays for discovering dependencies without `-I`
search paths. This is theoretically about the same but I expect this
file format to have better support in general than VFS overlays for
things like the new incremental compilation support, which currently
doesn't support VFS overlays, and this shouldn't have any downsides vs
VFS files.

This format does support some more keys than just the 2 we pass, as far
as I can tell they are unused today, so I'm opting not to pass them. We
may have to revisit this in the future.

Author: keith

swift/internal/compiling.bzl

@@ -53,6 +53,7 @@ load(
     "SWIFT_FEATURE_OPT",
     "SWIFT_FEATURE_OPT_USES_OSIZE",
     "SWIFT_FEATURE_OPT_USES_WMO",
+    "SWIFT_FEATURE_PARTIALLY_EXPLICIT_MODULES",
     "SWIFT_FEATURE_REWRITE_GENERATED_HEADER",
     "SWIFT_FEATURE_SPLIT_DERIVED_FILES_GENERATION",
     "SWIFT_FEATURE_SUPPORTS_LIBRARY_EVOLUTION",
@@ -90,7 +91,7 @@ load(
     "get_providers",
     "struct_fields",
 )
-load(":vfsoverlay.bzl", "write_vfsoverlay")
+load(":vfsoverlay.bzl", "write_explicit_module_map", "write_vfsoverlay")
 
 # VFS root where all .swiftmodule files will be placed when
 # SWIFT_FEATURE_VFSOVERLAY is enabled.
@@ -725,7 +726,10 @@ def compile_action_configs(
                 swift_action_names.DUMP_AST,
             ],
             configurators = [_dependencies_swiftmodules_configurator],
-            not_features = [SWIFT_FEATURE_VFSOVERLAY],
+            not_features = [
+                [SWIFT_FEATURE_VFSOVERLAY],
+                [SWIFT_FEATURE_PARTIALLY_EXPLICIT_MODULES],
+            ],
         ),
         swift_toolchain_config.action_config(
             actions = [
@@ -738,6 +742,17 @@ def compile_action_configs(
             ],
             features = [SWIFT_FEATURE_VFSOVERLAY],
         ),
+        swift_toolchain_config.action_config(
+            actions = [
+                swift_action_names.COMPILE,
+                swift_action_names.DERIVE_FILES,
+                swift_action_names.DUMP_AST,
+            ],
+            configurators = [
+                _explicit_module_map_configurator,
+            ],
+            features = [SWIFT_FEATURE_PARTIALLY_EXPLICIT_MODULES],
+        ),
     ])
 
     #### Search paths for framework dependencies
@@ -1425,6 +1440,17 @@ def _dependencies_swiftmodules_vfsoverlay_configurator(prerequisites, args):
         inputs = swiftmodules + [prerequisites.vfsoverlay_file],
     )
 
+def _explicit_module_map_configurator(prerequisites, args):
+    """Configures a explicit swiftmodule map file for compilation"""
+    swiftmodules = prerequisites.transitive_swiftmodules
+
+    args.add("-Xfrontend", "-explicit-swift-module-map-file")
+    args.add("-Xfrontend", prerequisites.explicit_module_file.path)
+
+    return swift_toolchain_config.config_result(
+        inputs = swiftmodules + [prerequisites.explicit_module_file],
+    )
+
 def _module_name_configurator(prerequisites, args):
     """Adds the module name flag to the command line."""
     args.add("-module-name", prerequisites.module_name)
@@ -1815,11 +1841,31 @@ def compile(
     else:
         vfsoverlay_file = None
 
+    if is_feature_enabled(
+        feature_configuration = feature_configuration,
+        feature_name = SWIFT_FEATURE_PARTIALLY_EXPLICIT_MODULES,
+    ):
+        explicit_module_file = derived_files.explicit_module_map(
+            actions = actions,
+            target_name = target_name,
+        )
+        write_explicit_module_map(
+            actions = actions,
+            swiftmodules = transitive_swiftmodules,
+            output_file = explicit_module_file,
+        )
+    else:
+        explicit_module_file = None
+
+    if vfsoverlay_file and explicit_module_file:
+        fail("VFS overlays cannot be used with explicit modules")
+
     prerequisites = struct(
         additional_inputs = additional_inputs,
         bin_dir = feature_configuration._bin_dir,
         cc_compilation_context = merged_providers.cc_info.compilation_context,
         defines = sets.to_list(defines_set),
+        explicit_module_file = explicit_module_file,
         genfiles_dir = feature_configuration._genfiles_dir,
         is_swift = True,
         module_name = module_name,

swift/internal/derived_files.bzl

@@ -294,6 +294,23 @@ def _vfsoverlay(actions, target_name):
     """
     return actions.declare_file("{}.vfsoverlay.yaml".format(target_name))
 
+def _explicit_module_map(actions, target_name):
+    """Declares a file for the explicit module map confoiguration for a
+    compilation action.
+
+    The explicit module map file is JSON-formatted file that allows us to place
+    the `.swiftmodule` files for all dependencies into a single file used for
+    lookup instead of discovering them through search paths.
+
+    Args:
+        actions: The context's actions object.
+        target_name: The name of the target being built.
+
+    Returns:
+        The declared `File`.
+    """
+    return actions.declare_file("{}.explicitmodulemap.json".format(target_name))
+
 def _whole_module_object_file(actions, target_name):
     """Declares a file for object files created with whole module optimization.
 
@@ -326,6 +343,7 @@ derived_files = struct(
     ast = _ast,
     autolink_flags = _autolink_flags,
     executable = _executable,
+    explicit_module_map = _explicit_module_map,
     indexstore_directory = _indexstore_directory,
     intermediate_bc_file = _intermediate_bc_file,
     intermediate_object_file = _intermediate_object_file,
@@ -334,8 +352,8 @@ derived_files = struct(
     precompiled_module = _precompiled_module,
     reexport_modules_src = _reexport_modules_src,
     static_archive = _static_archive,
-    swiftc_output_file_map = _swiftc_output_file_map,
     swiftc_derived_output_file_map = _swiftc_derived_output_file_map,
+    swiftc_output_file_map = _swiftc_output_file_map,
     swiftdoc = _swiftdoc,
     swiftinterface = _swiftinterface,
     swiftmodule = _swiftmodule,

swift/internal/feature_names.bzl

@@ -202,6 +202,11 @@ SWIFT_FEATURE_USE_RESPONSE_FILES = "swift.use_response_files"
 # when access to those paths involves traversing a networked file system.
 SWIFT_FEATURE_VFSOVERLAY = "swift.vfsoverlay"
 
+# If enabled, Swift compilation actions will use a explicit module map file for
+# discovering dependencies. This is faster than using search paths when you
+# have many dependencies. This doesn't apply to system dependencies.
+SWIFT_FEATURE_PARTIALLY_EXPLICIT_MODULES = "swift.partially_explicit_modules"
+
 # If enabled, builds using the "dbg" compilation mode will explicitly disable
 # swiftc from producing swiftmodules containing embedded file paths, which are
 # inherently non-portable across machines.

swift/internal/vfsoverlay.bzl

@@ -62,3 +62,27 @@ def write_vfsoverlay(
         content = vfsoverlay_yaml,
         output = vfsoverlay_file,
     )
+
+def write_explicit_module_map(
+        actions,
+        swiftmodules,
+        output_file):
+    """Generates a explicit module map and writes it to a file.
+
+    Args:
+        actions: The object used to register actions.
+        swiftmodules: The `list` of transitive `.swiftmodule` dependencies.
+        output_file: A `File` to write the output to.
+    """
+    virtual_swiftmodules = [
+        {
+            "moduleName": swiftmodule.basename.rsplit(".", 1)[0],
+            "modulePath": swiftmodule.path,
+        }
+        for swiftmodule in swiftmodules
+    ]
+
+    actions.write(
+        content = json.encode(virtual_swiftmodules),
+        output = output_file,
+    )