cmake: Support being included with add_subdirectory

Make changes needed to make the cmake project work well when it is not the top
level project and has been included with add_subdirectory:

- Avoid defining "tests" and "check" targets when project is not at the top
  level to avoid clashes. Add new "mptests" and "mpcheck" alternatives instead.
- Rename "example" target to "mpexamples"
- Rename "util" target to "mputil"
- Export MP_INCLUDE_DIR variable to parent scope so target_capnp_sources()
  function can work well there.
- Replace uses of CMAKE_SOURCE_DIR with CMAKE_CURRENT_SOURCE_DIR
- Reset INCLUDE_DIRECTORIES property so include_directories calls in the parent
  project do not affect this project. This was causing errors because the
  bitcoin core build was adding global include directories and causing its init.h
  file to take precedence over local one.

Author: ryanofsky

CMakeLists.txt

@@ -26,7 +26,20 @@ include("cmake/compat_config.cmake")
 include("cmake/pthread_checks.cmake")
 include(GNUInstallDirs)
 
+# Set convenience variables for subdirectories.
 set(MP_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/include")
+if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
+  set(MP_STANDALONE TRUE)
+else()
+  # Set MP_INCLUDE_DIR for parent directories too, so target_capnp_sources calls
+  # in parent directories can use it and not need to specify include directories
+  # manually or see capnproto error "error: Import failed: /mp/proxy.capnp"
+  set(MP_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/include" PARENT_SCOPE)
+  set(MP_STANDALONE FALSE)
+endif()
+
+# Prevent include directories from parent project from leaking into this one.
+set_property(DIRECTORY PROPERTY INCLUDE_DIRECTORIES "")
 
 # Generated C++ preprocessor defines
 configure_file(include/mp/config.h.in "${CMAKE_CURRENT_BINARY_DIR}/include/mp/config.h")
@@ -35,10 +48,10 @@ configure_file(include/mp/config.h.in "${CMAKE_CURRENT_BINARY_DIR}/include/mp/co
 capnp_generate_cpp(MP_PROXY_SRCS MP_PROXY_HDRS include/mp/proxy.capnp)
 
 # util library
-add_library(util OBJECT src/mp/util.cpp)
-target_include_directories(util PRIVATE
-  $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
-  $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
+add_library(mputil OBJECT src/mp/util.cpp)
+target_include_directories(mputil PRIVATE
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
+  $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
   ${CAPNP_INCLUDE_DIRECTORY})
 
 # libmultiprocess.a runtime library
@@ -52,7 +65,7 @@ add_library(multiprocess STATIC
   ${MP_PROXY_SRCS}
   ${MP_PUBLIC_HEADERS}
   src/mp/proxy.cpp
-  $<TARGET_OBJECTS:util>)
+  $<TARGET_OBJECTS:mputil>)
 add_library(Libmultiprocess::multiprocess ALIAS multiprocess)
 target_include_directories(multiprocess PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
@@ -70,7 +83,7 @@ install(TARGETS multiprocess EXPORT LibTargets
   PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/mp COMPONENT lib)
 
 # mpgen code generator
-add_executable(mpgen src/mp/gen.cpp $<TARGET_OBJECTS:util>)
+add_executable(mpgen src/mp/gen.cpp $<TARGET_OBJECTS:mputil>)
 add_executable(Libmultiprocess::mpgen ALIAS mpgen)
 target_include_directories(mpgen PRIVATE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>)
 target_include_directories(mpgen PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include> $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)

example/CMakeLists.txt

@@ -26,4 +26,4 @@ target_include_directories(mpexample PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
 target_link_libraries(mpexample PRIVATE Threads::Threads)
 target_link_libraries(mpexample PRIVATE stdc++fs)
 
-add_custom_target(example DEPENDS mpexample mpcalculator mpprinter)
+add_custom_target(mpexamples DEPENDS mpexample mpcalculator mpprinter)

test/CMakeLists.txt

@@ -11,8 +11,15 @@ include(CTest)
 # that were previously built, without building anything itself. Define "make
 # tests" here as a custom target to build all available tests and "make check"
 # as a custom target to build and run them.
-add_custom_target(tests)
-add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND} DEPENDS tests)
+add_custom_target(mptests)
+add_custom_target(mpcheck COMMAND ${CMAKE_CTEST_COMMAND} DEPENDS mptests)
+
+# Only add more convenient tests and check targets if project is being built
+# standlone, to prevent clashes with external projects.
+if (MP_STANDALONE)
+  add_custom_target(tests DEPENDS mptests)
+  add_custom_target(check DEPENDS mpcheck)
+endif()
 
 if(BUILD_TESTING AND TARGET CapnProto::kj-test)
   set_property(SOURCE ${MP_PROXY_HDRS} PROPERTY GENERATED 1)
@@ -29,6 +36,6 @@ if(BUILD_TESTING AND TARGET CapnProto::kj-test)
   target_link_libraries(mptest PRIVATE CapnProto::kj-test)
   target_link_libraries(mptest PRIVATE Threads::Threads)
 
-  add_dependencies(tests mptest)
+  add_dependencies(mptests mptest)
   add_test(NAME mptest COMMAND mptest)
 endif()