Scala.sc

// By Jascha Narveson and Charles Celeste Hutchins


Scala : Tuning {
	/*@
	shortDesc: open Scala files
	longDesc: Reads Scala files and creates a Tuning basedon them.  It can also generate a Scale that includes every interval in the Tuning.  See Tuning for the principle methods.

	More information about the Scala file format, and a link to the scale library, can be found at:
	http://www.huygens-fokker.org/scala/scl_format.html
	@*/
	//

	classvar <>defaultDir;
	var <pitchesPerOctave;


	*initClass {
		defaultDir = PathName( Scala.filenameSymbol.asString ).pathOnly +/+ "data/";
	}

	*new { arg path;
		/*@
		desc: open a Scala file
		path: path to the Scala file
		ex:
		a = Scala("slendro.scl");
		@*/

		^super.new.initOpen(pathname: path);

	}

	*open { arg path;
		/*@
		desc: a more intiutive syntax for opening a Scala file
		@*/

		^super.new.initOpen(pathname: path);
	}

	*at { arg name;
		try {
			^super.new.initOpen(name);
		} {|e| ^Tuning.at(name) }
	}


	*forceUpdate{|dir,lastModifiedFile|
		var file, data;
		data=dir?defaultDir;

		File.exists(data).not.if({
			File.mkdir(data)
		});

		lastModifiedFile =  lastModifiedFile ? (data +/+ "Last-Modified.txt");
		//"forceUpdate".postln;
		"cd % ; rm scales.zip ;  curl -L https://huygens-fokker.org/docs/scales.zip --output scales.zip && unzip -aa -u scales.zip".format(data).unixCmd({
			file = File.new(lastModifiedFile, "w");
			file.write("%".format(Date.getDate.rawSeconds));
			file.close;
		});
	}


	*update {|dir|

		var tmp, data, lastModifiedFile, lastModified, propFile, properties, propArr,
		dateStr, dateArr, month, time, archiveModified, shouldUpdate, doUpdate, key;

		tmp = Platform.defaultTempDir;
		data=dir?defaultDir;

		File.exists(data).not.if({
			File.mkdir(data)
		});

		shouldUpdate = true;

		doUpdate = {
			Scala.forceUpdate(data, lastModifiedFile);
			//	var file;
			//	"doUpdate".postln;
			//	"curl http://huygens-fokker.org/docs/scales.zip > % && cd % && unzip -aa scales.zip".format(data+/+"scales.zip", data).unixCmd({
			//		file = File.new(lastModifiedFile, "w");
			//		file.write(Date.getDate.rawSeconds);
			//		file.close;
			//	});
		};

		doUpdate.();


		// Checking if we should update doesn't work because of a 301 responce, so just update

		// check if we should update

		lastModifiedFile = data +/+ "Last-Modified.txt";
		File.exists(lastModifiedFile).if({
			lastModified = File.mtime(lastModifiedFile);
			propFile = tmp +/+ "scala.txt";

			// get just the header

			//("curl -I -L https://huygens-fokker.org/docs/scales.zip -D %".format(propFile)).unixCmd({
			("curl --get https://huygens-fokker.org/docs/scales.zip --output % -v -I".
				format(propFile)).unixCmd({


				properties = IdentityDictionary.new;

				File.exists(propFile).if ({
					propArr = FileReader.read(propFile, true, true, delimiter: $:);
					propArr.do({|pair|
						properties.put(pair[0].stripWhiteSpace.asSymbol, pair[1..]);
					});

					// now we've read the propFile, delete it
					File.delete(propFile);

					//properties.keys.postln;
					key = "Last-Modified";
					properties.keys.includes(key.asSymbol).not.if({
						key = key.toLower;
					});


					// check the date in the header
					dateArr = properties.at(key.asSymbol);
					dateArr = dateArr.collect({|i| i.stripWhiteSpace});
					dateArr = dateArr.collect({|i| i.split($ )}).flatten;

					month = case
					{ dateArr[2].compare("Jan", true)==0 }   { 1 } // Jan is 1
					{ dateArr[2].compare("Feb", true)==0 }   { 2 } // Jan is 1
					{ dateArr[2].compare("Mar", true)==0 }   { 3 } // Jan is 1
					{ dateArr[2].compare("Apr", true)==0 }   { 4 } // Jan is 1
					{ dateArr[2].compare("May", true)==0 }   { 5 } // Jan is 1
					{ dateArr[2].compare("Jun", true)==0 }   { 6 } // Jan is 1
					{ dateArr[2].compare("Jul", true)==0 }   { 7 } // Jan is 1
					{ dateArr[2].compare("Aug", true)==0 }   { 8 } // Jan is 1
					{ dateArr[2].compare("Sep", true)==0 }   { 9 } // Jan is 1
					{ dateArr[2].compare("Oct", true)==0 }   { 10 } // Jan is 1
					{ dateArr[2].compare("Nov", true)==0 }   { 11 } // Jan is 1
					{ dateArr[2].compare("Dec", true)==0 }   { 12 };

					//time = dateArr[4].split($:

					//Thu, 07 Mar 2019 13:28:36 GMT
					//year, month, day, hour, minute, second, dayOfWeek, rawSeconds;

					archiveModified = Date(dateArr[3], month, dateArr[1], dateArr[4], dateArr[5], dateArr[6], 0, 0);
					shouldUpdate = (archiveModified.rawSeconds > lastModified);

					shouldUpdate.if({
						File.delete(lastModifiedFile);
						doUpdate.();
					}, {
						"Up to date.".postln;

					});

				})
			});

		}, { doUpdate.();})

	}

	*install {|dir|

		Scala.update(dir);
	}


	initOpen{ arg pathname;

		var path, file,lines,line, ratios, num, numerator, denominator, clean_line, line_finished;

		tuning = [];
		ratios = [];
		path = pathname;

		// First try to find the file
		File.exists(pathname).not.if({
			pathname.endsWith("scl").not.if({
				pathname = pathname++".scl";
			});
		});
		File.exists(pathname).not.if({
			pathname = defaultDir  +/+ pathname;
		});

		File.exists(pathname).not.if({
			pathname = defaultDir +/+ "scl" +/+ path;
		});

		File.exists(pathname).not.if({
			pathname.endsWith("scl").not.if({
				pathname = pathname++".scl";
			});
		});


		pathname.postln;


		File.exists(pathname).not.if({
			MethodError("File % not found.".format(path)).throw;
		});


		// read the file

		// ok to read all the data into memory because it's small
		file = File.open(pathname,"r"); // open the .scl file
		lines = [];	// start an array for the relevant lines of the file
		line = 0;
		while ({line != nil},
			{
				line=file.getLine;
				if(line.isNil==false,
					{
						if(line.beginsWith("!").not,
							// ignore commented .scl file lines (starting with "!")
							{
								lines = lines.add(line);
								//line.postln;
							} // look at non-commented lines
						);
					}
				);
			}
		);
		file.close;


		// parse the results
		name = lines.removeAt(0);
		name = name.asString; // the first line will the the name
		pitchesPerOctave = lines.removeAt(0).asInteger;
		lines.do({|line|  // each scale pitch will be either in ratio or cents notation
			//line.post;
			clean_line = String.new;
			line_finished = false;

			line.do({|char|
				// only take numbers
				(((char >= $0) && (char <= $9)) || ( char==$.) || (char==$/)).if({
					line_finished.not.if({
						clean_line = clean_line.add(char);
					});
				}, {
					((char == $ )||(char == $\t )).if({
						// ignore whitespace
					}, {
						// other stuff (letters, etc)
						line_finished = true
					});
				});
			});

			clean_line.endsWith(".").if({
				clean_line = clean_line.add($0); // 433. is a legal number
			});


			(clean_line.contains(".").not).if({

				// the ratio case
				//num = clean_line.interpret.ratiomidi;
				#numerator,denominator = clean_line.split($/);
				numerator.notNil.if({
					// watch out for blank lines
					denominator.isNil.if({ denominator =1 });
					num = (numerator.asInteger / denominator.asInteger);
					// get the ratio
					ratios = ratios ++ num;
					// put the midi stuff in the tuning
					num = num.ratiomidi;
					tuning = tuning ++ num;
				});
			},
			{// the cents case
				//"as float: ".post; i.asFloat.postln;
				num = clean_line.asFloat;
				num = num / 100;
				tuning = tuning ++ num;
				// also stuff this into ratios
				ratios = ratios ++ num.midiratio;
			});
		});

		tuning = tuning.addFirst(0); // the interval 1/1 is not explicitly stated in the .scl file

		(tuning.size > pitchesPerOctave).if({
			// 12.midiratio has rounding error, should be 2, is 1.999etc
			num = tuning.pop;
			(num == 12).if ({ // octave
				octaveRatio = 2;
			}, {
				octaveRatio = ratios.pop;
			});
		}, {
			octaveRatio=2
		});


		path = PathName.new(pathname);
		all.put(path.fileNameWithoutExtension.asSymbol, this);
	}


	scale {

		/*@
		desc: Generates a Scale which contains as a degree every step in the tuning
		ex:
		a = Scala("slendro.scl");
		b = a.scale;
		@*/

		var degrees;

		degrees = Array.series(pitchesPerOctave, 0, 1);
		^Scale(degrees, pitchesPerOctave, this, name);
	}

}


/*
The scale archive, and rules for formatting .scl files, are described at
<http://www.xs4all.nl/~huygensf/scala/scl_format.html>
as of Nov.11, 2005:

� 	The files are human readable ASCII or 8-bit character text-files.
� 	The file type is .scl .
� 	There is one scale per file.
� 	Lines beginning with an exclamation mark are regarded as comments and are to be ignored.
� 	The first (non comment) line contains a short description of the scale, preferably not exceeding 80 characters, but longer lines are possible and should not give a read error. The description is only one line. If there is no description, there should be an empty line.
� 	The second line contains the number of notes. This number indicates the number of lines with pitch values that follow. In principle there is no upper limit to this, but it is allowed to reject files exceeding a certain size. The lower limit is 0, which is possible since degree 0 of 1/1 is implicit. Spaces before or after the number are allowed.
� 	After that come the pitch values, each on a separate line, either as a ratio or as a value in cents. If the value contains a period, it is a cents value, otherwise a ratio. Ratios are written with a slash, and only one. Integer values with no period or slash should be regarded as such, for example "2" should be taken as "2/1". The highest allowed numerator or denominator is 231-1 = 2147483647. Anything after a valid pitch value should be ignored. Space or horizontal tab characters are allowed and should be ignored. Negative ratios are meaningless and should give a read error. For a description of cents, go here.
� 	The first note of 1/1 or 0.0 cents is implicit and not in the files.
� 	Files for which Scala gives Error in file format are incorrectly formatted. They should give a read error and be rejected.

So these lines are all valid pitch lines:

81/64
408.0
408.
5
-5.0
10/20
100.0 cents
100.0 C#
5/4   E\

Here is an example of a valid file:

! meanquar.scl
!
1/4-comma meantone scale. Pietro Aaron's temperament (1523)
12
!
76.04900
193.15686
310.26471
5/4
503.42157
579.47057
696.57843
25/16
889.73529
1006.84314
1082.89214
2/1

An advise for writing a scale file: put the filename on the first line behind an exclamation mark. Then someone receiving the file and reading it knows a name under which to save it.
*/