Support :make variant/option that renders to a temporary file and opens a webbrowser to display it?

[anntzer]

Your :make currently writes the html output next to the rst file. I have personally found it useful to write instead to a temporary directory, and immediately display the result in a webbrowser. See marshallward/vim-restructuredtext#62 for the implementation I currently use, although variants are certainly possible. Perhaps this behavior can be configured with a variable?

[habamax]

Probably. I for now use :make and a simple mapping that opens generated html in a browser.

[anntzer]

If you can suggest a mapping implementation that would be nice too.

[habamax]

Something similar is currently in my after/ftplugin/rst.vim

" Open filename in an OS
func! OSopen(url) abort
    let url = a:url
    if has("win32") || has("win32unix")
        let cmd = ':silent !start'
    elseif executable('xdg-open')
        let cmd = ":silent !xdg-open"
    elseif executable('open')
        let cmd = ":silent !open"
    else
        echohl Error
        echomsg "Can't find proper opener for an URL!"
        echohl None
        return
    endif

    try
        echom cmd . ' "' . url . '"'
        exe cmd . ' "' . url . '"'
    catch
        echohl Error
        echomsg v:exception
        echohl None
    finally
        redraw!
    endtry
endfunc


command -buffer RSTViewHtml :call OSopen(expand("%:p:r").'.html')
nnoremap <buffer> goh :RSTViewHtml<CR>

[anntzer]

Ah, thanks, I'll play with that. (For the OS-dependent side, perhaps you can use python -mwebbrowser instead -- if rst2html5 works, you probably have a python in your path.)

[habamax]

I wish there was webbrowser extension, like Asciidoctor.js Live Preview that would render plain rst file as html.

[habamax]

I was thinking about it the other day and decided not to add it.

One can add following snippet into their ~/.vim/after/ftplugin/rst.vim to get desired/tailored behavior:

  func! s:rst_view() abort
    let output = tempname() . '.html'

    call system(printf("%s %s %s %s",
          \ "rst2html5.py",
          \ " --input-encoding=utf8 --stylesheet-path=minimal.css,responsive.css",
          \ shellescape(expand("%:p")),
          \ output
          \ ))

    " Comment/Uncomment what is appropriate
    " Windows
    exe ':silent !start ' . output
    " OSX
    " exe ':silent !xdg-open ' . output
    " Linux
    " exe ':silent !open ' . output
  endfunc

  command! -buffer RSTView call s:rst_view()