build.gradle

buildscript {
	repositories {
		mavenCentral()
	}
}
apply from: rootProject.file('gradle/java-publish.gradle')
apply from: rootProject.file('gradle/changelog.gradle')
allprojects {
	apply from: rootProject.file('gradle/spotless.gradle')
}
apply from: rootProject.file('gradle/spotless-freshmark.gradle')

spotless {
	groovyGradle {
		target '*.gradle', 'gradle/*.gradle'
	}
	format 'dotfiles', {
		target '.gitignore', '.gitattributes', '.editorconfig'
		indentWithSpaces(2)
		trimTrailingWhitespace()
		endWithNewline()
	}
}

// root eclipse project
apply plugin: 'com.diffplug.eclipse.resourcefilters'
eclipseResourceFilters {
	exclude().folders().name('.git')
	exclude().folders().name('build').recursive()

	exclude().folders().name('lib')
	exclude().folders().name('lib-extra')
	exclude().folders().name('plugin-gradle')
	exclude().folders().name('plugin-maven')
	exclude().folders().name('testlib')
}

static Class<?> spotBugsTaskType() {
	return com.github.spotbugs.snom.SpotBugsTask
}