-
Notifications
You must be signed in to change notification settings - Fork 2
/
ftpcmd.y
1806 lines (1678 loc) · 36.2 KB
/
ftpcmd.y
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*-
* SPDX-License-Identifier: BSD-3-Clause
*
* Copyright (c) 1985, 1988, 1993, 1994
* The Regents of the University of California. All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the distribution.
* 3. Neither the name of the University nor the names of its contributors
* may be used to endorse or promote products derived from this software
* without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*/
/*
* Grammar for FTP commands.
* See RFC 959.
*/
%{
#include <sys/param.h>
#include <sys/socket.h>
#include <sys/stat.h>
#include <netinet/in.h>
#include <arpa/ftp.h>
#include <ctype.h>
#include <errno.h>
#include <glob.h>
#include <libutil.h>
#include <limits.h>
#include <md5.h>
#include <netdb.h>
#include <pwd.h>
#include <signal.h>
#include <stdint.h>
#include <stdio.h>
#include <stdlib.h>
#include <string.h>
#include <syslog.h>
#include <time.h>
#include <unistd.h>
#include "extern.h"
#include "pathnames.h"
#define yylex ftpcmd_yylex
off_t restart_point;
static int cmd_type;
static int cmd_form;
static int cmd_bytesz;
static int state;
char cbuf[512];
char *fromname = NULL;
%}
%union {
struct {
off_t o;
int i;
} u;
char *s;
}
%token
A B C E F I
L N P R S T
ALL
SP CRLF COMMA
USER PASS ACCT REIN QUIT PORT
PASV TYPE STRU MODE RETR STOR
APPE MLFL MAIL MSND MSOM MSAM
MRSQ MRCP ALLO REST RNFR RNTO
ABOR DELE CWD LIST NLST SITE
STAT HELP NOOP MKD RMD PWD
CDUP STOU SMNT SYST SIZE MDTM
LPRT LPSV EPRT EPSV FEAT
UMASK IDLE CHMOD MDFIVE
LEXERR NOTIMPL
%token <s> STRING
%token <u> NUMBER
%type <u.i> check_login octal_number byte_size
%type <u.i> check_login_ro check_login_epsv
%type <u.i> struct_code mode_code type_code form_code
%type <s> pathstring pathname password username
%type <s> ALL NOTIMPL
%start cmd_list
%%
cmd_list
: /* empty */
| cmd_list cmd
{
if (fromname)
free(fromname);
fromname = NULL;
restart_point = 0;
}
| cmd_list rcmd
;
cmd
: USER SP username CRLF
{
user($3);
free($3);
}
| PASS SP password CRLF
{
pass($3);
free($3);
}
| PASS CRLF
{
pass("");
}
| PORT check_login SP host_port CRLF
{
if (epsvall) {
reply(501, "No PORT allowed after EPSV ALL.");
goto port_done;
}
if (!$2)
goto port_done;
if (port_check("PORT") == 1)
goto port_done;
#ifdef INET6
if ((his_addr.su_family != AF_INET6 ||
!IN6_IS_ADDR_V4MAPPED(&his_addr.su_sin6.sin6_addr))) {
/* shoud never happen */
usedefault = 1;
reply(500, "Invalid address rejected.");
goto port_done;
}
port_check_v6("pcmd");
#endif
port_done:
;
}
| LPRT check_login SP host_long_port CRLF
{
if (epsvall) {
reply(501, "No LPRT allowed after EPSV ALL.");
goto lprt_done;
}
if (!$2)
goto lprt_done;
if (port_check("LPRT") == 1)
goto lprt_done;
#ifdef INET6
if (his_addr.su_family != AF_INET6) {
usedefault = 1;
reply(500, "Invalid address rejected.");
goto lprt_done;
}
if (port_check_v6("LPRT") == 1)
goto lprt_done;
#endif
lprt_done:
;
}
| EPRT check_login SP STRING CRLF
{
char delim;
char *tmp = NULL;
char *p, *q;
char *result[3];
struct addrinfo hints;
struct addrinfo *res;
int i;
if (epsvall) {
reply(501, "No EPRT allowed after EPSV ALL.");
goto eprt_done;
}
if (!$2)
goto eprt_done;
memset(&data_dest, 0, sizeof(data_dest));
tmp = strdup($4);
if (ftpdebug)
syslog(LOG_DEBUG, "%s", tmp);
if (!tmp) {
fatalerror("not enough core");
/*NOTREACHED*/
}
p = tmp;
delim = p[0];
p++;
memset(result, 0, sizeof(result));
for (i = 0; i < 3; i++) {
q = strchr(p, delim);
if (!q || *q != delim) {
parsefail:
reply(500,
"Invalid argument, rejected.");
if (tmp)
free(tmp);
usedefault = 1;
goto eprt_done;
}
*q++ = '\0';
result[i] = p;
if (ftpdebug)
syslog(LOG_DEBUG, "%d: %s", i, p);
p = q;
}
/* some more sanity check */
p = result[0];
while (*p) {
if (!isdigit(*p))
goto parsefail;
p++;
}
p = result[2];
while (*p) {
if (!isdigit(*p))
goto parsefail;
p++;
}
/* grab address */
memset(&hints, 0, sizeof(hints));
if (atoi(result[0]) == 1)
hints.ai_family = PF_INET;
#ifdef INET6
else if (atoi(result[0]) == 2)
hints.ai_family = PF_INET6;
#endif
else
hints.ai_family = PF_UNSPEC; /*XXX*/
hints.ai_socktype = SOCK_STREAM;
i = getaddrinfo(result[1], result[2], &hints, &res);
if (i)
goto parsefail;
memcpy(&data_dest, res->ai_addr, res->ai_addrlen);
#ifdef INET6
if (his_addr.su_family == AF_INET6
&& data_dest.su_family == AF_INET6) {
/* XXX more sanity checks! */
data_dest.su_sin6.sin6_scope_id =
his_addr.su_sin6.sin6_scope_id;
}
#endif
free(tmp);
tmp = NULL;
if (port_check("EPRT") == 1)
goto eprt_done;
#ifdef INET6
if (his_addr.su_family != AF_INET6) {
usedefault = 1;
reply(500, "Invalid address rejected.");
goto eprt_done;
}
if (port_check_v6("EPRT") == 1)
goto eprt_done;
#endif
eprt_done:
free($4);
}
| PASV check_login CRLF
{
if (epsvall)
reply(501, "No PASV allowed after EPSV ALL.");
else if ($2)
passive();
}
| LPSV check_login CRLF
{
if (epsvall)
reply(501, "No LPSV allowed after EPSV ALL.");
else if ($2)
long_passive("LPSV", PF_UNSPEC);
}
| EPSV check_login_epsv SP NUMBER CRLF
{
if ($2) {
int pf;
switch ($4.i) {
case 1:
pf = PF_INET;
break;
#ifdef INET6
case 2:
pf = PF_INET6;
break;
#endif
default:
pf = -1; /*junk value*/
break;
}
long_passive("EPSV", pf);
}
}
| EPSV check_login_epsv SP ALL CRLF
{
if ($2) {
reply(200, "EPSV ALL command successful.");
epsvall++;
}
}
| EPSV check_login_epsv CRLF
{
if ($2)
long_passive("EPSV", PF_UNSPEC);
}
| TYPE check_login SP type_code CRLF
{
if ($2) {
switch (cmd_type) {
case TYPE_A:
if (cmd_form == FORM_N) {
reply(200, "Type set to A.");
type = cmd_type;
form = cmd_form;
} else
reply(504, "Form must be N.");
break;
case TYPE_E:
reply(504, "Type E not implemented.");
break;
case TYPE_I:
reply(200, "Type set to I.");
type = cmd_type;
break;
case TYPE_L:
#if CHAR_BIT == 8
if (cmd_bytesz == 8) {
reply(200,
"Type set to L (byte size 8).");
type = cmd_type;
} else
reply(504, "Byte size must be 8.");
#else /* CHAR_BIT == 8 */
UNIMPLEMENTED for CHAR_BIT != 8
#endif /* CHAR_BIT == 8 */
}
}
}
| STRU check_login SP struct_code CRLF
{
if ($2) {
switch ($4) {
case STRU_F:
reply(200, "STRU F accepted.");
break;
default:
reply(504, "Unimplemented STRU type.");
}
}
}
| MODE check_login SP mode_code CRLF
{
if ($2) {
switch ($4) {
case MODE_S:
reply(200, "MODE S accepted.");
break;
default:
reply(502, "Unimplemented MODE type.");
}
}
}
| ALLO check_login SP NUMBER CRLF
{
if ($2) {
reply(202, "ALLO command ignored.");
}
}
| ALLO check_login SP NUMBER SP R SP NUMBER CRLF
{
if ($2) {
reply(202, "ALLO command ignored.");
}
}
| RETR check_login SP pathname CRLF
{
if (noretr || (guest && noguestretr))
reply(500, "RETR command disabled.");
else if ($2 && $4 != NULL)
retrieve(NULL, $4);
if ($4 != NULL)
free($4);
}
| STOR check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
store($4, "w", 0);
if ($4 != NULL)
free($4);
}
| APPE check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
store($4, "a", 0);
if ($4 != NULL)
free($4);
}
| NLST check_login CRLF
{
if ($2)
send_file_list(".");
}
| NLST check_login SP pathstring CRLF
{
if ($2)
send_file_list($4);
free($4);
}
| LIST check_login CRLF
{
if ($2)
retrieve(_PATH_LS " -lA", "");
}
| LIST check_login SP pathstring CRLF
{
if ($2)
retrieve(_PATH_LS " -lA %s", $4);
free($4);
}
| STAT check_login SP pathname CRLF
{
if ($2 && $4 != NULL)
statfilecmd($4);
if ($4 != NULL)
free($4);
}
| STAT check_login CRLF
{
if ($2) {
statcmd();
}
}
| DELE check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
delete($4);
if ($4 != NULL)
free($4);
}
| RNTO check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL) {
if (fromname) {
renamecmd(fromname, $4);
free(fromname);
fromname = NULL;
} else {
reply(503, "Bad sequence of commands.");
}
}
if ($4 != NULL)
free($4);
}
| ABOR check_login CRLF
{
if ($2)
reply(225, "ABOR command successful.");
}
| CWD check_login CRLF
{
if ($2) {
cwd(homedir);
}
}
| CWD check_login SP pathname CRLF
{
if ($2 && $4 != NULL)
cwd($4);
if ($4 != NULL)
free($4);
}
| HELP CRLF
{
help(cmdtab, NULL);
}
| HELP SP STRING CRLF
{
char *cp = $3;
if (strncasecmp(cp, "SITE", 4) == 0) {
cp = $3 + 4;
if (*cp == ' ')
cp++;
if (*cp)
help(sitetab, cp);
else
help(sitetab, NULL);
} else
help(cmdtab, $3);
free($3);
}
| NOOP CRLF
{
reply(200, "NOOP command successful.");
}
| MKD check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
makedir($4);
if ($4 != NULL)
free($4);
}
| RMD check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
removedir($4);
if ($4 != NULL)
free($4);
}
| PWD check_login CRLF
{
if ($2)
pwd();
}
| CDUP check_login CRLF
{
if ($2)
cwd("..");
}
| SITE SP HELP CRLF
{
help(sitetab, NULL);
}
| SITE SP HELP SP STRING CRLF
{
help(sitetab, $5);
free($5);
}
| SITE SP MDFIVE check_login SP pathname CRLF
{
char p[64], *q;
if ($4 && $6) {
q = MD5File($6, p);
if (q != NULL)
reply(200, "MD5(%s) = %s", $6, p);
else
perror_reply(550, $6);
}
if ($6)
free($6);
}
| SITE SP UMASK check_login CRLF
{
int oldmask;
if ($4) {
oldmask = umask(0);
(void) umask(oldmask);
reply(200, "Current UMASK is %03o.", oldmask);
}
}
| SITE SP UMASK check_login SP octal_number CRLF
{
int oldmask;
if ($4) {
if (($6 == -1) || ($6 > 0777)) {
reply(501, "Bad UMASK value.");
} else {
oldmask = umask($6);
reply(200,
"UMASK set to %03o (was %03o).",
$6, oldmask);
}
}
}
| SITE SP CHMOD check_login_ro SP octal_number SP pathname CRLF
{
if ($4 && ($8 != NULL)) {
if (($6 == -1 ) || ($6 > 0777))
reply(501, "Bad mode value.");
else if (chmod($8, $6) < 0)
perror_reply(550, $8);
else
reply(200, "CHMOD command successful.");
}
if ($8 != NULL)
free($8);
}
| SITE SP check_login IDLE CRLF
{
if ($3)
reply(200,
"Current IDLE time limit is %d seconds; max %d.",
timeout, maxtimeout);
}
| SITE SP check_login IDLE SP NUMBER CRLF
{
if ($3) {
if ($6.i < 30 || $6.i > maxtimeout) {
reply(501,
"Maximum IDLE time must be between 30 and %d seconds.",
maxtimeout);
} else {
timeout = $6.i;
(void) alarm(timeout);
reply(200,
"Maximum IDLE time set to %d seconds.",
timeout);
}
}
}
| STOU check_login_ro SP pathname CRLF
{
if ($2 && $4 != NULL)
store($4, "w", 1);
if ($4 != NULL)
free($4);
}
| FEAT CRLF
{
lreply(211, "Extensions supported:");
#if 0
/* XXX these two keywords are non-standard */
printf(" EPRT\r\n");
if (!noepsv)
printf(" EPSV\r\n");
#endif
printf(" MDTM\r\n");
printf(" REST STREAM\r\n");
printf(" SIZE\r\n");
if (assumeutf8) {
/* TVFS requires UTF8, see RFC 3659 */
printf(" TVFS\r\n");
printf(" UTF8\r\n");
}
reply(211, "End.");
}
| SYST check_login CRLF
{
if ($2) {
if (hostinfo)
#ifdef BSD
reply(215, "UNIX Type: L%d Version: BSD-%d",
CHAR_BIT, BSD);
#else /* BSD */
reply(215, "UNIX Type: L%d", CHAR_BIT);
#endif /* BSD */
else
reply(215, "UNKNOWN Type: L%d", CHAR_BIT);
}
}
/*
* SIZE is not in RFC959, but Postel has blessed it and
* it will be in the updated RFC.
*
* Return size of file in a format suitable for
* using with RESTART (we just count bytes).
*/
| SIZE check_login SP pathname CRLF
{
if ($2 && $4 != NULL)
sizecmd($4);
if ($4 != NULL)
free($4);
}
/*
* MDTM is not in RFC959, but Postel has blessed it and
* it will be in the updated RFC.
*
* Return modification time of file as an ISO 3307
* style time. E.g. YYYYMMDDHHMMSS or YYYYMMDDHHMMSS.xxx
* where xxx is the fractional second (of any precision,
* not necessarily 3 digits)
*/
| MDTM check_login SP pathname CRLF
{
if ($2 && $4 != NULL) {
struct stat stbuf;
if (stat($4, &stbuf) < 0)
perror_reply(550, $4);
else if (!S_ISREG(stbuf.st_mode)) {
reply(550, "%s: not a plain file.", $4);
} else {
struct tm *t;
t = gmtime(&stbuf.st_mtime);
reply(213,
"%04d%02d%02d%02d%02d%02d",
1900 + t->tm_year,
t->tm_mon+1, t->tm_mday,
t->tm_hour, t->tm_min, t->tm_sec);
}
}
if ($4 != NULL)
free($4);
}
| QUIT CRLF
{
reply(221, "Goodbye.");
dologout(0);
}
| NOTIMPL
{
nack($1);
}
| error
{
yyclearin; /* discard lookahead data */
yyerrok; /* clear error condition */
state = CMD; /* reset lexer state */
}
;
rcmd
: RNFR check_login_ro SP pathname CRLF
{
restart_point = 0;
if ($2 && $4) {
if (fromname)
free(fromname);
fromname = NULL;
if (renamefrom($4))
fromname = $4;
else
free($4);
} else if ($4) {
free($4);
}
}
| REST check_login SP NUMBER CRLF
{
if ($2) {
if (fromname)
free(fromname);
fromname = NULL;
restart_point = $4.o;
reply(350, "Restarting at %jd. %s",
(intmax_t)restart_point,
"Send STORE or RETRIEVE to initiate transfer.");
}
}
;
username
: STRING
;
password
: /* empty */
{
$$ = (char *)calloc(1, sizeof(char));
}
| STRING
;
byte_size
: NUMBER
{
$$ = $1.i;
}
;
host_port
: NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER
{
char *a, *p;
data_dest.su_len = sizeof(struct sockaddr_in);
data_dest.su_family = AF_INET;
p = (char *)&data_dest.su_sin.sin_port;
p[0] = $9.i; p[1] = $11.i;
a = (char *)&data_dest.su_sin.sin_addr;
a[0] = $1.i; a[1] = $3.i; a[2] = $5.i; a[3] = $7.i;
}
;
host_long_port
: NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER
{
char *a, *p;
memset(&data_dest, 0, sizeof(data_dest));
data_dest.su_len = sizeof(struct sockaddr_in6);
data_dest.su_family = AF_INET6;
p = (char *)&data_dest.su_port;
p[0] = $39.i; p[1] = $41.i;
a = (char *)&data_dest.su_sin6.sin6_addr;
a[0] = $5.i; a[1] = $7.i; a[2] = $9.i; a[3] = $11.i;
a[4] = $13.i; a[5] = $15.i; a[6] = $17.i; a[7] = $19.i;
a[8] = $21.i; a[9] = $23.i; a[10] = $25.i; a[11] = $27.i;
a[12] = $29.i; a[13] = $31.i; a[14] = $33.i; a[15] = $35.i;
if (his_addr.su_family == AF_INET6) {
/* XXX more sanity checks! */
data_dest.su_sin6.sin6_scope_id =
his_addr.su_sin6.sin6_scope_id;
}
if ($1.i != 6 || $3.i != 16 || $37.i != 2)
memset(&data_dest, 0, sizeof(data_dest));
}
| NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER COMMA NUMBER COMMA NUMBER COMMA NUMBER COMMA
NUMBER
{
char *a, *p;
memset(&data_dest, 0, sizeof(data_dest));
data_dest.su_sin.sin_len = sizeof(struct sockaddr_in);
data_dest.su_family = AF_INET;
p = (char *)&data_dest.su_port;
p[0] = $15.i; p[1] = $17.i;
a = (char *)&data_dest.su_sin.sin_addr;
a[0] = $5.i; a[1] = $7.i; a[2] = $9.i; a[3] = $11.i;
if ($1.i != 4 || $3.i != 4 || $13.i != 2)
memset(&data_dest, 0, sizeof(data_dest));
}
;
form_code
: N
{
$$ = FORM_N;
}
| T
{
$$ = FORM_T;
}
| C
{
$$ = FORM_C;
}
;
type_code
: A
{
cmd_type = TYPE_A;
cmd_form = FORM_N;
}
| A SP form_code
{
cmd_type = TYPE_A;
cmd_form = $3;
}
| E
{
cmd_type = TYPE_E;
cmd_form = FORM_N;
}
| E SP form_code
{
cmd_type = TYPE_E;
cmd_form = $3;
}
| I
{
cmd_type = TYPE_I;
}
| L
{
cmd_type = TYPE_L;
cmd_bytesz = CHAR_BIT;
}
| L SP byte_size
{
cmd_type = TYPE_L;
cmd_bytesz = $3;
}
/* this is for a bug in the BBN ftp */
| L byte_size
{
cmd_type = TYPE_L;
cmd_bytesz = $2;
}
;
struct_code
: F
{
$$ = STRU_F;
}
| R
{
$$ = STRU_R;
}
| P
{
$$ = STRU_P;
}
;
mode_code
: S
{
$$ = MODE_S;
}
| B
{
$$ = MODE_B;
}
| C
{
$$ = MODE_C;
}
;
pathname
: pathstring
{
if (logged_in && $1) {
char *p;
/*
* Expand ~user manually since glob(3)
* will return the unexpanded pathname
* if the corresponding file/directory
* doesn't exist yet. Using sole glob(3)
* would break natural commands like
* MKD ~user/newdir
* or
* RNTO ~/newfile
*/
if ((p = exptilde($1)) != NULL) {
$$ = expglob(p);
free(p);
} else
$$ = NULL;
free($1);
} else
$$ = $1;
}
;
pathstring
: STRING
;
octal_number
: NUMBER
{
int ret, dec, multby, digit;
/*
* Convert a number that was read as decimal number
* to what it would be if it had been read as octal.
*/
dec = $1.i;
multby = 1;
ret = 0;
while (dec) {
digit = dec%10;
if (digit > 7) {
ret = -1;
break;
}
ret += digit * multby;
multby *= 8;
dec /= 10;
}
$$ = ret;
}