Initial commit

Author: daggerok

.gitignore

@@ -0,0 +1,13 @@
+.idea/
+*.iml
+*.ipr
+*.iws
+*.log*
+out/
+build/
+target/
+.gradle/
+.settings/
+.project
+.classpath
+.DS_Store

.travis.yml

@@ -0,0 +1,37 @@
+notifications:
+  email: false
+
+git:
+  depth: false
+  quiet: true
+
+language: java
+jdk: oraclejdk8
+node_js: lts/*
+
+addons:
+  apt:
+    packages:
+      - bash
+      - tree
+
+env:
+  global:
+    - TERM=dumb
+
+install: true
+before_install:
+  - sudo apt-get update -yqq
+
+script:
+  - ./gradlew check -PignoreBugs
+  - tree ./build/spotbugs
+  #
+  - ./gradlew clean
+  - ./gradlew check || echo 'error expected.'
+  - tree ./build/spotbugs
+
+cache:
+  packages: true
+  directories:
+    - ${HOME}/.gradle

README.md

@@ -0,0 +1,79 @@
+# spotbugs gradle multi-project build [![Build Status](https://travis-ci.org/daggerok/spotbugs-gradle-plugin-multi-project-example.svg?branch=master)](https://travis-ci.org/daggerok/spotbugs-gradle-plugin-multi-project-example)
+Example of usage `spotbugs-gradle-plugin` (findbugs replacement) with HTML reports enabled in multi module Gradle project
+
+config:
+
+`build.gradle` file:
+
+```gradle
+buildscript {
+  ext {
+    spotbugsVersion = '1.6.8'
+    toolVersion = '3.1.10'
+  }
+}
+
+plugins { 
+  id 'com.github.spotbugs' version '1.6.8' apply false
+}
+
+apply from: "$rootProject.projectDir/gradle/spotbugs.gradle"
+
+defaultTasks 'clean', 'check'
+```
+
+`gradle/spotbugs.gradle` file:
+
+```gradle
+buildscript {
+  repositories {
+    maven { url "https://plugins.gradle.org/m2/" }
+  }
+  dependencies {
+    classpath "gradle.plugin.com.github.spotbugs:spotbugs-gradle-plugin:$spotbugsVersion"
+  }
+}
+
+subprojects {
+  apply plugin: "com.github.spotbugs"
+
+  repositories {
+    maven { url "https://plugins.gradle.org/m2/" }
+  }
+
+  spotbugs {
+    toolVersion = project.toolVersion
+    effort = "max"
+    ignoreFailures = project.findProperty('ignoreBugs') != null
+  }
+
+  tasks.withType(com.github.spotbugs.SpotBugsTask) {
+    reports {
+      html {
+        enabled = true
+      }
+      xml {
+        enabled = false
+      }
+    }
+  }
+}
+```
+
+versions:
+
+- gradle: 5.1
+- spotbugs-gradle-plugin: 1.6.8
+- tool: 3.1.10
+
+usage:
+
+```bash
+./gradlew               # to be failed
+./gradlew -PignoreBugs  # do not failed on found bugs
+```
+
+links:
+
+- [spotbugs gradle plugin html report in multi-project issue](https://github.com/spotbugs/spotbugs-gradle-plugin/issues/32)
+- [not generates HTML report when lombok gradle plugin enabled issue](https://github.com/spotbugs/spotbugs-gradle-plugin/issues/94)

build.gradle

@@ -0,0 +1,31 @@
+buildscript {
+  ext {
+    spotbugsVersion = '1.6.8'
+    toolVersion = '3.1.10'
+
+    javaVersion = JavaVersion.VERSION_1_8
+    lombokVersion = '1.18.4'
+    logbackVersion = '1.2.3'
+    slf4jVersion = '1.7.25'
+    vavrVersion = '0.9.2'
+
+    junitPlatformVersion = '1.3.0'
+    junitJupiterVersion = '5.3.1'
+    assertjVersion = '3.11.1'
+    hamcrestVersion = '2.1'
+    junit4Version = '4.12'
+  }
+}
+
+plugins { 
+  id 'com.github.spotbugs' version '1.6.8' apply false
+//  // one more bug: 
+//  // SpotBugs HTML reports not working (generates XML instead)
+//  // when gradle lombok plugin also applied
+//  id 'io.franzbecker.gradle-lombok' version '1.14' apply false
+}
+
+apply from: "$rootProject.projectDir/gradle/java.gradle"
+apply from: "$rootProject.projectDir/gradle/spotbugs.gradle"
+
+defaultTasks 'clean', 'check'

gradle/java.gradle

@@ -0,0 +1,46 @@
+allprojects {
+  apply plugin: 'java'
+
+  clean.doFirst {
+    delete "$project.buildDir"
+  }
+}
+
+subprojects {
+//  // one more bug:
+//  // SpotBugs HTML reports not working (generates XML instead)
+//  // when gradle lombok plugin also applied
+//  apply plugin: 'io.franzbecker.gradle-lombok'
+//  lombok.version = project.lombokVersion
+
+  version = project.findProperty('org.gradle.project.version') ?: '1.0.0-SNAPSHOT'
+  group = 'com.github.daggerok'
+  sourceCompatibility = targetCompatibility = "$javaVersion"
+
+  defaultTasks 'clean', 'check'
+
+  dependencies {
+    implementation "org.slf4j:slf4j-api:$slf4jVersion"
+    implementation "ch.qos.logback:logback-classic:$logbackVersion"
+
+    // test
+    testImplementation "junit:junit:$junit4Version"
+    testImplementation "org.assertj:assertj-core:$assertjVersion"
+    testImplementation "org.hamcrest:hamcrest-core:$hamcrestVersion"
+    testImplementation "org.junit.jupiter:junit-jupiter-api:$junitJupiterVersion"
+    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitJupiterVersion"
+    testRuntimeOnly "org.junit.vintage:junit-vintage-engine:$junitJupiterVersion", {
+      because 'allows JUnit 3 and JUnit 4 tests to run'
+    }
+    testRuntime "org.junit.platform:junit-platform-launcher:$junitPlatformVersion", {
+      because 'allows tests to run from IDEs that bundle older version of launcher'
+    }
+    testCompileOnly 'org.apiguardian:apiguardian-api:1.0.0'
+  }
+
+  test {
+    useJUnitPlatform {
+      includeEngines 'junit-jupiter', 'junit-vintage'
+    }
+  }
+}

gradle/spotbugs.gradle

@@ -0,0 +1,43 @@
+buildscript {
+  repositories {
+    maven { url "https://plugins.gradle.org/m2/" }
+  }
+  dependencies {
+    classpath "gradle.plugin.com.github.spotbugs:spotbugs-gradle-plugin:$spotbugsVersion"
+  }
+}
+
+subprojects {
+  apply plugin: "com.github.spotbugs"
+  
+  repositories {
+    maven { url "https://plugins.gradle.org/m2/" }
+  }
+  
+  def suffix = project.path.replaceAll(':', '-').replaceFirst('-', '')
+  def prefix = rootProject.buildDir.absolutePath
+  def path = "$prefix/spotbugs/$suffix" // customize reports location
+
+  spotbugs {
+    toolVersion = project.toolVersion
+    effort = "max"
+    reportsDir = file("$path")
+    ignoreFailures = project.findProperty('ignoreBugs') != null // gradle -PignoreBugs ..
+  }
+
+  tasks.withType(com.github.spotbugs.SpotBugsTask) {
+    reports {
+      html {
+        enabled = true
+        impliesSubProjects = true
+//        // disabled on 1.6.8
+//        destination = "$path/index.html"
+      }
+      xml {
+        enabled = false
+      }
+    }
+//    pluginClasspath = project.configurations.spotbugsPlugins
+  }
+}
+

gradle/wrapper/gradle-wrapper.jar

@@ -0,0 +1,5 @@
+distributionBase=GRADLE_USER_HOME
+distributionPath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-5.1-bin.zip
+zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists