Removed superfluous copy operations in iOS flutter platform messages.

Author: gaaclarke

shell/platform/darwin/common/buffer_conversions.h

@@ -13,13 +13,9 @@
 
 namespace flutter {
 
-std::vector<uint8_t> GetVectorFromNSData(NSData* data);
+std::vector<uint8_t> CopyNSDataToVector(NSData* data);
 
-NSData* GetNSDataFromVector(const std::vector<uint8_t>& buffer);
-
-std::unique_ptr<fml::Mapping> GetMappingFromNSData(NSData* data);
-
-NSData* GetNSDataFromMapping(std::unique_ptr<fml::Mapping> mapping);
+std::unique_ptr<fml::Mapping> CopyNSDataToMapping(NSData* data);
 
 }  // namespace flutter
 

shell/platform/darwin/common/buffer_conversions.mm

@@ -6,21 +6,13 @@
 
 namespace flutter {
 
-std::vector<uint8_t> GetVectorFromNSData(NSData* data) {
+std::vector<uint8_t> CopyNSDataToVector(NSData* data) {
   const uint8_t* bytes = reinterpret_cast<const uint8_t*>(data.bytes);
   return std::vector<uint8_t>(bytes, bytes + data.length);
 }
 
-NSData* GetNSDataFromVector(const std::vector<uint8_t>& buffer) {
-  return [NSData dataWithBytes:buffer.data() length:buffer.size()];
-}
-
-std::unique_ptr<fml::Mapping> GetMappingFromNSData(NSData* data) {
-  return std::make_unique<fml::DataMapping>(GetVectorFromNSData(data));
-}
-
-NSData* GetNSDataFromMapping(std::unique_ptr<fml::Mapping> mapping) {
-  return [NSData dataWithBytes:mapping->GetMapping() length:mapping->GetSize()];
+std::unique_ptr<fml::Mapping> CopyNSDataToMapping(NSData* data) {
+  return std::make_unique<fml::DataMapping>(CopyNSDataToVector(data));
 }
 
 }  // namespace flutter

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -807,7 +807,7 @@ - (void)sendOnChannel:(NSString*)channel
   fml::RefPtr<flutter::PlatformMessage> platformMessage =
       (message == nil) ? fml::MakeRefCounted<flutter::PlatformMessage>(channel.UTF8String, response)
                        : fml::MakeRefCounted<flutter::PlatformMessage>(
-                             channel.UTF8String, flutter::GetVectorFromNSData(message), response);
+                             channel.UTF8String, flutter::CopyNSDataToVector(message), response);
 
   _shell->GetPlatformView()->DispatchPlatformMessage(platformMessage);
 }

shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.mm

@@ -4,6 +4,47 @@
 
 #import "flutter/shell/platform/darwin/ios/framework/Source/platform_message_response_darwin.h"
 
+/// A proxy object that behaves like NSData represented in a Mapping.
+/// This isn't a subclass of NSData because NSData is in a class cluster.
+@interface FlutterMappingData : NSObject
+@end
+
+@implementation FlutterMappingData {
+  NSData* _data;
+  std::unique_ptr<fml::Mapping> _mapping;
+}
+
++ (NSData*)dataWithMapping:(std::unique_ptr<fml::Mapping>)mapping {
+  return (NSData*)[[[FlutterMappingData alloc] initWithMapping:std::move(mapping)] autorelease];
+}
+
+- (instancetype)initWithMapping:(std::unique_ptr<fml::Mapping>)mapping {
+  self = [super init];
+  if (self) {
+    const void* rawData = mapping->GetMapping();
+
+    // Const cast is required because the NSData API requires it despite
+    // guarentees that the buffer won't be deleted or modified.
+    _data = [[NSData alloc] initWithBytesNoCopy:const_cast<void*>(rawData)
+                                         length:mapping->GetSize()
+                                   freeWhenDone:NO];
+
+    _mapping = std::move(mapping);
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [_data release];
+  [super dealloc];
+}
+
+- (id)forwardingTargetForSelector:(SEL)aSelector {
+  return _data;
+}
+
+@end
+
 namespace flutter {
 
 PlatformMessageResponseDarwin::PlatformMessageResponseDarwin(
@@ -17,7 +58,8 @@
 void PlatformMessageResponseDarwin::Complete(std::unique_ptr<fml::Mapping> data) {
   fml::RefPtr<PlatformMessageResponseDarwin> self(this);
   platform_task_runner_->PostTask(fml::MakeCopyable([self, data = std::move(data)]() mutable {
-    self->callback_.get()(GetNSDataFromMapping(std::move(data)));
+    NSData* callbackData = [FlutterMappingData dataWithMapping:std::move(data)];
+    self->callback_.get()(callbackData);
   }));
 }
 

shell/platform/darwin/ios/framework/Source/platform_message_router.mm

@@ -8,6 +8,48 @@
 
 #import "flutter/shell/platform/darwin/common/buffer_conversions.h"
 
+/// A proxy object that behaves like NSData represented in a PlatformMessage.
+/// This isn't a subclass of NSData because NSData is in a class cluster.
+@interface FlutterMessageData : NSObject
+@end
+
+@implementation FlutterMessageData {
+  NSData* _data;
+  fml::RefPtr<flutter::PlatformMessage> _platformMessage;
+}
+
++ (NSData*)dataWithMessage:(fml::RefPtr<flutter::PlatformMessage>)platformMessage {
+  return (NSData*)[[[FlutterMessageData alloc] initWithMessage:std::move(platformMessage)]
+      autorelease];
+}
+
+- (instancetype)initWithMessage:(fml::RefPtr<flutter::PlatformMessage>)platformMessage {
+  self = [super init];
+  if (self) {
+    const void* rawData = platformMessage->data().data();
+
+    // Const cast is required because the NSData API requires it despite
+    // guarentees that the buffer won't be deleted or modified.
+    _data = [[NSData alloc] initWithBytesNoCopy:const_cast<void*>(rawData)
+                                         length:platformMessage->data().size()
+                                   freeWhenDone:NO];
+
+    _platformMessage = std::move(platformMessage);
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [_data release];
+  [super dealloc];
+}
+
+- (id)forwardingTargetForSelector:(SEL)aSelector {
+  return _data;
+}
+
+@end
+
 namespace flutter {
 
 PlatformMessageRouter::PlatformMessageRouter() = default;
@@ -22,12 +64,12 @@
     FlutterBinaryMessageHandler handler = it->second;
     NSData* data = nil;
     if (message->hasData()) {
-      data = GetNSDataFromVector(message->data());
+      data = [FlutterMessageData dataWithMessage:std::move(message)];
     }
     handler(data, ^(NSData* reply) {
       if (completer) {
         if (reply) {
-          completer->Complete(GetMappingFromNSData(reply));
+          completer->Complete(CopyNSDataToMapping(reply));
         } else {
           completer->CompleteEmpty();
         }