build.gradle

plugins {
    id 'java-library'
}

allprojects {
    version = mod_version
    group = mod_group_id
}

base {
    archivesName = mod_id
}

repositories {
    maven { url "https://maven.neoforged.net/releases" }
    maven { url "https://libraries.minecraft.net/" }
}

configurations {
    jij {}
}

dependencies {
    compileOnly("net.neoforged.fancymodloader:loader:${fancy_mod_loader_version}")
    compileOnly("cpw.mods:securejarhandler:3.0.8")
    compileOnly("org.jetbrains:annotations:24.1.0")
    jij(project(path: ":mod", configuration: "builtModJar"))
}

jar {
    manifest {
        attributes["FMLModType"] = "LIBRARY"
        attributes["Automatic-Module-Name"] = "monocle_locator"
    }
    into("META-INF/mod") {
        from(configurations.jij) {
            rename { String filename ->
                return "monocle-mod-file.jar"
            }
        }
    }
}

tasks.named('wrapper', Wrapper).configure {
    // Define wrapper values here so as to not have to always do so when updating gradlew.properties.
    // Switching this to Wrapper.DistributionType.ALL will download the full gradle sources that comes with
    // documentation attached on cursor hover of gradle classes and methods. However, this comes with increased
    // file size for Gradle. If you do switch this to ALL, run the Gradle wrapper task twice afterwards.
    // (Verify by checking gradle/wrapper/gradle-wrapper.properties to see if distributionUrl now points to `-all`)
    distributionType = Wrapper.DistributionType.BIN
}