build.gradle

plugins {
    id 'java'
    id 'groovy'
    id 'application'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '1.2.2'
}
def AWS_MVN_BUCKET = System.getenv("AWS_MVN_BUCKET")
def AWS_DEFAULT_REGION = System.getenv("AWS_DEFAULT_REGION")
def AWS_ACCESS_KEY_ID = System.getenv("AWS_ACCESS_KEY_ID")
def AWS_SECRET_ACCESS_KEY = System.getenv("AWS_SECRET_ACCESS_KEY")

repositories {
    jcenter()
    maven {
        url = 'https://oss.sonatype.org/content/repositories/snapshots/'
    }
     if (AWS_MVN_BUCKET && !AWS_MVN_BUCKET.allWhitespace) {
        maven {
            url "s3://$AWS_MVN_BUCKET/maven2"
            credentials(AwsCredentials) {
                accessKey AWS_ACCESS_KEY_ID
                secretKey AWS_SECRET_ACCESS_KEY
            }
        }
    }
}

def libversion = '3.5.2'
if(System.getenv("VERTX_VERSION") != null)
    libversion = System.getenv("VERTX_VERSION")

version = "${libversion}-1.0"
sourceCompatibility = '1.8'

dependencies {
    compile 'me.escoffier.vertx:vertx-completable-future:0.1.3-SNAPSHOT'
    compile "io.vertx:vertx-core:$libversion"
    compile "io.vertx:vertx-auth-common:$libversion"
    compile "io.vertx:vertx-auth-shiro:$libversion"
    compile "org.slf4j:slf4j-api:1.7.12"
    compile 'org.glassfish.tyrus.bundles:tyrus-standalone-client-jdk:1.13.1'
    compile 'org.codehaus.groovy:groovy:2.5.0'
    compile 'com.suse.salt:salt-netapi-client:0.14.0'
}

mainClassName = 'io.vertx.core.Launcher'

shadowJar {
    classifier = 'fat'
    manifest {
        attributes 'Main-Verticle': 'saltConnection.groovy'
    }
    mergeServiceFiles {
        include 'META-INF/services/io.vertx.core.spi.VerticleFactory'
    }
}


publishing {
    repositories {
        mavenLocal()
        if (AWS_MVN_BUCKET && !AWS_MVN_BUCKET.allWhitespace) {
            maven {
                url "s3://$AWS_MVN_BUCKET/maven2"
                credentials(AwsCredentials) {
                    accessKey AWS_ACCESS_KEY_ID
                    secretKey AWS_SECRET_ACCESS_KEY
                }
            }
        }
    }

    publications {
        mavenJava(MavenPublication) {
            groupId 'net.iowntheinter'
            artifactId 'vertx-salt'
            from components.java
        }
    }
}


task wrapper(type: Wrapper) {
    gradleVersion = '2.8'
}