build.gradle

plugins {
    id "io.github.goooler.shadow" version "8.1.8" apply false
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.7-SNAPSHOT" apply false
    id "net.neoforged.licenser" version "0.7.+" apply false
    id "io.github.p03w.machete" version "2.+" apply false
}

architectury {
    minecraft = rootProject.minecraft_version
}

subprojects {
    apply plugin: "dev.architectury.loom"
    apply plugin: "io.github.p03w.machete"
    apply plugin: "net.neoforged.licenser"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.layered() {
            officialMojangMappings()
            parchment("org.parchmentmc.data:parchment-${rootProject.minecraft_version}:${rootProject.parchment_version}@zip")
        }
    }

    machete {
        ignoredTasks.add("shadowJar")
        ignoredTasks.add("jar")
    }

    license {
        header = rootProject.file('HEADER')
        skipExistingHeaders = false

        tasks {
            oe {
                files.from rootProject.fileTree("src", {
                    include "**/*.java"
                })
            }
        }
    }

    processResources {
        // inputs.property "project", project

        filesMatching(["META-INF/mods.toml", "fabric.mod.json"]) {
            expand "project": project
        }
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.archives_base_name
    version = "${rootProject.mod_version}+mc${rootProject.minecraft_version}-${project.name}"
    group = rootProject.maven_group

    repositories {
        maven {
            name "NeoForged"
            url "https://maven.neoforged.net/releases"
            content {
                excludeGroupByRegex "org.parchmentmc"
            }
        }
        maven {
            name "ParchmentMC"
            url "https://maven.parchmentmc.org"
        }
        maven {
            url "https://maven.shedaniel.me"
        }
        maven {
            url "https://maven.terraformersmc.com/releases"
        }

        // Additional repos
        maven {
            name "Modrinth"
            url "https://api.modrinth.com/maven"

            content {
                includeGroup "maven.modrinth"
            }
        }
        maven {
            name "KosmX's maven"
            url "https://maven.kosmx.dev"
        }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
        options.release.set(17)
    }

    java {
        withSourcesJar()
    }

    publishing {
        repositories {
        }
    }
}