jenkinsfile-build-pipeline-docker

/**
* Copy of the jenkins job that creates and tags dockers for dev
* Tags are develop
*/

import groovy.json.JsonSlurper

REPO="prismcmap"
DEV_TAG="develop"
WORKSPACE_DIR="/ci-data/jenkins/workspace/BUILD-PIPELINE-DOCKER/"
GIT_FOLDER = "/ci-data/jenkins/workspace/START-BUILD-PIPELINE/.git/"
URL_PREFIX="https://api.clue.io/api/pipeline_versions/upsertWithWhere?where=";

def getCheckedOutGitCommitHash() {

    def takeFromHash = 12
    /*
     * '.git/HEAD' contains either
     *      in case of detached head: the currently checked out commit hash
     *      otherwise: a reference to a file containing the current commit hash
     */
    def head = new File("${GIT_FOLDER}" + "HEAD").text.split(":") // .git/HEAD
    def isCommit = head.length == 1 // e5a7c79edabbf7dd39888442df081b1c9d8e88fd
    // def isRef = head.length > 1     // ref: refs/heads/master

    if(isCommit) return head[0].trim().take(takeFromHash) // e5a7c79edabb

    def refHead = new File("${GIT_FOLDER}" + head[1].trim()) // .git/refs/heads/master
    refHead.text.trim().take takeFromHash
}

def parallelStagesMap(DIRS,GIT_PREVIOUS_COMMIT,GIT_COMMIT){
  def mp = [:]
    CHANGED = sh(returnStdout: true, script: "git diff --name-only ${GIT_PREVIOUS_COMMIT} ${GIT_COMMIT}").trim()

    if(CHANGED){
        CHANGED_LINES = CHANGED.split("\n")
        if(CHANGED_LINES.size() > 0){
            for( String CHANGED_LINE : CHANGED_LINES ){
                try{
                    def (DIR)=CHANGED_LINE.tokenize( '/' );
                    API_JOB = DIR.replace("/","") + "_API"

                    DOCKER_FILE_EXISTS=sh(returnStdout: true, script: "test -f ${DIR}/Dockerfile && echo 'FILE exists.'").trim()

                    if(DOCKER_FILE_EXISTS){

                        GIT_COMMIT_HASH = getCheckedOutGitCommitHash()
                        mp.put("${DIR}",generateStage(DIR,GIT_COMMIT_HASH))
                        mp.put("${API_JOB}",generateAPIStage(API_JOB,DIR,GIT_COMMIT_HASH))
                    }

                }
                catch(err){
                    println(err);
                }
            }
        }
    }
    return mp
}
def generateAPIStage(job,repo_name,docker_hash) {
    return {
        stage("stage: ${job}") {
            String name = REPO + "/" + repo_name;
            String where = '{"name":"' + name + '","docker_tag":"' + DEV_TAG + '"}';
            String whereClause = java.net.URLEncoder.encode(where, "UTF-8");
            def message = '{"name":"' + name + '","docker_tag":"' + DEV_TAG + '","docker_hash": "' + docker_hash + '"}';
            def post = new URL(URL_PREFIX + whereClause).openConnection();
            post.setRequestMethod("POST")
            post.setDoOutput(true)
            post.setRequestProperty("Content-Type", "application/json")
            post.setRequestProperty("user_key",API_KEY)
            post.getOutputStream().write(message.getBytes("UTF-8"));
            def postRC = post.getResponseCode();
            println(postRC);
      }
    }
}
def generateStage(job,HASH_TAG) {
    return {
        stage("stage: ${job}") {
          dir("${job}") {
            sh script: "pwd"
            sh script: "docker build -t ${REPO}/${job}:${DEV_TAG} -t ${REPO}/${job}:${HASH_TAG} --rm=true ."
            sh script: "docker push ${REPO}/${job}:${DEV_TAG}"
            sh script: "docker push ${REPO}/${job}:${HASH_TAG}"
        }
      }
    }
}
pipeline{
    agent any
    environment {
        DOCKERHUB_CREDENTIALS= credentials('dockerhub-cred-jasiedu')
        GIT_PREVIOUS_COMMIT=''
        GIT_COMMIT=''
        API_KEY = credentials('API_KEY')
    }
    stages {
        stage('Login to Docker Hub') {
           steps{
             sh 'echo $DOCKERHUB_CREDENTIALS_PSW | sudo docker login -u $DOCKERHUB_CREDENTIALS_USR --password-stdin'
             echo 'Login Completed'
           }
       }
        stage("Git Checkout"){
            steps{
	            git credentialsId: '4c3bd279-468f-4837-a095-3366964ae937', url: 'https://github.com/cmap/dockerized_mts.git' ,branch: 'dev'
	            echo 'Git Checkout Completed'
            }
        }
        stage('Configure') {
            steps {
                script {
                    GIT_PREVIOUS_COMMIT = sh(returnStdout: true, script: "git rev-parse --short 'HEAD^'").trim()
                    GIT_COMMIT=sh(returnStdout: true, script: "git rev-parse --short HEAD").trim()
                }
            }
        }
        stage('Checkout code') {
            steps {
                script {
                    DIRS=sh(returnStdout: true, script: "ls -d -- */").trim()
                    DIR_PATHS = DIRS.split("\n")
                    mp = parallelStagesMap(DIR_PATHS,GIT_PREVIOUS_COMMIT,GIT_COMMIT)
                    mp.each { key, value ->
                           println("Key: ${key}, Value: ${value}")
                    }

                    if(mp.size() > 0){
                      parallel mp
                    }
                }
            }
        }
    }
    post {
      always {
        cleanWs()
        dir("${env.WORKSPACE}@tmp") {
          deleteDir()
        }
        dir("${env.WORKSPACE}@script") {
          deleteDir()
        }
        dir("${env.WORKSPACE}@script@tmp") {
          deleteDir()
        }
      }
    }
}