Error: Ingress.extensions "mimir-distributed-nginx" is invalid: spec.rules[0].host: Invalid value: "[mimiraksclus.xxxxx.cloud]": a lowercase RFC 1123 subdomain must consist of lower case alphanumeric characters, '-' or '.', and must start and end with an alphanumeric character (e.g. 'example.com', regex used for validation is '[a-z0-9]([-a-z0-9]*[a-z0-9])?(\.[a-z0-9]([-a-z0-9]*[a-z0-9])?)*')

[dwaiba]

Using this and getting this error: (CRDs are installed for Operator)

Error: Ingress.extensions "mimir-distributed-nginx" is invalid: spec.rules[0].host: Invalid value: "[mimiraksclus.xxxxxx.cloud]": a lowercase RFC 1123 subdomain must consist of lower case alphanumeric characters, '-' or '.', and must start and end with an alphanumeric character (e.g. 'example.com', regex used for validation is '[a-z0-9]([-a-z0-9]*[a-z0-9])?(\.[a-z0-9]([-a-z0-9]*[a-z0-9])?)*')

resource "helm_release" "mimir" {
  count      = var.install_kv_charts["mimir"] == "yes" ? 1 : 0
  chart      = "mimir-distributed"
  name       = "mimir-distributed"
  repository = "https://grafana.github.io/helm-charts"
  namespace  = "monitoring"

  set {
    name  = "enterprise.enabled"
    value = "false"
  }
  set {
    name  = "persistence.enabled"
    value = "true"
  }
  set {
    name  = "nginx.ingress.enabled"
    value = "true"
  }
  set {
    name  = "nginx.ingress.ClassName"
    value = "nginx"
  }
  set {
    name  = "nginx.ingress.hosts[0].host[0]"
    value = "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
  }
  set {
    name  = "nginx.ingress.tls[0].hosts[0]"
    value = "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
  }
  set {
    name  = "nginx.ingress.tls[0].secretName"
    value = "mimir-tls"
  }
  set {
    name  = "ingress.annotations.\"kubernetes\\.io/ingress\\.class\""
    value = "nginx"
  }
  set {
    name  = "ingress.annotations.\"cert-manager\\.io/cluster-issuer\""
    value = "letsencrypt"
  }

  set {
    name  = "ingress.annotations.\"meta\\.helm\\.sh/release-name\""
    value = "mimir-distributed"
  }
  set {
    name  = "ingress.annotations.\"meta\\.helm\\.sh/release-namespace\""
    value = "monitoring"
  }

  set {
    name  = "nginx.ingress.hosts[0].paths[0].path"
    value = "/"
  }

  set {
    name  = "nginx.ingress.hosts[0].paths[0].pathType"
    value = "Prefix"
  }
  set {
    name  = "controller.service.annotations.service\\.beta\\.kubernetes\\.io/azure-dns-label-name"
    value = azurerm_public_ip.mimir[0].domain_name_label
  }

  set {
    name  = "persistence.enabled"
    value = "true"
  }
  set {
    name  = "ingress.annotations.\"kubernetes\\.io/ingress\\.rewrite-target\""
    value = "/$1"
  }
  set {
    name  = "ingress.annotations.\"kubernetes\\.io/ingress\\.use-regex\""
    value = "true"
  }
  set {
    name  = "gateway.EnabledNonEnterprise"
    value = "true"
  }
  set {
    name  = "metaMonitoring.serviceMonitor.enabled"
    value = "true"
  }

  set {
    name  = "metaMonitoring.grafanaAgent.enabled"
    value = "true"
  }

  set {
    name  = "metaMonitoring.grafanaAgent.installOperator"
    value = "true"
  }
  depends_on = [
    helm_release.nginx-ingress
  ]
}

[charleskorn]

I've never used Helm with Terraform before, but this line looks suspicious to me:

name  = "nginx.ingress.hosts[0].host[0]"

The value for nginx.ingress.hosts[0].host should be a single value, not an array.

I think it should be: (note the removed [0] array index after .host)

name  = "nginx.ingress.hosts[0].host"

[dwaiba]

Thank you for the correct change suggestion. However had trouble with the nginx annotations for Mimir-distributed chart via direct set ... Hence changed to yaml and it works..

/**
resource "helm_release" "mimir" {
  count      = var.install_kv_charts["mimir"] == "yes" ? 1 : 0
  chart      = "mimir-distributed"
  name       = "mimir-distributed"
  repository = "https://grafana.github.io/helm-charts"
  namespace  = "monitoring"
  set {
    name  = "enterprise.enabled"
    value = "false"
  }
  set {
    name  = "persistence.enabled"
    value = "true"
  }
  set {
    name  = "nginx.ingress.enabled"
    value = "true"
  }
  set {
    name  = "nginx.ingress.ClassName"
    value = "nginx"
  }
  set {
    name  = "nginx.ingress.hosts[0].host"
    value = "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
  }
  set {
    name  = "nginx.ingress.hosts[0].paths[0].path"
    value = "/"
  }

  set {
    name  = "nginx.ingress.hosts[0].paths[0].pathType"
    value = "Prefix"
  }
  set {
    name  = "nginx.ingress.tls[0].hosts[0]"
    value = "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
  }
  set {
    name  = "nginx.ingress.tls[0].secretName"
    value = "mimir-tls"
  }
  set {
    name  = "nginx.ingress.annotations.\"kubernetes\\.io/ingress\\.class\""
    value = "nginx"
  }
  set {
    name  = "nginx.ingress.annotations.\"cert-manager\\.io/cluster-issuer\""
    value = "letsencrypt"
  }
  set {
    name  = "persistence.enabled"
    value = "true"
  }
  set {
    name  = "gateway.EnabledNonEnterprise"
    value = "true"
  }
  set {
    name  = "metaMonitoring.serviceMonitor.enabled"
    value = "true"
  }
  set {
    name  = "metaMonitoring.grafanaAgent.enabled"
    value = "true"
  }
  set {
    name  = "metaMonitoring.grafanaAgent.installOperator"
    value = "true"
  }
  set {
    name  = "metaMonitoring.grafanaAgent.metrics.additionalRemoteWriteConfigs[0].url"
    value = "http://mimir-distributed-nginx.monitoring.svc:80/api/v1/push"
  }
  depends_on = [
    helm_release.nginx-ingress
  ]
}
**/
resource "helm_release" "mimir" {
  count      = var.install_kv_charts["mimir"] == "yes" ? 1 : 0
  chart      = "mimir-distributed"
  name       = "mimir-distributed"
  repository = "https://grafana.github.io/helm-charts"
  namespace  = "monitoring"
  # set the values as inline yaml in the helm_release resource
  values = [
    <<EOF
enterprise:
  enabled: false
persistence:
  enabled: true
nginx:
  autoscaling:
    enabled: false
  ingress:
    enabled: true
    annotations:
      kubernetes.io/ingress.class: "nginx"
      cert-manager.io/cluster-issuer: letsencrypt

    hosts:
      - host: "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
        paths:
          - path: /
            pathType: Prefix
    tls:
      - secretName: mimir-gateway-tls
        hosts:
          - "${var.mimir_domain_name}.${tolist(keys(var.zone_rgmaps))[0]}"
ingester:
  replicas: 3
  zoneAwareReplication:
    enabled: false
alertmanager:
  replicas: 1
  zoneAwareReplication:
    enabled: false
gateway:
  enabledNonEnterprise: true
  replicas: 1
  zoneAwareReplication:
    enabled: false
store_gateway:
  replicas: 1
  zoneAwareReplication:
    enabled: false
query_scheduler:
  replicas: 2
querier:
  replicas: 2
metaMonitoring:
  serviceMonitor:
    enabled: true
  grafanaAgent:
    enabled: true
    installOperator: true
    metrics:
      additionalRemoteWriteConfigs:
        - url: "http://mimir-distributed-nginx.monitoring.svc:80/api/v1/push"

EOF

  ]
  depends_on = [
    helm_release.nginx-ingress
  ]
}