build.gradle

buildscript {
  repositories {
    mavenCentral()
    gradlePluginPortal()
    maven { url 'https://repo.spring.io/plugins-release' }
  }
}

plugins {
  id 'org.springframework.boot' version "${springBootVersion}" apply false
  id "io.spring.dependency-management" version "${springDependenciesManagement}" apply false
  id 'idea'
  id 'eclipse'
  id 'java'
}

subprojects {

  group = 'com.vmware.gemfire'

  sourceCompatibility = JavaVersion.VERSION_17
  targetCompatibility = JavaVersion.VERSION_17

  repositories {
    mavenLocal()
    mavenCentral()
    maven {
      credentials {
        username "$gemfireRepoUsername"
        password "$gemfireRepoPassword"
      }
      url = uri("https://commercial-repo.pivotal.io/data3/gemfire-release-repo/gemfire")
    }
  }

  repositories {
    def additionalMavenRepoURLs = project.ext.get('additionalMavenRepoURLs')
    if (!additionalMavenRepoURLs.isEmpty() && !additionalMavenRepoURLs.isBlank()) {
      additionalMavenRepoURLs.split(",").each {
        project.getRepositories()
                .maven(mavenRepository -> {
                  mavenRepository.setUrl(uri(it.toString()));
                });
      }
    }
  }

  configurations.all {
    resolutionStrategy.cacheChangingModulesFor 0, "minutes"
  }
}