forked from techsneeze/dmarcts-report-parser
-
Notifications
You must be signed in to change notification settings - Fork 0
/
dmarcts-report-parser.pl
executable file
·821 lines (726 loc) · 27.2 KB
/
dmarcts-report-parser.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
#!/usr/bin/perl
################################################################################
# dmarcts-report-parser - A Perl based tool to parse DMARC reports from an IMAP
# mailbox or from the filesystem, and insert the information into a database.
# ( Formerly known as imap-dmarcts )
#
# Copyright (C) 2016 TechSneeze.com and John Bieling
#
# Available at:
# https://github.com/techsneeze/dmarcts-report-parser
#
# This program is free software: you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free Software
# Foundation, either version 3 of the License, or (at your option) any later
# version.
#
# This program is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License along with
# this program. If not, see <http://www.gnu.org/licenses/>.
################################################################################
################################################################################
# The subroutines storeXMLInDatabase() and getXMLFromMessage() are based on
# John R. Levine's rddmarc (http://www.taugh.com/rddmarc/). The following
# special conditions apply to those subroutines:
#
# Copyright 2012, Taughannock Networks. All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are met:
#
# Redistributions of source code must retain the above copyright notice, this
# list of conditions and the following disclaimer.
#
# Redistributions in binary form must reproduce the above copyright notice, this
# list of conditions and the following disclaimer in the documentation and/or
# other materials provided with the distribution.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
# IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
# DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
# FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
# DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
# SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
# CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
# OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
################################################################################
################################################################################
# Usage:
# ./dmarcts-report-parser.pl [OPTIONS] [PATH]
#
# If PATH is not provided, reports are read from an IMAP server, otherwise they
# are read from PATH from local filesystem. PATH can be a filename of a single
# mime message file or multiple mime message files - wildcard expression are
# allowed.
#
# To run, this script needs custom configurations: a database server and
# credentials and (if used) an IMAP server and credentials. These values can be
# set inside the script or by providing them via <dmarcts-report-parser.conf> in
# the current working directory.
#
# The following options are always allowed:
# -d : Print debug info.
# -r : Replace existing reports rather than failing.
# --delete : Delete processed message files (the XML is stored in the
# database for later reference).
#
# If a PATH is given, the following option is also allowed:
# -x : Files specified by PATH are XML report files, rather than
# mime messages containing the XML report files.
################################################################################
# Always be safe
use strict;
use warnings;
# Use these modules
use Getopt::Long;
use IO::Compress::Gzip qw(gzip $GzipError);
#use Data::Dumper;
use Mail::IMAPClient;
use Mail::Mbox::MessageParser;
use MIME::Base64 qw(encode_base64);
use MIME::Words qw(decode_mimewords);
use MIME::Parser;
use MIME::Parser::Filer;
use XML::Simple;
use DBI;
use Socket;
use Socket6;
use PerlIO::gzip;
use File::Basename ();
# Define all possible configuration options.
our ($debug, $delete_reports, $maxsize_xml, $compress_xml,
$dbname, $dbuser, $dbpass, $dbhost,
$imapserver, $imapuser, $imappass, $imapssl, $imaptls, $delete_failed,
$imapmovefolder, $imapreadfolder, $imapopt);
# config file will be searched in running directory, then in call path
my $conf_file = 'dmarcts-report-parser.conf';
################################################################################
### main #######################################################################
################################################################################
# Load script configuration options from local config file. The file is expected
# to be in the current working directory.
# defaults
$maxsize_xml = 50000;
# load configuration
if ( -e $conf_file ) {
do $conf_file;
} elsif( -e (File::Basename::dirname($0) . "/$conf_file" ) ) {
do ( File::Basename::dirname($0) . "/$conf_file" );
} else {
die "Could not read config file '$conf_file' from current working directory or path (" . File::Basename::dirname($0) . ')'
}
# Get command line options.
my %options = ();
GetOptions( \%options, 'd', 'r', 'x', 'm', 'delete' );
# Set default behaviour.
use constant { TS_IMAP => 0, TS_MESSAGE_FILE => 1, TS_XML_FILE => 2, TS_MBOX_FILE => 3 };
our $reports_source = TS_IMAP;
our $reports_replace = 0;
# Check for further command line arguments (interpreted as PATH)
if ($ARGV[0]) {
$reports_source = TS_MESSAGE_FILE;
}
# Evaluate command line options
if (exists $options{r}) {$reports_replace = 1;}
if (exists $options{x}) {
if ($reports_source == TS_IMAP) {
die "The -x OPTION requires a PATH.\n";
} else {
$reports_source = TS_XML_FILE;
}
}
if (exists $options{m}) {
if ($reports_source == TS_IMAP) {
die "The -m OPTION requires a PATH.\n";
} elsif ($reports_source == TS_IMAP) {
die "The -m and -x OPTIONS cannot be used both.\n";
} else {
$reports_source = TS_MBOX_FILE;
}
}
# Override config options by command line options.
if (exists $options{d}) {$debug = 1;}
if (exists $options{delete}) {$delete_reports = 1;}
# Setup connection to database server.
my $dbh = DBI->connect("DBI:mysql:database=$dbname;host=$dbhost",
$dbuser, $dbpass)
or die "Cannot connect to database\n";
checkDatabase($dbh);
# Process messages based on $reports_source.
if ($reports_source == TS_IMAP) {
# Disable verify mode for TLS support.
if ($imaptls == 1) {
$imapopt = [ SSL_verify_mode => 0 ];
}
# Setup connection to IMAP server.
my $imap = Mail::IMAPClient->new( Server => $imapserver,
Ssl => $imapssl,
Starttls => $imapopt,
User => $imapuser,
Password => $imappass)
# module uses eval, so we use $@ instead of $!
or die "IMAP Failure: $@";
# Set $imap to UID mode, which will force imap functions to use/return
# UIDs, instead of message sequence numbers. UIDs are not allowed to
# change during a session and are not allowed to be used twice. Looping
# over message sequence numbers and deleting a msg in between could have
# unwanted side effects.
$imap->Uid(1);
if ($debug == 1) {
# How many msgs are we going to process?
print "There are ". $imap->message_count($imapreadfolder).
" messages in the $imapreadfolder folder.\n";
}
# Only select and search $imapreadfolder, if we actually
# have something to do.
if ($imap->message_count($imapreadfolder)) {
# Select the mailbox to get messages from.
$imap->select($imapreadfolder)
or die "IMAP Select Error: $!";
# Store each message as an array element.
my @msgs = $imap->search('ALL')
or die "Couldn't get all messages\n";
# Loop through IMAP messages.
foreach my $msg (@msgs) {
if ($debug == 1) {
print "--------------------------------\n";
print "The Current Message UID is: ";
print $msg. "\n";
print "--------------------------------\n";
}
my $xml = getXMLFromMessage($imap->message_string($msg),"IMAP message with UID #".$msg);
# If !$xml, the mail is probably not a DMARC report, so
# do not storeXMLInDatabase.
if ($xml) {
# If storeXMLInDatabase returns false, there was some sort
# of database storage failure and we MUST stop the file
# procession, because it is not pushed into the database.
# The user must investigate this issue.
if (storeXMLInDatabase($xml) <= 0) {
next;
}
}
# Delete processed message files, if the --delete option
# is given. Otherwise move msgs if $imapmovefolder is set.
if ($delete_reports && ($xml || $delete_failed)) {
if ($debug == 1) {
print "Deleting processed IMAP message file.\n";
}
if (!$xml) {
# A mail which does not look like a DMARC report
# has been processed and should now be deleted.
# Print its content so it gets send as cron
# message, so the user can still investigate.
print $imap->message_string($msg)."\n"
}
$imap->delete_message($msg)
or print "Could not delete IMAP message. [$@]\n";
} elsif ($imapmovefolder) {
if ($debug == 1) {
print "Moving (copy and delete) processed IMAP message file to IMAP folder: $imapmovefolder\n";
}
# Try to create $imapmovefolder, if it does not exist.
if (!$imap->exists($imapmovefolder)) {
$imap->create($imapmovefolder)
or print "Could not create IMAP folder: $imapmovefolder.\n";
}
# Try to move the message to $imapmovefolder.
my $newid = $imap->copy($imapmovefolder, [ $msg ]);
if (!$newid) {
print "Error on moving (copy and delete) processed IMAP message: Could not COPY message to IMAP folder: <$imapmovefolder>!\n";
print "Messsage will not be moved/deleted. [$@]\n";
} else {
$imap->delete_message($msg)
or do {
print "Error on moving (copy and delete) processed IMAP message: Could not DELETE message\n";
print "after copying it to <$imapmovefolder>. [$@]\n";
}
}
}
}
# Expunge and close the folder.
$imap->expunge($imapreadfolder);
$imap->close($imapreadfolder);
}
# We're all done with IMAP here.
$imap->logout();
} else { # TS_MESSAGE_FILE or TS_XML_FILE
foreach my $a (@ARGV) {
# Linux bash supports wildcard expansion BEFORE the script is
# called, so here we only see a list of files. Other OS behave
# different, so we should not depend on that feature: Use glob
# on each argument to manually expand the argument, if possible.
my @file_list = glob($a);
if ($debug == 1) {
# How many msgs are we going to process?
print "There are ". @file_list. " messages to be processed.\n";
}
foreach my $f (@file_list) {
if ($debug == 1) {
print "--------------------------------\n";
print "The Current Message is: ";
print $f. "\n";
print "--------------------------------\n";
}
my $xml;
my $filecontent;
my $err = 0;
if ($reports_source == TS_MBOX_FILE) {
my $parser = Mail::Mbox::MessageParser->new({"file_name" => $f, "debug" => $debug, "enable_cache" => 0});
my $num = 1;
do {
$filecontent = $parser->read_next_email();
if ($filecontent) {
my $mboxxml = getXMLFromMessage($filecontent,"$f message $num");
if($mboxxml && storeXMLInDatabase($mboxxml) <= 0) {
$err = 1;
}
}
++$num;
} while (defined($filecontent));
} elsif (open FILE, $f) {
$filecontent = join("", <FILE>);
close FILE;
if ($reports_source == TS_MESSAGE_FILE) {
# Get XML data from mime message.
$xml = getXMLFromMessage($filecontent,$f);
} else {
# Get XML data from XML file directly.
$xml = getXMLFromXMLString($filecontent);
if (!$xml) {
print "File <$f> does not seem to be a valid XML file. Skipped.\n";
}
}
} else {
print "Could not open file <$f>: $!. Skipped.\n";
# Could not retrieve filecontent, so it is not
# possible to --delete file and send filecontent
# as cron message. The user has to look at the
# actual file. The skipped message must be send
# on each cron.
next;
}
# If !$xml, the file/mail is probably not a DMARC report.
# So do not storeXMLInDatabase.
if ($xml) {
# If storeXMLInDatabase returns false, there was some sort
# of database storage failure and we MUST stop the file
# procession, because it is not pushed into the database.
# The user must investigate this issue.
if (storeXMLInDatabase($xml) <= 0) {
next;
}
} else {
$err = 1;
}
# Delete processed message files, if the --delete option
# is given.
if ($delete_reports && (!$err || $delete_failed)) {
if (!$xml) {
# A mail which does not look like a DMARC report
# has been processed and should now be deleted.
# Print its content so it gets send as cron
# message, so the user can still investigate.
print $filecontent."\n"
}
if($debug) {
print "Remove file <$f>.\n";
}
unlink($f);
}
}
}
}
################################################################################
### subroutines ################################################################
################################################################################
# Walk through a mime message and return a reference to the XML data containing
# the fields of the first ZIPed XML file embedded into the message. The XML
# itself is not checked to be a valid DMARC report.
sub getXMLFromMessage {
my $message = $_[0];
my $messagefile = $_[1];
my $parser = new MIME::Parser;
$parser->output_dir("/tmp");
$parser->filer->ignore_filename(1);
my $ent = $parser->parse_data($message);
my $body = $ent->bodyhandle;
my $mtype = $ent->mime_type;
my $subj = decode_mimewords($ent->get('subject'));
if ($debug == 1) {
print "Subject: $subj"; # Subject always contains a \n.
print "MimeType: $mtype\n";
}
my $location;
my $isgzip = 0;
if(lc $mtype eq "application/zip") {
if ($debug == 1) {
print "This is a ZIP file \n";
}
$location = $body->path;
} elsif (lc $mtype eq "application/gzip") {
if ($debug == 1) {
print "This is a GZIP file \n";
}
$location = $body->path;
$isgzip = 1;
} elsif (lc $mtype eq "multipart/mixed") {
# At the moment, nease.net messages are multi-part, so we need
# to breakdown the attachments and find the zip.
if ($debug == 1) {
print "This is a multipart attachment \n";
}
#print Dumper($ent->parts);
my $num_parts = $ent->parts;
for (my $i=0; $i < $num_parts; $i++) {
my $part = $ent->parts($i);
# Find a zip file to work on...
if(lc $part->mime_type eq "application/gzip") {
$location = $ent->parts($i)->{ME_Bodyhandle}->{MB_Path};
$isgzip = 1;
print "$location\n" if $debug;
last; # of parts
} elsif(lc $part->mime_type eq "application/x-zip-compressed"
or $part->mime_type eq "application/zip") {
$location = $ent->parts($i)->{ME_Bodyhandle}->{MB_Path};
print "$location\n" if $debug;
} elsif(lc $part->mime_type eq "application/octet-stream") {
$location = $ent->parts($i)->{ME_Bodyhandle}->{MB_Path};
$isgzip = 1 if $location =~ /\.gz$/;
print "$location\n" if $debug;
} else {
# Skip the attachment otherwise.
if($debug == 1) {
print "Skipped an unknown attachment \n";
}
next; # of parts
}
}
} else {
## Clean up dangling mime parts in /tmp of messages without ZIP.
my $num_parts = $ent->parts;
for (my $i=0; $i < $num_parts; $i++) {
if($debug == 1) {
if ($ent->parts($i)->{ME_Bodyhandle} && $ent->parts($i)->{ME_Bodyhandle}->{MB_Path}) {
print $ent->parts($i)->{ME_Bodyhandle}->{MB_Path};
} else {
print "undef";
}
print "\n";
}
if($ent->parts($i)->{ME_Bodyhandle}) {$ent->parts($i)->{ME_Bodyhandle}->purge;}
}
}
# If a ZIP has been found, extract XML and parse it.
my $xml;
if(defined($location)) {
if ($debug == 1) {
print "body is in " . $location . "\n";
}
# Open the zip file and process the XML contained inside.
my $unzip = "";
if($isgzip) {
open(XML, "<:gzip", $location)
or $unzip = "ungzip";
} else {
open(XML,"unzip -p " . $location . " |")
or $unzip = "unzip"; # Will never happen.
# Sadly unzip -p never failes, but we can check if the
# filehandle points to an empty file and pretend it did
# not open/failed.
if (eof XML) {
$unzip = "unzip";
close XML;
}
}
# Read XML if possible (if open)
if ($unzip eq "") {
$xml = getXMLFromXMLString(join("", <XML>));
if (!$xml) {
print "The XML found in ZIP file (temp. location: <$location>) extracted from <$messagefile> does not seem to be valid XML. Skipped.\n";
}
close XML;
} else {
print "Failed to $unzip ZIP file (temp. location: <$location>) extracted from <$messagefile>. Skipped.\n";
}
} else {
print "Could not find an embedded ZIP in <$messagefile>. Skipped.\n";
}
if($body) {$body->purge;}
if($ent) {$ent->purge;}
return $xml;
}
################################################################################
sub getXMLFromXMLString {
my $raw_xml = $_[0];
eval {
my $xs = XML::Simple->new();
my $ref = $xs->XMLin($raw_xml, SuppressEmpty => '');
$ref->{'raw_xml'} = $raw_xml;
return $ref;
} or do {
return undef;
}
}
################################################################################
# Extract fields from the XML report data hash and store them into the database.
# return 1 when ok, 0, for serious error and -1 for minor errors
sub storeXMLInDatabase {
my $xml = $_[0]; # $xml is a reference to the xml data
my $from = $xml->{'report_metadata'}->{'date_range'}->{'begin'};
my $to = $xml->{'report_metadata'}->{'date_range'}->{'end'};
my $org = $xml->{'report_metadata'}->{'org_name'};
my $id = $xml->{'report_metadata'}->{'report_id'};
my $email = $xml->{'report_metadata'}->{'email'};
my $extra = $xml->{'report_metadata'}->{'extra_contact_info'};
my $domain = $xml->{'policy_published'}->{'domain'};
my $policy_adkim = $xml->{'policy_published'}->{'adkim'};
my $policy_aspf = $xml->{'policy_published'}->{'aspf'};
my $policy_p = $xml->{'policy_published'}->{'p'};
my $policy_sp = $xml->{'policy_published'}->{'sp'};
my $policy_pct = $xml->{'policy_published'}->{'pct'};
# see if already stored
my $sth = $dbh->prepare(qq{SELECT org, serial FROM report WHERE reportid=?});
$sth->execute($id);
while ( my ($xorg,$sid) = $sth->fetchrow_array() )
{
if ($reports_replace) {
# $sid is the serial of a report with reportid=$id
# Remove this $sid from rptrecord and report table, but
# try to continue on failure rather than skipping.
print "Replacing $xorg $id.\n";
$dbh->do(qq{DELETE from rptrecord WHERE serial=?}, undef, $sid);
if ($dbh->errstr) {
print "Cannot remove report data from database (". $dbh->errstr ."). Try to continue.\n";
}
$dbh->do(qq{DELETE from report WHERE serial=?}, undef, $sid);
if ($dbh->errstr) {
print "Cannot remove report from database (". $dbh->errstr ."). Try to continue.\n";
}
} else {
print "Already have $xorg $id, skipped\n";
# Do not store in DB, but return true, so the message can
# be moved out of the way, if configured to do so.
return 1;
}
}
my $sql = qq{INSERT INTO report(serial,mindate,maxdate,domain,org,reportid,email,extra_contact_info,policy_adkim, policy_aspf, policy_p, policy_sp, policy_pct, raw_xml)
VALUES(NULL,FROM_UNIXTIME(?),FROM_UNIXTIME(?),?,?,?,?,?,?,?,?,?,?,?)};
my $storexml = $xml->{'raw_xml'};
if ($compress_xml) {
my $gzipdata;
if(!gzip(\$storexml => \$gzipdata)) {
print "Cannot add gzip XML for database ($GzipError). Skipped.\n";
$storexml = "";
} else {
$storexml = encode_base64($gzipdata, "");
}
}
if (length($storexml) > $maxsize_xml) {
print "Skipping storage of large XML (".length($storexml)." bytes).\n";
$storexml = "";
}
$dbh->do($sql, undef, $from, $to, $domain, $org, $id, $email, $extra, $policy_adkim, $policy_aspf, $policy_p, $policy_sp, $policy_pct, $storexml);
if ($dbh->errstr) {
print "Cannot add report to database (". $dbh->errstr ."). Skipped.\n";
return 0;
}
my $serial = $dbh->{'mysql_insertid'} || $dbh->{'insertid'};
if($debug == 1){
print " serial $serial ";
}
my $record = $xml->{'record'};
sub dorow($$) {
my ($serial,$recp) = @_;
my %r = %$recp;
my $ip = $r{'row'}->{'source_ip'};
#print "ip $ip\n";
my $count = $r{'row'}->{'count'};
my $disp = $r{'row'}->{'policy_evaluated'}->{'disposition'};
# some reports don't have dkim/spf, "unknown" is default for these
my $dkim_align = $r{'row'}->{'policy_evaluated'}->{'dkim'} || "unknown";
my $spf_align = $r{'row'}->{'policy_evaluated'}->{'spf'} || "unknown";
my $identifier_hfrom = $r{'identifiers'}->{'header_from'};
my ($dkim, $dkimresult, $spf, $spfresult, $reason);
my $rp = $r{'auth_results'}->{'dkim'};
if(ref $rp eq "HASH") {
$dkim = $rp->{'domain'};
$dkim = undef if ref $dkim eq "HASH";
$dkimresult = $rp->{'result'};
} else { # array
# glom sigs together, report first result
$dkim = join '/',map { my $d = $_->{'domain'}; ref $d eq "HASH"?"": $d } @$rp;
$dkimresult = $rp->[0]->{'result'};
}
$rp = $r{'auth_results'}->{'spf'};
if(ref $rp eq "HASH") {
$spf = $rp->{'domain'};
$spfresult = $rp->{'result'};
} else { # array
# glom domains together, report first result
$spf = join '/',map { my $d = $_->{'domain'}; ref $d eq "HASH"? "": $d } @$rp;
$spfresult = $rp->[0]->{'result'};
}
$rp = $r{'row'}->{'policy_evaluated'}->{'reason'};
if(ref $rp eq "HASH") {
$reason = $rp->{'type'};
} else {
$reason = join '/',map { $_->{'type'} } @$rp;
}
#print "ip=$ip, count=$count, disp=$disp, r=$reason,";
#print "dkim=$dkim/$dkimresult, spf=$spf/$spfresult\n";
# What type of IP address?
my ($nip, $iptype, $ipval);
if($debug == 1) {
print "ip=$ip\n";
}
if($nip = inet_pton(AF_INET, $ip)) {
$ipval = unpack "N", $nip;
$iptype = "ip";
} elsif($nip = inet_pton(AF_INET6, $ip)) {
$ipval = "X'" . unpack("H*",$nip) . "'";
$iptype = "ip6";
} else {
print "??? mystery ip $ip\n";
next; # of dorow
}
$dbh->do(qq{INSERT INTO rptrecord(serial,$iptype,rcount,disposition,spf_align,dkim_align,reason,dkimdomain,dkimresult,spfdomain,spfresult,identifier_hfrom)
VALUES(?,$ipval,?,?,?,?,?,?,?,?,?,?)},undef,$serial,$count,$disp,$spf_align,$dkim_align,$reason,$dkim,$dkimresult,$spf,$spfresult,$identifier_hfrom);
if ($dbh->errstr) {
print "Cannot add report data to database (". $dbh->errstr ."). Skipped.\n";
return 0;
}
return 1;
}
my $res = 1;
if(ref $record eq "HASH") {
if($debug == 1){
print "single record\n";
}
$res = -1 if !dorow($serial,$record);
} elsif(ref $record eq "ARRAY") {
if($debug == 1){
print "multi record\n";
}
foreach my $row (@$record) {
$res = -1 if !dorow($serial,$row);
}
} else {
print "mystery type " . ref($record) . "\n";
}
if ($debug && $res <= 0) {
print "Result $res XML: $xml->{raw_xml}\n";
}
return $res;
}
################################################################################
# Check, if the database contains needed tables and columns. The idea is, that
# the user only has to create the database/database_user. All needed tables and
# columns are created automatically. Furthermore, if new columns are introduced,
# the user does not need to make any changes to the database himself.
sub checkDatabase {
my $dbh = $_[0];
my %tables = (
"report" => {
column_definitions => [
"serial" , "int(10) unsigned NOT NULL AUTO_INCREMENT",
"mindate" , "timestamp NOT NULL DEFAULT CURRENT_TIMESTAMP ON UPDATE CURRENT_TIMESTAMP",
"maxdate" , "timestamp NULL",
"domain" , "varchar(255) NOT NULL",
"org" , "varchar(255) NOT NULL",
"reportid" , "varchar(255) NOT NULL",
"email" , "varchar(255) NULL",
"extra_contact_info" , "varchar(255) NULL",
"policy_adkim" , "varchar(20) NULL",
"policy_aspf" , "varchar(20) NULL",
"policy_p" , "varchar(20) NULL",
"policy_sp" , "varchar(20) NULL",
"policy_pct" , "tinyint unsigned",
"raw_xml" , "mediumtext",
],
additional_definitions => "PRIMARY KEY (serial), UNIQUE KEY domain (domain,reportid)",
table_options => "",
},
"rptrecord" =>{
column_definitions => [
"serial" , "int(10) unsigned NOT NULL",
"ip" , "int(10) unsigned",
"ip6" , "binary(16)",
"rcount" , "int(10) unsigned NOT NULL",
"disposition" , "enum('none','quarantine','reject')",
"reason" , "varchar(255)",
"dkimdomain" , "varchar(255)",
"dkimresult" , "enum('none','pass','fail','neutral','policy','temperror','permerror')",
"spfdomain" , "varchar(255)",
"spfresult" , "enum('none','neutral','pass','fail','softfail','temperror','permerror','unknown')",
"spf_align" , "enum('fail','pass','unknown') NOT NULL",
"dkim_align" , "enum('fail','pass','unknown') NOT NULL",
"identifier_hfrom" , "varchar(255)",
],
additional_definitions => "KEY serial (serial,ip), KEY serial6 (serial,ip6)",
table_options => "ENGINE=MyISAM",
},
);
# Get current tables in this DB.
my %db_tbl_exists = ();
for ( @{ $dbh->selectall_arrayref( "SHOW TABLES;") } ) {
$db_tbl_exists{$_->[0]} = 1;
}
# Create missing tables and missing columns.
for my $table ( keys %tables ) {
if (!$db_tbl_exists{$table}) {
# Table does not exist, build CREATE TABLE cmd from tables hash.
print "Adding missing table <" . $table . "> to the database.\n";
my $sql_create_table = "CREATE TABLE " . $table . " (\n";
for (my $i=0; $i <= $#{$tables{$table}{"column_definitions"}}; $i+=2) {
my $col_name = $tables{$table}{"column_definitions"}[$i];
my $col_def = $tables{$table}{"column_definitions"}[$i+1];
# add comma if second or later entry
if ($i != 0) {
$sql_create_table .= ",\n";
}
$sql_create_table .= $col_name . " " .$col_def;
}
# Add additional_definitions, if defined.
if ($tables{$table}{"additional_definitions"} ne "") {
$sql_create_table .= ",\n" . $tables{$table}{"additional_definitions"};
}
# Add options.
$sql_create_table .= ") " . $tables{$table}{"table_options"} . ";";
# Create table.
print "$sql_create_table\n" if $debug;
$dbh->do($sql_create_table);
} else {
#Table exists, get current columns in this table from DB.
my %db_col_exists = ();
for ( @{ $dbh->selectall_arrayref( "SHOW COLUMNS FROM $table;") } ) {
$db_col_exists{$_->[0]} = $_->[1];
};
# Check if all needed columns are present, if not add them at the desired position.
my $insert_pos = "FIRST";
for (my $i=0; $i <= $#{$tables{$table}{"column_definitions"}}; $i+=2) {
my $col_name = $tables{$table}{"column_definitions"}[$i];
my $col_def = $tables{$table}{"column_definitions"}[$i+1];
my $short_def = $col_def;
$short_def =~ s/ +.*$//;
if (!$db_col_exists{$col_name}) {
# add column
my $sql_add_column = "ALTER TABLE $table ADD $col_name $col_def $insert_pos;";
print "$sql_add_column\n" if $debug;
$dbh->do($sql_add_column);
} elsif ($db_col_exists{$col_name} !~ /^\Q$short_def\E/) {
# modify column
my $sql_modify_column = "ALTER TABLE $table MODIFY COLUMN $col_name $col_def;";
print "$sql_modify_column\n" if $debug;
$dbh->do($sql_modify_column);
}
$insert_pos = "AFTER $col_name";
}
}
}
}