-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathMainForm.pas
1069 lines (980 loc) · 37.3 KB
/
MainForm.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{******************************************************************************}
{ }
{ PNDTools is Copyright ©2011-2013 Janek Schäfer }
{ }
{ This file is part of PNDTools }
{ }
{ PNDTools is free software: you can redistribute it and/or modify }
{ it under the terms of the GNU General Public License as published by }
{ the Free Software Foundation, either version 3 of the License, or }
{ (at your option) any later version. }
{ }
{ PNDTools is distributed in the hope that it will be useful, }
{ but WITHOUT ANY WARRANTY; without even the implied warranty of }
{ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the }
{ GNU General Public License for more details. }
{ }
{ You should have received a copy of the GNU General Public License }
{ along with this program. If not, see <http://www.gnu.org/licenses/>. }
{ }
{******************************************************************************}
unit MainForm;
{$IFDEF FPC}
{$MODE DELPHI}
{$ENDIF}
interface
uses
VirtualTrees,
Types, Messages, Classes, Graphics, Controls, Forms, SysUtils, IniFiles,
Dialogs, StdCtrls, ImgList, ExtCtrls, XPMan, {$Ifdef Win32}FileCtrl{$Endif},
ComCtrls, Menus;
type
TExtractBehaviour = (ebTemp, ebUser, ebAsk);
TWarningLevel = (wlInfo, wlSuccess, wlWarning, wlError, wlNone);
rSettings = record
SmartAdd : Boolean;
ShowIcons : Boolean;
SizeBinary : Boolean;
ProgMkSquash : String;
ProgUnSquash : String;
ProgChmod : String;
Prog7zip : String;
ParamMkSquash : String;
ParamUnSquash : String;
ParamChmod : String;
Param7zip : String;
SchemaFile : String;
LogLevel : Integer;
DialogueLevel : Integer;
end;
TfrmMain = class(TForm)
imlFileTree: TImageList;
pnlButtons: TPanel;
btnCreate: TButton;
opdFileAny: TOpenDialog;
opdPXML: TOpenDialog;
opdIcon: TOpenDialog;
sadPND: TSaveDialog;
grbLog: TGroupBox;
redLog: TRichEdit;
opdPND: TOpenDialog;
menMain: TMainMenu;
menMainFile: TMenuItem;
menMainHelp: TMenuItem;
menMainHelpAbout: TMenuItem;
menMainFileOpen: TMenuItem;
pomFiles: TPopupMenu;
pomFilesOpen: TMenuItem;
N1: TMenuItem;
menMainHelpPXML: TMenuItem;
menMainHelpPND: TMenuItem;
grbFiles: TGroupBox;
vstFiles: TVirtualStringTree;
pnlFilesButtons: TPanel;
btnFilesClear: TButton;
btnFilesFolder: TButton;
btnFilesFile: TButton;
cbxRecursive: TCheckBox;
pnlFilesInfo: TPanel;
lblFilesSizeLbl: TLabel;
lblFilesSize: TLabel;
grbIcon: TGroupBox;
edtIcon: TEdit;
btnIconLoad: TButton;
grbPXML: TGroupBox;
btnPXMLLoad: TButton;
edtPXML: TEdit;
btnIconClear: TButton;
btnPXMLClear: TButton;
N2: TMenuItem;
menMainFileOptions: TMenuItem;
N3: TMenuItem;
menMainFileExit: TMenuItem;
btnPXMLEdit: TButton;
pomFilesDelete: TMenuItem;
menMainHelpThread: TMenuItem;
pomFilesFolder: TMenuItem;
menMainFileNew: TMenuItem;
procedure vstFilesHeaderClick(Sender: TVTHeader; HitInfo: TVTHeaderHitInfo);
procedure menMainFileNewClick(Sender: TObject);
procedure pomFilesFolderClick(Sender: TObject);
procedure menMainHelpThreadClick(Sender: TObject);
procedure pomFilesDeleteClick(Sender: TObject);
procedure edtPXMLChange(Sender: TObject);
procedure FormShow(Sender: TObject);
procedure menMainFileOptionsClick(Sender: TObject);
procedure menMainFileExitClick(Sender: TObject);
procedure btnPXMLClearClick(Sender: TObject);
procedure btnIconClearClick(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
procedure btnPXMLEditClick(Sender: TObject);
procedure grbLogDblClick(Sender: TObject);
procedure menMainHelpPNDClick(Sender: TObject);
procedure menMainHelpPXMLClick(Sender: TObject);
procedure menMainHelpAboutClick(Sender: TObject);
procedure vstFilesNodeMoving(Sender: TBaseVirtualTree; Node,
Target: PVirtualNode; var Allowed: Boolean);
procedure pomFilesOpenClick(Sender: TObject);
procedure vstFilesMouseUp(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
procedure menMainFileOpenClick(Sender: TObject);
procedure vstFilesStructureChange(Sender: TBaseVirtualTree;
Node: PVirtualNode; Reason: TChangeReason);
procedure vstFilesKeyDown(Sender: TObject; var Key: Word;
Shift: TShiftState);
procedure btnCreateClick(Sender: TObject);
procedure btnFilesFolderClick(Sender: TObject);
procedure btnFilesFileClick(Sender: TObject);
procedure FormCreate(Sender: TObject);
procedure vstFilesGetImageIndex(Sender: TBaseVirtualTree;
Node: PVirtualNode; Kind: TVTImageKind; Column: TColumnIndex;
var Ghosted: Boolean; var ImageIndex: Integer);
procedure vstFilesCompareNodes(Sender: TBaseVirtualTree; Node1,
Node2: PVirtualNode; Column: TColumnIndex; var Result: Integer);
procedure vstFilesGetText(Sender: TBaseVirtualTree;
Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
var CellText: WideString);
procedure vstFilesDragOver(Sender: TBaseVirtualTree;
Source: TObject; Shift: TShiftState; State: TDragState; Pt: TPoint;
Mode: TDropMode; var Effect: Integer; var Accept: Boolean);
procedure btnIconLoadClick(Sender: TObject);
procedure btnPXMLLoadClick(Sender: TObject);
procedure btnFilesClearClick(Sender: TObject);
private
{ Copies the tree file-data (represented by the nodes) to the passed folder
Uses CopyFileEx internally }
procedure CopyTreeToFolder(Tree : TBaseVirtualTree; const TargetDir : String);
{ Extracts PXML and Icon data (if found) from an already open PND file stream
and saves them to the passed filenames. Filenames are changed to '' if
no file has been saved }
procedure ExtractPNDMetaData(Stream : TFileStream; var PXML : String;
var Icon : String);
{ Function to read/write saved settings specific to the passed TForm
component, such as position and size }
procedure ReadFormSettings(const Ini : TIniFile; Frm : TForm);
procedure WriteFormSettings(Ini : TIniFile; const Frm : TForm);
public
Settings : rSettings;
// Default names for saving extracted files and for the "smart add" function
const PXML_PATH : String = 'PXML.xml';
const ICON_PATH : String = 'icon.png';
const PND_EXT : String = '.pnd';
// Default colour for LogLine
const LOG_ERROR_COLOR : TColor = clRed;
const LOG_WARNING_COLOR : TColor = $0000AAFF;
const LOG_SUCCESS_COLOR : TColor = clGreen;
const LOG_INFO_COLOR : TColor = clBlack;
{ Depennding on the passed Level and set levels LogLevel and DialogueLevel in
frmMain.Settings this will print the passed string to frmMain.redLog in
a colour according to Level OR show a MessageDlg with the passed Text }
procedure LogLine(const TextToAdd : String; const Level : TWarningLevel = wlInfo);
{ Opens the specified file as PND, extracts its contents and meta data and
updates the GUI accordingly }
procedure OpenPND(const FileName : String);
{ Creates a PND with the contents of the file tree in the main window and
attaches the passed PXML and icon files }
procedure SavePND(const FileName : String; const PXML : String;
const Icon : String);
{ Load/Save settings from/to an ini file }
procedure LoadSettings(const FileName : String; var S : rSettings);
procedure SaveSettings(const FileName : String; const S : rSettings);
end;
const
VERSION : String = '0.7.3';
BUILD_DATE : String = '2015-03-13';
// Default tool paths
UNSQUASHFS_PATH : String = 'tools\unsquashfs.exe';
MKSQUASH_PATH : String = 'tools\mksquashfs.exe';
CHMOD_PATH : String = 'tools\chmod.exe';
ZIP_PATH : String = 'tools\7z.exe';
SETTINGS_PATH : String = 'settings.ini';
SCHEMA_PATH : String = 'tools\PXML_schema.xml';
// Variables for program arguments
SOURCE_VAR : String = '%source%';
TARGET_VAR : String = '%target%';
var
frmMain: TfrmMain;
implementation
{$R *.dfm}
// DONE: Graphical browser and editor for the PXML
// TODO: Display icon in main form
// DONE: Ask for overwrite on copy to file tree
// DONE: Open PND
// DONE: Show total uncompressed size
// DONE: Clear temp folder on exit and start
// DONE: Check for write access on start
// DONE: Function for proper conversion from Windows to Cygwin POSIX path
// TODO: Pass all external paths to function for WinLin conversion
// TODO: Add option for extraction behaviour (user path, program path, ask)
// DONE: ISO file system
// DONE: Show message box when encountering a critical error
// DONE: Option to show message, log or both on error
// DONE: Add proper licensing information
// DONE: Scroll down Log automatically to reveal latest line
// DONE: Dropping a file onto another file (blue selection) will not trigger the overwrite promt
// DONE: Moving a file within PNDTools will not trigger the overwrite promt
// TODO: Command line utilities
// DONE: "Open folder": explorer.exe /select
// DONE: Add warnings to PXML Creator (no description, no icon, etc.)
// DONE: Don't close PXMLCreator automatically, instead change "Cancel" to "Close" and alert user to press that
// DONE: Investigate adding gifs as screenshots (better display if not able to load)
// TODO: Better error handling when tools cannot be found (open/save PND)
// TODO: Configure button in OptionsForm to generate mksquashfs and unsquashfs options (for beginners)
uses
VSTUtils, FormatUtils, FileUtils, OptionsForm, PXMLForm, CreatorForm,
AboutForm, FileConflictForm, GraphicUtils,
VSTDragDrop, VSTIcons, ShellStuff, {$Ifdef Win32}ControlHideFix{$Endif};
// --- Functions ---------------------------------------------------------------
procedure TfrmMain.CopyTreeToFolder(Tree : TBaseVirtualTree; const TargetDir : String);
var
Source : String;
Destination : String;
begin
CopyTreeData(Tree,Tree.GetFirst(),TargetDir,Source,Destination);
if ShellCopyFile(Source,Destination,false) then
begin
LogLine('Copied all files to temporary directory '#13#10 + TargetDir,
wlSuccess);
end
else
begin
LogLine('An error occurred when copying the files to the temporary ' +
'folder ' + #13#10 + TargetDir + #13#10 +
'Check whether you have right access to it and no file is ' +
'currently in use by another application.' + #13#10 +
'The error code was: ' + IntToStr(GetLastError()),
wlError);
end;
end;
procedure TfrmMain.ExtractPNDMetaData(Stream : TFileStream; var PXML : String;
var Icon : String);
const
PXML_HEADER : String = '<?xml';
PXML_HEADER_FALLBACK : String = '<PXML';
PXML_FOOTER : String = '</PXML>';
var
OutputStream : TFileStream;
Pos : Int64;
NumRead, NumWrite : Integer;
Buffer : Array [Word] of Byte;
Headers : Array [0..4] of String;
ImageIndex : Integer;
begin
// File signatures taken from: http://www.garykessler.net/library/file_sigs.html
Headers[0] := Chr(137) + 'PNG' + Chr(13) + Chr(10) + Chr(26) + Chr(10); // PNG
Headers[1] := Chr(255) + Chr(216) + Chr(255); // JPG
Headers[2] := 'GIF8'; // GIF
Headers[3] := 'BM'; // BMP
Headers[4] := Chr(0) + Chr(0) + Chr(1) + Chr(0); // ICO
// find PXML data
LogLine('Looking for PXML data...');
Pos := FindStringDataInStream(PXML_HEADER,Stream,0,true);
if Pos = -1 then
begin
Pos := FindStringDataInStream(PXML_HEADER_FALLBACK,Stream,0,true);
if Pos = -1 then
begin
LogLine('No PXML data found!',wlError);
PXML := '';
Icon := '';
Exit;
end else
LogLine('PXML file missing proper xml header, you should fix ' +
'that, check the PXML specification for details',
wlWarning);
end;
// write PXML data to a file
LogLine('PXML data found, writing to file ' + PXML);
OutputStream := TFileStream.Create(PXML,fmCreate);
try
Pos := FindStringDataInStream(PXML_FOOTER,Stream,Pos,false,OutputStream);
finally
OutputStream.Free;
end;
// search for icon header and extract icon data
ImageIndex := Low(Headers);
while (Pos = -1) AND (ImageIndex <= High(Headers)) do
begin
Pos := FindStringDataInStream(Headers[ImageIndex],Stream,Pos);
Inc(ImageIndex);
end;
if Pos <> -1 then
begin
case ImageIndex of
1: ChangeFileExt(Icon,'.png');
2: ChangeFileExt(Icon,'.jpg');
3: ChangeFileExt(Icon,'.gif');
4: ChangeFileExt(Icon,'.bmp');
5: ChangeFileExt(Icon,'.ico');
end;
LogLine('Icon data found, writing to file ' + Icon);
OutputStream := TFileStream.Create(Icon,fmCreate);
try
Stream.Seek(Pos,soFromBeginning);
repeat
NumRead := Stream.Read(Buffer,SizeOf(Buffer));
NumWrite := OutputStream.Write(Buffer,NumRead);
until (NumRead = 0) OR (NumRead <> NumWrite);
finally
OutputStream.Free;
end;
end else
begin
LogLine('No icon data found in PND',wlWarning);
Icon := '';
end;
LogLine('PND metadata successfully extracted',wlSuccess);
end;
procedure TfrmMain.LogLine(const TextToAdd : String; const Level : TWarningLevel = wlInfo);
function LevelToDlgType(const Level : TWarningLevel) : TMsgDlgType;
begin
Result := mtCustom;
case Level of
wlInfo: Result := mtInformation;
wlSuccess: Result := mtInformation;
wlWarning: Result := mtWarning;
wlError: Result := mtError;
end;
end;
var
Count : Integer;
begin
if Ord(Level) >= Ord(Settings.DialogueLevel) then
begin
MessageDlg(TextToAdd,LevelToDlgType(Level),[mbOk],0);
end;
if Ord(Level) >= Ord(Settings.LogLevel) then
begin
Count := Length(redLog.Text);
redLog.Lines.Add(TextToAdd);
redLog.SelStart := count;
redLog.SelLength := Length(redLog.Text) - redLog.SelStart;
case Level of
wlInfo: redLog.SelAttributes.Color := LOG_INFO_COLOR;
wlSuccess: redLog.SelAttributes.Color := LOG_SUCCESS_COLOR;
wlWarning: redLog.SelAttributes.Color := LOG_WARNING_COLOR;
wlError: redLog.SelAttributes.Color := LOG_ERROR_COLOR;
end;
redLog.SelLength := 0;
end;
end;
procedure TfrmMain.OpenPND(const FileName: string);
const
TEMP_PATH : String = 'temp2'; // Relative path (from the .exe) to the temporary folder
META_PATH : String = 'meta'; // Relative path to the meta folder (for PXML and Icon)
var
Stream : TFileStream;
PXML, Icon, Prog, Param : String;
temp, IsISO : Boolean;
begin
// clean-up
vstFiles.Clear;
edtPXML.Clear;
edtIcon.Clear;
LogLine('Deleting old temporary files');
Param := IncludeTrailingPathDelimiter(ExtractFilePath(Application.ExeName) + META_PATH);
PXML := Param + PXML_PATH;
Icon := Param + ICON_PATH;
ShellDeleteFile(PXML);
ShellDeleteFile(Icon);
Param := ExtractFilePath(Application.ExeName) + TEMP_PATH;
ShellDeleteFile(Param);
CreateDir(Param);
CreateDir(ExtractFilePath(Application.ExeName) + META_PATH);
// Detect ISO file system
Stream := TFileStream.Create(FileName,fmOpenRead);
IsISO := DetectIsoFormat(Stream);
if IsISO then
LogLine('ISO file format detected!',wlWarning);
// extract PXML and Icon
try
ExtractPNDMetaData(Stream,PXML,Icon);
finally
Stream.Free;
end;
// Extract the PND
LogLine('Extracting PND to ' + Param + '... this might take a while');
if IsISO then
begin
Prog := Settings.Prog7zip;
Param := StringReplace(Settings.Param7zip,SOURCE_VAR,FileName,[rfReplaceAll]);
Param := StringReplace(Param,TARGET_VAR,TEMP_PATH,[rfReplaceAll]);
end else // squashFS
begin
Prog := Settings.ProgUnSquash;
Param := StringReplace(Settings.ParamUnSquash,SOURCE_VAR,ConvertPath(FileName),[rfReplaceAll]);
Param := StringReplace(Param,TARGET_VAR,ConvertPath(TEMP_PATH),[rfReplaceAll]);
end;
LogLine('Calling program: ' + Prog + ' ' + Param);
if not ExecuteProgram(Prog,Param) then
begin
MessageDlg('Encountered an error while extracting PND' + #13#10 +
'Error code: ' + IntToStr(GetLastError),mtError,[mbOK],0);
Exit;
end;
// add files to tree
LogLine('Adding files to tree, this might take a while...');
vstFiles.BeginUpdate;
temp := Settings.SmartAdd;
Settings.SmartAdd := false;
try
AddFolder(vstFiles,nil,ExtractFilePath(Application.ExeName) + TEMP_PATH,true);
finally
vstFiles.EndUpdate;
end;
Settings.SmartAdd := temp;
vstFiles.SortTree(0,vstFiles.Header.SortDirection);
edtPXML.Text := PXML;
edtIcon.Text := Icon;
if vstFiles.GetFirst = nil then
LogLine('No files have been added, this most likely is due to an ' +
'error while extracting the PND.'#13#10 +
'You can get a more detailed error report, by using the supplied '+
'batch scripts. See the Readme.txt for more info and how to use them.',wlError)
else
LogLine('PND successfully extracted to ' +
ExtractFilePath(Application.ExeName) + TEMP_PATH,wlSuccess);
end;
procedure TfrmMain.SavePND(const FileName : String; const PXML : String;
const Icon : String);
const
TEMP_PATH : String = 'temp'; // Relative path (from the .exe) to the temporary folder
var
Prog, Param : String;
PNDFile : TFileStream;
Return : Integer;
NoPXML : Boolean;
begin
NoPXML := false;
if (PXML = '') OR (not FileExists(PXML)) then
begin
Return := MessageDlg('No PXML file was specified or the entered filename ' +
'could not be loaded!'#13#10 +
'This file is mandatory for the PND to work!',
mtWarning,[mbAbort,mbIgnore],0);
if Return = mrAbort then
Exit;
NoPXML := true;
end;
// temporary data handling
Param := ExtractFilePath(Application.ExeName) + TEMP_PATH;
LogLine('Deleting old temporary files');
ShellDeleteFile(Param); // clean-up
LogLine('Copying new temporary files to folder ' + Param + ' - This may ' +
'take a while.');
CopyTreeToFolder(vstFiles,Param);
// set corrent file flags to work on the Pandora
Prog := Settings.ProgChmod;
Param := StringReplace(Settings.ParamChmod,SOURCE_VAR,ConvertPath(TEMP_PATH),[rfReplaceAll]);
LogLine('Calling program: ' + Prog + ' ' + Param);
if not ExecuteProgram(Prog,Param) then
begin
MessageDlg('Encountered an error while trying to set file flags' + #13#10 +
'Error code: ' + IntToStr(GetLastError),mtError,[mbOK],0);
Exit;
end;
// Make the squashFS filesystem from the temporary files
Prog := Settings.ProgMkSquash;
Param := StringReplace(Settings.ParamMkSquash,SOURCE_VAR,ConvertPath(TEMP_PATH),[rfReplaceAll]);
Param := StringReplace(Param,TARGET_VAR,ConvertPath(FileName),[rfReplaceAll]);
LogLine('Calling program: ' + Prog + ' ' + Param);
if not ExecuteProgram(Prog,Param) then
begin
MessageDlg('Encountered an error while creating SquashFS archive' + #13#10 +
'Error code: ' + IntToStr(GetLastError),mtError,[mbOK],0);
Exit;
end;
// append PXML and icon
LogLine('Appending icon and PXML data (if found).');
PNDFile := TFileStream.Create(FileName,fmOpenReadWrite);
try
if not NoPXML then
AppendDataToFileStream(PNDFile,PXML)
else
LogLine('Creating PND without PXML data (you should not do this!)',
wlWarning);
if (Icon <> '') AND FileExists(Icon) then
AppendDataToFileStream(PNDFile,Icon)
else
LogLine('No icon found or icon could not be accessed',
wlWarning);
finally
PNDFile.Free;
end;
LogLine('PND created successfully: ' + FileName,wlSuccess);
end;
procedure TfrmMain.LoadSettings(const FileName: string; var S: rSettings);
var
Ini : TIniFile;
begin
Ini := TIniFile.Create(ExtractFilePath(Application.ExeName) + FileName);
try
with S do
begin
SmartAdd := Ini.ReadBool('General','SmartAdd',true);
ShowIcons := Ini.ReadBool('General','ShowIcons',true);
SizeBinary := Ini.ReadBool('General','SizeBinary',false);
ProgMkSquash := Ini.ReadString('Paths','MkSquash',MKSQUASH_PATH);
ProgUnSquash := Ini.ReadString('Paths','UnSquash',UNSQUASHFS_PATH);
ProgChmod := Ini.ReadString('Paths','Chmod',CHMOD_PATH);
Prog7zip := Ini.ReadString('Paths','7zip',ZIP_PATH);
ParamMkSquash := Ini.ReadString('Params','MkSquash','"' +
SOURCE_VAR + '" "' + TARGET_VAR + '" -nopad -no-recovery -noappend');
ParamUnSquash := Ini.ReadString('Params','UnSquash','-f -d "' +
TARGET_VAR + '" "' + SOURCE_VAR + '"');
ParamChmod := Ini.ReadString('Params','Chmod','-R 755 "' +
SOURCE_VAR + '"');
Param7zip := Ini.ReadString('Params','7zip','x "' +
SOURCE_VAR + '" -o"' + TARGET_VAR + '" -y');
SchemaFile := Ini.ReadString('Paths','Schema',SCHEMA_PATH);
LogLevel := Ini.ReadInteger('General','LogLevel',Ord(wlInfo));
DialogueLevel := Ini.ReadInteger('General','DialogueLevel',Ord(wlError));
end;
ReadFormSettings(Ini,frmMain);
ReadFormSettings(Ini,frmPXML);
ReadFormSettings(Ini,frmCreator);
finally
Ini.Free;
end;
end;
procedure TfrmMain.SaveSettings(const FileName: string; const S: rSettings);
var
Ini : TIniFile;
begin
Ini := TIniFile.Create(ExtractFilePath(Application.ExeName) + FileName);
try
with S do
begin
Ini.WriteBool('General','SmartAdd',SmartAdd);
Ini.WriteBool('General','ShowIcons',ShowIcons);
Ini.WriteBool('General','SizeBinary',SizeBinary);
Ini.WriteString('Paths','MkSquash',ProgMkSquash);
Ini.WriteString('Paths','UnSquash',ProgUnSquash);
Ini.WriteString('Paths','Chmod',ProgChmod);
Ini.WriteString('Paths','7zip',Prog7zip);
Ini.WriteString('Params','MkSquash',ParamMkSquash);
Ini.WriteString('Params','UnSquash',ParamUnSquash);
Ini.WriteString('Params','Chmod',ParamChmod);
Ini.WriteString('Params','7zip',Param7zip);
Ini.WriteString('Paths','Schema',SchemaFile);
Ini.WriteInteger('General','LogLevel',LogLevel);
Ini.WriteInteger('General','DialogueLevel',DialogueLevel);
end;
WriteFormSettings(Ini,frmMain);
WriteFormSettings(Ini,frmPXML);
WriteFormSettings(Ini,frmCreator);
finally
Ini.Free;
end;
end;
procedure TfrmMain.ReadFormSettings(const Ini: TIniFile; Frm: TForm);
begin
with Frm do
begin
Width := Ini.ReadInteger(Name,'Width',Frm.Constraints.MinWidth);
Height := Ini.ReadInteger(Name,'Height',Frm.Constraints.MinHeight);
Left := Ini.ReadInteger(Name,'Left',100);
Top := Ini.ReadInteger(Name,'Top',100);
end;
end;
procedure TfrmMain.WriteFormSettings(Ini: TIniFile; const Frm: TForm);
begin
with Frm do
begin
Ini.WriteInteger(Name,'Width',Width);
Ini.WriteInteger(Name,'Height',Height);
Ini.WriteInteger(Name,'Left',Left);
Ini.WriteInteger(Name,'Top',Top);
end;
end;
// --- Menu --------------------------------------------------------------------
procedure TfrmMain.menMainFileExitClick(Sender: TObject);
begin
Close;
end;
procedure TfrmMain.menMainFileNewClick(Sender: TObject);
begin
vstFiles.Clear;
edtIcon.Clear;
edtPXML.Clear;
LogLine('All inputs cleared!',wlInfo);
end;
procedure TfrmMain.menMainFileOpenClick(Sender: TObject);
begin
// error checking
if not FileExists(ExtractFilePath(Application.ExeName) + UNSQUASHFS_PATH) then
begin
MessageDlg('The squashFS tools could not be found!'#13#10 +
'Please make sure they are located in the ''tools'' folder next to the ' +
'program executable.',mtError,[mbOK],0);
Exit;
end;
if vstFiles.GetFirst <> nil then
begin
if MessageDlg('Opening a PND will clear your current file-tree. Proceed?',
mtWarning,[mbYes,mbNo],0) = mrNo then
Exit;
end;
if not opdPND.Execute then
Exit;
OpenPND(opdPND.FileName);
end;
procedure TfrmMain.menMainFileOptionsClick(Sender: TObject);
begin
CenterControl(frmOptions,frmMain);
if frmOptions.Execute(Settings) then
Settings := frmOptions.Settings;
end;
procedure TfrmMain.menMainHelpAboutClick(Sender: TObject);
begin
CenterControl(frmAbout,frmMain);
frmAbout.ShowModal;
end;
procedure TfrmMain.menMainHelpPNDClick(Sender: TObject);
begin
ExecuteProgram('http://pandorawiki.org/PND_quickstart','','','open',false);
end;
procedure TfrmMain.menMainHelpPXMLClick(Sender: TObject);
begin
ExecuteProgram('http://pandorawiki.org/PXML_specification','','','open',false);
end;
procedure TfrmMain.menMainHelpThreadClick(Sender: TObject);
begin
ExecuteProgram('http://boards.openpandora.org/index.php?/topic/3756-pndtools/','','','open',false);
end;
// --- Popup Menu --------------------------------------------------------------
procedure TfrmMain.pomFilesDeleteClick(Sender: TObject);
begin
vstFiles.DeleteSelectedNodes;
end;
procedure TfrmMain.pomFilesFolderClick(Sender: TObject);
var
Node : PVirtualNode;
PData : PFileTreeData;
begin
Node := vstFiles.GetFirstSelected();
PData := vstFiles.GetNodeData(Node);
ExecuteProgram('explorer','/select,"' + PData.Name + '"','','runas',false);
//ExecuteProgram(ExtractFilePath(PData.Name),'','','explore',false);
end;
procedure TfrmMain.pomFilesOpenClick(Sender: TObject);
var
Node : PVirtualNode;
PData : PFileTreeData;
begin
Node := vstFiles.GetFirstSelected();
PData := vstFiles.GetNodeData(Node);
if IsFile(vstFiles,Node) then
ExecuteProgram(PData.Name,'','','open',false)
else
ExecuteProgram(PData.Name,'','','explore',false);
end;
// --- Form --------------------------------------------------------------------
procedure TfrmMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
SaveSettings(SETTINGS_PATH,Settings);
end;
procedure TfrmMain.FormCreate(Sender: TObject);
const
TEST_FILE_NAME : String = 'asdftestxyz.txt';
var
dummy : TDragEvent;
jummy : TButtonEvent;
F : File;
begin
// Check for write access by writing dummy file
try
AssignFile(F,TEST_FILE_NAME);
ReWrite(F);
CloseFile(F);
ShellDeleteFile(TEST_FILE_NAME);
except
on E : Exception do
begin
MessageDlg('You do not have permission to write files in the folder ' +
'the program is located in'#13#10 +
'This functionality is mandatory for the program to work ' +
'properly'#13#10#13#10 +
'You can either move the program to a directory you have ' +
'write-access to (any except for the Programs, ' +
'Windows and User-folder should work) or run the program ' +
'as Administrator (Right-click -> Run as Administrator).' +
#13#10#13#10 + 'The Program will now exit.',mtError,[mbOk],1);
Application.Terminate;
end;
end;
vstFiles.NodeDataSize := sizeof(rFileTreeData);
dummy := TDragEvent.Create;
vstFiles.OnDragDrop := dummy.VSTDragDrop;
dummy.Free;
{$Ifdef Win32}
KeyPreview := true;
jummy := TButtonEvent.Create;
OnKeyDown := jummy.KeyDown;
jummy.Free;
{$Endif}
LoadSystemIcons(imlFileTree);
Caption := Caption + ' [Version ' + VERSION + ' built ' + BUILD_DATE + ']';
end;
procedure TfrmMain.FormShow(Sender: TObject);
begin
frmAbout.memAbout.Lines[1] := 'Version ' + VERSION + ' built ' + BUILD_DATE;
LoadSettings(SETTINGS_PATH,Settings);
if ParamCount > 0 then
if FileExists(ParamStr(1)) then
OpenPND(ParamStr(1));
end;
procedure TfrmMain.grbLogDblClick(Sender: TObject);
var
C : TControl;
begin
C := (Sender as TControl);
if C.Height = C.Constraints.MinHeight then
C.Height := C.Constraints.MaxHeight
else
C.Height := C.Constraints.MinHeight;
C.Top := pnlButtons.Top - C.Height;
end;
// --- Misc. -------------------------------------------------------------------
procedure TfrmMain.edtPXMLChange(Sender: TObject);
begin
if Length(edtPXML.Text) = 0 then
btnPXMLEdit.Caption := 'Create PXML'
else
btnPXMLEdit.Caption := 'Edit PXML'
end;
// --- Files Tree --------------------------------------------------------------
procedure TfrmMain.vstFilesCompareNodes(Sender: TBaseVirtualTree; Node1,
Node2: PVirtualNode; Column: TColumnIndex; var Result: Integer);
var
PData1, PData2 : PFileTreeData;
begin
PData1 := Sender.GetNodeData(Node1);
PData2 := Sender.GetNodeData(Node2);
if Column = 0 then
begin
if (PData1.Attr and faDirectory > 0) XOR (PData2.Attr and faDirectory > 0) then
begin
if (PData1.Attr and faDirectory > 0) then
Result := -1
else
Result := 1;
end else
{$Ifdef Win32}
Result := CompareText(ExtractFileName(PData1.Name), ExtractFileName(PData2.Name));
{$Else}
Result := CompareStr(ExtractFileName(PData1.Name), ExtractFileName(PData2.Name));
{$Endif}
end else
if Column = 1 then
begin
if PData1.Size > PData2.Size then
Result := 1
else
Result := -1
end;
end;
procedure TfrmMain.vstFilesDragOver(Sender: TBaseVirtualTree;
Source: TObject; Shift: TShiftState; State: TDragState; Pt: TPoint;
Mode: TDropMode; var Effect: Integer; var Accept: Boolean);
begin
Accept := true;
end;
procedure TfrmMain.vstFilesGetImageIndex(Sender: TBaseVirtualTree;
Node: PVirtualNode; Kind: TVTImageKind; Column: TColumnIndex;
var Ghosted: Boolean; var ImageIndex: Integer);
var
PData : PFileTreeData;
begin
if (Column <> 0) OR (Kind = ikOverlay) then
Exit;
PData := Sender.GetNodeData(Node);
if Sender.Expanded[Node] then
ImageIndex := PData.OpenIndex
else
ImageIndex := PData.ClosedIndex;
end;
procedure TfrmMain.vstFilesGetText(Sender: TBaseVirtualTree;
Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType;
var CellText: WideString);
var
PData : PFileTreeData;
begin
PData := Sender.GetNodeData(Node);
case Column of
0 : CellText := ExtractFileName(PData.Name);
1 : begin
if (PData.Attr and faDirectory = 0) then
CellText := SizeToStr(PData.Size,Settings.SizeBinary)
else
CellText := '';
end;
2 : CellText := PData.Name;
end;
end;
procedure TfrmMain.vstFilesHeaderClick(Sender: TVTHeader;
HitInfo: TVTHeaderHitInfo);
begin
if Sender.SortColumn = HitInfo.Column then
begin
if Sender.SortDirection=sdAscending then
Sender.SortDirection:=sdDescending
else
Sender.SortDirection:=sdAscending;
end else
Sender.SortColumn := HitInfo.Column;
Sender.Treeview.SortTree(HitInfo.Column,Sender.SortDirection,True);
end;
procedure TfrmMain.vstFilesKeyDown(Sender: TObject; var Key: Word;
Shift: TShiftState);
begin
case Key of
46 : // Del
begin
vstFiles.DeleteSelectedNodes;
end;
end;
end;
procedure TfrmMain.vstFilesMouseUp(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
var Node : PVirtualNode;
begin
if Button = mbRight then
begin
Node := (Sender as TBaseVirtualTree).GetNodeAt(X,Y);
if Node <> nil then
begin
(Sender as TBaseVirtualTree).ClearSelection;
(Sender as TBaseVirtualTree).Selected[Node] := true;
pomFiles.Popup(Mouse.CursorPos.X,Mouse.CursorPos.Y);
end;
end;
end;
procedure TfrmMain.vstFilesNodeMoving(Sender: TBaseVirtualTree; Node,
Target: PVirtualNode; var Allowed: Boolean);
var
PData : PFileTreeData;
begin
PData := Sender.GetNodeData(Node);
Allowed := (CheckForExistance(Sender,Sender.GetFirstChild(Target),
ExtractFileName(PData.Name)) = nil);
end;
procedure TfrmMain.vstFilesStructureChange(Sender: TBaseVirtualTree;
Node: PVirtualNode; Reason: TChangeReason);
begin
lblFilesSize.Caption := SizeToStr(CalculateTotalSize(vstFiles),Settings.SizeBinary);
end;
// --- Buttons -----------------------------------------------------------------
procedure TfrmMain.btnCreateClick(Sender: TObject);
begin
// error checking
if not FileExists(ExtractFilePath(Application.ExeName) + MKSQUASH_PATH) OR
not FileExists(ExtractFilePath(Application.ExeName) + CHMOD_PATH) then
begin
MessageDlg('The squashFS or chmod tools could not be found!'#13#10 +
'Please make sure they are located in the ''tools'' folder next to the ' +
'program executable.',mtError,[mbOK],0);
Exit;
end;
if vstFiles.GetFirst() = nil then
begin
MessageDlg('No files added to the PND!',mtError,[mbOK],0);
Exit;
end;
if not sadPND.Execute then
Exit;
SavePND(sadPND.FileName,edtPXML.Text,edtIcon.Text);
end;
procedure TfrmMain.btnFilesClearClick(Sender: TObject);
begin
vstFiles.Clear;
end;
procedure TfrmMain.btnFilesFileClick(Sender: TObject);
var
I : Integer;
begin
if opdFileAny.Execute then
begin
for I := 0 to opdFileAny.Files.Count - 1 do
AddItem(vstFiles,vstFiles.GetFirstSelected(false),opdFileAny.Files[I]);
vstFiles.SortTree(0,vstFiles.Header.SortDirection);
end;
end;
procedure TfrmMain.btnFilesFolderClick(Sender: TObject);
var
Dir : String;
begin
// TODO: Yeah I guess this is not exactly cross-platform safe...
{$Ifdef Win32}
SelectDirectory('Select a directory to add','',Dir);
{$Else}
MessageDlg('This function is not implemented yet, sorry :(',mtInformation,[mbOK],0);
btnFilesFolder.Enabled := false;
{$Endif}
if Dir <> '' then
begin
vstFiles.BeginUpdate;
try