build.gradle

buildscript {
  repositories {
    maven {
      url = 'https://repository.apache.org/content/groups/snapshots'
      content {
        includeVersionByRegex 'org[.]apache[.]((grails)|(groovy)).*', '.*', '.*-SNAPSHOT'
      }
    }
    maven {
      url = 'https://central.sonatype.com/repository/maven-snapshots'
      content {
        includeVersionByRegex 'cloud[.]wondrify', '.*', '.*-SNAPSHOT'
      }
    }
    maven { url = 'https://repo.grails.org/grails/restricted' }
  }
  dependencies {
    classpath platform("org.apache.grails:grails-bom:$grailsVersion")
    classpath "org.apache.grails:grails-gradle-plugins"
    classpath "cloud.wondrify:asset-pipeline-gradle"
  }
}

allprojects {
  repositories {
    mavenCentral()
    maven {
      url = 'https://repository.apache.org/content/groups/snapshots'
      content {
        includeVersionByRegex 'org[.]apache[.]((grails)|(groovy)).*', '.*', '.*-SNAPSHOT'
      }
    }
    maven {
      url = 'https://central.sonatype.com/repository/maven-snapshots'
      content {
        includeVersionByRegex 'cloud[.]wondrify', '.*', '.*-SNAPSHOT'
      }
    }
    maven { url = 'https://repo.grails.org/grails/restricted' }
//      mavenLocal() // for local testing, do not commit uncommented
  }
}

version = project.projectVersion
group = "org.grails.plugins"

subprojects { Project project ->
  project.version = project.projectVersion
  project.group = "org.grails.plugins"

  if(project.name.endsWith('audit-logging')) {
    apply plugin: "org.apache.grails.gradle.grails-publish"
    grailsPublish {
      githubSlug = 'grails-plugins/grails-audit-logging-plugin'
      license {
        name = 'Apache-2.0'
      }
      title = "Grails Audit-Logging Plugin"
      desc = "Grails Audit-Logging Plugin for Grails 7+"
      developers = [robertoschwald:"Robert Oschwald", longwa:"Aaron Long", elkr:"Elmar Kretzer",
                    jamesfredley:"James Fredley", jdaugherty:"James Daugherty"]
    }
  }
}