-
Notifications
You must be signed in to change notification settings - Fork 0
/
default.nix
49 lines (43 loc) · 1.27 KB
/
default.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
{ configuration
, lib
, check ? true
}:
with lib;
let
# A lib with extensions
extlib = lib.extend (import ./lib);
eval = extlib.evalModules {
modules = (toList configuration) ++ [
({ config, ... }: {
config = {
_module.check = check;
_module.args = {
ipam = config; # Re-expose global config into submodules
};
};
options = {
assertions = mkOption {
type = types.listOf types.unspecified;
internal = true;
default = [ ];
example = [{ assertion = false; message = "you can't enable this for that reason"; }];
description = ''
This option allows modules to express conditions that must
hold for the evaluation of the system configuration to
succeed, along with associated error messages for the user.
'';
};
};
})
] ++ (import ./modules);
specialArgs = {
modulesPath = builtins.toString ./modules;
};
};
failedAssertions = filter (x: !x.assertion) eval.config.assertions;
in
if failedAssertions != [ ]
then throw "\nFailed assertions:\n${concatStringsSep "\n" (map (x: "- ${x.message}") failedAssertions)}"
else {
inherit (eval) config options;
}