Add Gleam integration with Mix

- Add Mix.Gleam module
- Add specific gleam binary version requirement
- Rely on `gleam export package-info`

Author: Rodrigo Álvarez

lib/mix/lib/mix/dep.ex

@@ -27,7 +27,7 @@ defmodule Mix.Dep do
     * `top_level` - true if dependency was defined in the top-level project
 
     * `manager` - the project management, possible values:
-      `:rebar3` | `:mix` | `:make` | `nil`
+      `:rebar3` | `:mix` | `:make` | `:gleam' | `nil`
 
     * `from` - path to the file where the dependency was defined
 
@@ -73,7 +73,7 @@ defmodule Mix.Dep do
           status: {:ok, String.t() | nil} | atom | tuple,
           opts: keyword,
           top_level: boolean,
-          manager: :rebar3 | :mix | :make | nil,
+          manager: :rebar3 | :mix | :make | :gleam | nil,
           from: String.t(),
           extra: term,
           system_env: keyword
@@ -535,6 +535,13 @@ defmodule Mix.Dep do
     manager == :make
   end
 
+  @doc """
+  Returns `true` if dependency is a Gleam project.
+  """
+  def gleam?(%Mix.Dep{manager: manager}) do
+    manager == :gleam
+  end
+
   ## Helpers
 
   defp mix_env_var do

lib/mix/lib/mix/dep/converger.ex

@@ -426,7 +426,7 @@ defmodule Mix.Dep.Converger do
     %{other | manager: sort_manager(other_manager, manager, in_upper?)}
   end
 
-  @managers [:mix, :rebar3, :make]
+  @managers [:mix, :rebar3, :make, :gleam]
 
   defp sort_manager(other_manager, manager, true) do
     other_manager || manager

lib/mix/lib/mix/dep/loader.ex

@@ -8,7 +8,7 @@
 defmodule Mix.Dep.Loader do
   @moduledoc false
 
-  import Mix.Dep, only: [ok?: 1, mix?: 1, rebar?: 1, make?: 1]
+  import Mix.Dep, only: [ok?: 1, mix?: 1, rebar?: 1, make?: 1, gleam?: 1]
 
   @doc """
   Gets all direct children of the current `Mix.Project`
@@ -84,9 +84,9 @@ defmodule Mix.Dep.Loader do
   def load(%Mix.Dep{manager: manager, scm: scm, opts: opts} = dep, children, locked?) do
     # The manager for a child dependency is set based on the following rules:
     #   1. Set in dependency definition
-    #   2. From SCM, so that Hex dependencies of a rebar project can be compiled with mix
+    #   2. From SCM, so that Hex dependencies of a rebar/gleam project can be compiled with mix
     #   3. From the parent dependency, used for rebar dependencies from git
-    #   4. Inferred from files in dependency (mix.exs, rebar.config, Makefile)
+    #   4. Inferred from files in dependency (mix.exs, rebar.config, Makefile, gleam.toml)
     manager = opts[:manager] || scm_manager(scm, opts) || manager || infer_manager(opts[:dest])
     dep = %{dep | manager: manager, status: scm_status(scm, opts)}
 
@@ -106,6 +106,9 @@ defmodule Mix.Dep.Loader do
         make?(dep) ->
           make_dep(dep)
 
+        gleam?(dep) ->
+          gleam_dep(dep, children, locked?)
+
         true ->
           {dep, []}
       end
@@ -220,7 +223,7 @@ defmodule Mix.Dep.Loader do
 
   # Note that we ignore Make dependencies because the
   # file based heuristic will always figure it out.
-  @scm_managers ~w(mix rebar3)a
+  @scm_managers ~w(mix rebar3 gleam)a
 
   defp scm_manager(scm, opts) do
     managers = scm.managers(opts)
@@ -246,6 +249,9 @@ defmodule Mix.Dep.Loader do
       any_of?(dest, ["Makefile", "Makefile.win"]) ->
         :make
 
+      any_of?(dest, ["gleam.toml"]) ->
+        :gleam
+
       true ->
         nil
     end
@@ -361,6 +367,21 @@ defmodule Mix.Dep.Loader do
     {dep, []}
   end
 
+  defp gleam_dep(%Mix.Dep{opts: opts} = dep, children, locked?) do
+    Mix.Gleam.require!()
+
+    deps =
+      if children do
+        Enum.map(children, &to_dep(&1, opts[:dest], _manager = nil, locked?))
+      else
+        config = File.cd!(opts[:dest], fn -> Mix.Gleam.load_config(".") end)
+        from = Path.join(opts[:dest], "gleam.toml")
+        Enum.map(config[:deps], &to_dep(&1, from, _manager = nil, locked?))
+      end
+
+    {%{dep | opts: Keyword.merge(opts, app: false, override: true)}, deps}
+  end
+
   defp mix_children(config, locked?, opts) do
     from = Mix.Project.project_file()
 

lib/mix/lib/mix/gleam.ex

@@ -0,0 +1,92 @@
+defmodule Mix.Gleam do
+  @required_gleam_version ">= 1.9.0"
+
+  def load_config(dir) do
+    File.cd!(dir, fn ->
+      gleam!(["export", "package-info", "--out", "/dev/stdout"])
+      |> JSON.decode!()
+      |> parse_config()
+    end)
+  end
+
+  def parse_config(json) do
+    try do
+      deps =
+        Map.get(json, "dependencies", %{})
+        |> Enum.map(&parse_dep/1)
+
+      dev_deps =
+        Map.get(json, "dev-dependencies", %{})
+        |> Enum.map(&parse_dep(&1, only: :dev))
+
+      %{
+        name: Map.fetch!(json, "name"),
+        version: Map.fetch!(json, "version"),
+        deps: deps ++ dev_deps
+      }
+      |> maybe_gleam_version(json["gleam"])
+    rescue
+      KeyError ->
+        Mix.raise("Command \"gleam export package-info\" unexpected format: \n" <> json)
+    end
+  end
+
+  defp parse_dep({dep, requirement}, opts \\ []) do
+    dep = String.to_atom(dep)
+
+    spec =
+      case requirement do
+        %{"version" => version} -> {dep, version, opts}
+        %{"path" => path} -> {dep, Keyword.merge(opts, path: path)}
+      end
+
+    case spec do
+      {dep, version, []} -> {dep, version}
+      spec -> spec
+    end
+  end
+
+  defp maybe_gleam_version(config, nil), do: config
+
+  defp maybe_gleam_version(config, version) do
+    Map.put(config, :gleam, version)
+  end
+
+  def require!() do
+    available_version()
+    |> Version.match?(@required_gleam_version)
+  end
+
+  defp available_version do
+    try do
+      case gleam!(["--version"]) do
+        "gleam " <> version -> Version.parse!(version) |> Version.to_string()
+        output -> Mix.raise("Command \"gleam --version\" unexpected format: #{output}")
+      end
+    rescue
+      e in Version.InvalidVersionError ->
+        Mix.raise("Command \"gleam --version\" invalid version format: #{e.version}")
+    end
+  end
+
+  defp gleam!(args) do
+    try do
+      System.cmd("gleam", args)
+    catch
+      :error, :enoent ->
+        Mix.raise(
+          "The \"gleam\" executable is not available in your PATH. " <>
+            "Please install it, as one of your dependencies requires it. "
+        )
+    else
+      {response, 0} ->
+        String.trim(response)
+
+      {response, _} when is_binary(response) ->
+        Mix.raise("Command \"gleam #{Enum.join(args, " ")}\" failed with reason: #{response}")
+
+      {_, _} ->
+        Mix.raise("Command \"gleam #{Enum.join(args, " ")}\" failed")
+    end
+  end
+end

lib/mix/lib/mix/task.compiler.ex

@@ -80,7 +80,7 @@ defmodule Mix.Task.Compiler do
         * `:scm` - the SCM module of the dependency.
 
         * `:manager` - the dependency project management, possible values:
-          `:rebar3`, `:mix`, `:make`, `nil`.
+          `:rebar3`, `:mix`, `:make`, `:gleam`, `nil`.
 
         * `:os_pid` - the operating system PID of the process that run
           the compilation. The value is a string and it can be compared

lib/mix/lib/mix/tasks/deps.compile.ex

@@ -22,6 +22,7 @@ defmodule Mix.Tasks.Deps.Compile do
     * `Makefile.win`- invokes `nmake /F Makefile.win` (only on Windows)
     * `Makefile` - invokes `gmake` on DragonFlyBSD, FreeBSD, NetBSD, and OpenBSD,
       invokes `make` on any other operating system (except on Windows)
+    * `gleam.toml` - invokes `gleam export`
 
   The compilation can be customized by passing a `compile` option
   in the dependency:
@@ -101,9 +102,12 @@ defmodule Mix.Tasks.Deps.Compile do
             dep.manager == :rebar3 ->
               do_rebar3(dep, config)
 
+            dep.manager == :gleam ->
+              do_gleam(dep, config)
+
             true ->
               shell.error(
-                "Could not compile #{inspect(app)}, no \"mix.exs\", \"rebar.config\" or \"Makefile\" " <>
+                "Could not compile #{inspect(app)}, no \"mix.exs\", \"rebar.config\", \"Makefile\" or \"gleam.toml\" " <>
                   "(pass :compile as an option to customize compilation, set it to \"false\" to do nothing)"
               )
 
@@ -296,6 +300,21 @@ defmodule Mix.Tasks.Deps.Compile do
     true
   end
 
+  defp do_gleam(%Mix.Dep{opts: opts} = dep, config) do
+    Mix.Gleam.require!()
+
+    lib = Path.join(Mix.Project.build_path(), "lib")
+    out = opts[:build]
+    package = opts[:dest]
+
+    command =
+      {"gleam",
+       ["compile-package", "--target", "erlang", "--package", package, "--out", out, "--lib", lib]}
+
+    shell_cmd!(dep, config, command)
+    Code.prepend_path(Path.join(out, "ebin"), cache: true)
+  end
+
   defp make_command(dep) do
     makefile_win? = makefile_win?(dep)
 

lib/mix/lib/mix/tasks/deps.ex

@@ -101,10 +101,10 @@ defmodule Mix.Tasks.Deps do
     * `:override` - if set to `true` the dependency will override any other
       definitions of itself by other dependencies
 
-    * `:manager` - Mix can also compile Rebar3 and makefile projects
+    * `:manager` - Mix can also compile Rebar3, makefile and gleam projects
       and can fetch sub dependencies of Rebar3 projects. Mix will
       try to infer the type of project but it can be overridden with this
-      option by setting it to `:mix`, `:rebar3`, or `:make`. In case
+      option by setting it to `:mix`, `:rebar3`, `:make` or `:gleam`. In case
       there are conflicting definitions, the first manager in the list above
       will be picked up. For example, if a dependency is found with `:rebar3`
       as a manager in different part of the trees, `:rebar3` will be automatically

lib/mix/test/mix/gleam_test.exs

@@ -0,0 +1,93 @@
+# SPDX-License-Identifier: Apache-2.0
+# SPDX-FileCopyrightText: 2021 The Elixir Team
+# SPDX-FileCopyrightText: 2012 Plataformatec
+
+Code.require_file("../test_helper.exs", __DIR__)
+
+defmodule Mix.GleamTest do
+  use MixTest.Case
+
+  @compile {:no_warn_undefined, [:gleam_dep, :gleam@int]}
+
+  defmodule GleamAsDep do
+    def project do
+      [
+        app: :gleam_as_dep,
+        version: "0.1.0",
+        deps: [
+          {:gleam_dep, path: MixTest.Case.tmp_path("gleam_dep"), app: false}
+        ]
+      ]
+    end
+  end
+
+  describe "load_config/1" do
+    test "loads gleam.toml" do
+      path = MixTest.Case.fixture_path("gleam_dep")
+      config = Mix.Gleam.load_config(path)
+
+      expected = [
+        {:gleam_stdlib, ">= 0.44.0 and < 2.0.0"},
+        {:gleam_otp, ">= 0.16.1 and < 1.0.0"},
+        {:gleeunit, ">= 1.0.0 and < 2.0.0", only: :dev}
+      ]
+
+      assert Enum.sort(config[:deps]) == Enum.sort(expected)
+    end
+  end
+
+  describe "gleam export package-info format" do
+    test "parse_config" do
+      config =
+        %{
+          "name" => "gael",
+          "version" => "1.0.0",
+          "gleam" => ">= 1.8.0",
+          "dependencies" => %{
+            "gleam_stdlib" => %{"version" => ">= 0.18.0 and < 2.0.0"},
+            "my_other_project" => %{"path" => "../my_other_project"}
+          },
+          "dev-dependencies" => %{"gleeunit" => %{"version" => ">= 1.0.0 and < 2.0.0"}}
+        }
+        |> Mix.Gleam.parse_config()
+
+      assert config == %{
+               name: "gael",
+               version: "1.0.0",
+               gleam: ">= 1.8.0",
+               deps: [
+                 {:gleam_stdlib, ">= 0.18.0 and < 2.0.0"},
+                 {:my_other_project, path: "../my_other_project"},
+                 {:gleeunit, ">= 1.0.0 and < 2.0.0", only: :dev}
+               ]
+             }
+    end
+  end
+
+  describe "integration with Mix" do
+    test "gets and compiles dependencies" do
+      in_tmp("get and compile dependencies", fn ->
+        Mix.Project.push(GleamAsDep)
+
+        Mix.Tasks.Deps.Get.run([])
+        assert_received {:mix_shell, :info, ["* Getting gleam_stdlib " <> _]}
+        assert_received {:mix_shell, :info, ["* Getting gleam_otp " <> _]}
+        assert_received {:mix_shell, :info, ["* Getting gleeunit " <> _]}
+
+        Mix.Tasks.Deps.Compile.run([])
+        assert :gleam_dep.main()
+        assert :gleam@int.to_string(1) == "1"
+
+        load_paths =
+          Mix.Dep.Converger.converge([])
+          |> Enum.map(&Mix.Dep.load_paths(&1))
+          |> Enum.concat()
+
+        assert Enum.any?(load_paths, &String.ends_with?(&1, "gleam_dep/ebin"))
+        assert Enum.any?(load_paths, &String.ends_with?(&1, "gleam_stdlib/ebin"))
+        # Dep of a dep
+        assert Enum.any?(load_paths, &String.ends_with?(&1, "gleam_erlang/ebin"))
+      end)
+    end
+  end
+end