-
Notifications
You must be signed in to change notification settings - Fork 17
/
plats.qc
1430 lines (1242 loc) · 41.5 KB
/
plats.qc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
=============================================================================
LIFTS AND TRAINS
=============================================================================
*/
float PLAT_LOW_TRIGGER = 1;
float() plat_try_find_trigger =
{
entity t;
t = find (world, targetname, self.target);
if (!t)
{
dprint("plat with unmatched target\n");
return FALSE;
}
else if ( (t.classname != "trigger_once") && (t.classname != "trigger_multiple") && (t.classname != "trigger_multiple_box") )
{
dprint("plat targets a non-trigger\n");
return FALSE;
}
else
{
dprint3("plat trigger found, ", t.classname, "\n");
t.touch = plat_center_touch;
t.think = SUB_Null;
t.movetype = MOVETYPE_NONE;
t.enemy = self;
self.trigger_field = t;
self.target = "";
}
self.think = SUB_Null;
return TRUE;
}
void() plat_spawn_inside_trigger =
{
entity t;
vector tmin, tmax;
if (self.target != string_null)
{
dprint("overriding plat trigger\n");
// find overridden trigger for custom trigger zones
if (plat_try_find_trigger())
return;
}
// touch zone should extend from the top of the plat in its lowest position
// to 8 units above the top of the plat in its highest position. pos1 cannot
// be assumed to be the highest position.
t = spawn();
local float high, low;
high = max(self.pos1_z, self.pos2_z) + self.maxs_z;
low = min(self.pos1_z, self.pos2_z) + self.maxs_z;
tmin = self.mins + '25 25 0';
tmax = self.maxs - '25 25 0';
if (self.size_x <= 50)
{
tmin_x = (self.mins_x + self.maxs_x) / 2;
tmax_x = tmin_x + 1;
}
if (self.size_y <= 50)
{
tmin_y = (self.mins_y + self.maxs_y) / 2;
tmax_y = tmin_y + 1;
}
tmin_z = low;
if (self.spawnflags & PLAT_LOW_TRIGGER)
tmax_z = low + 8;
else
tmax_z = high + 8;
t.solid = SOLID_TRIGGER;
setsize (t, tmin, tmax);
t.touch = plat_center_touch;
t.think = SUB_Null;
t.movetype = MOVETYPE_NONE;
t.enemy = self;
self.trigger_field = t;
}
void() plat_hit_top =
{
sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
self.state = STATE_TOP;
self.think = plat_go_down;
self.nextthink = self.ltime + self.wait;
SUB_UseTargetsAlt(target2);
}
void() plat_hit_bottom =
{
sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
self.state = STATE_BOTTOM;
SUB_UseTargetsAlt(target4);
}
void() plat_go_down =
{
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
self.state = STATE_DOWN;
SUB_CalcMove (self.pos2, self.speed, plat_hit_bottom);
SUB_UseTargetsAlt(target3);
}
void() plat_go_up =
{
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
self.state = STATE_UP;
SUB_CalcMove (self.pos1, self.speed, plat_hit_top);
SUB_UseTargetsAlt(target);
}
// ---------------------------------------------------------
// plat_can_go
//
// plats are guaranteed to split the party in coop, requiring multiple
// players who want to take the same plat to stop at the edge, hold
// hands, and jump together - not foolproof in netquake. so, if any
// clients are about to get on the plat with us, just wait a moment
// so players can take the actions they want to take and not have to
// be so precious
// ---------------------------------------------------------
float() plat_can_go =
{
if (!coop) return TRUE;
// currently waiting
if (time < self.attack_finished)
return FALSE;
// wait completed, don't wait more than once
if (self.attack_finished > 0)
{
self.attack_finished = 0;
return TRUE;
}
if (plat_check_other_clients())
{
// play a sound
sound (self.enemy, CHAN_VOICE, self.enemy.noise1, 1, ATTN_NORM);
self.attack_finished = time + 1.2;
return FALSE;
}
return TRUE;
}
float() plat_check_other_clients =
{
// self is trigger, other is player
float cl = 0;
entity pl = world;
entity oself;
while (cl < clients)
{
pl = find(pl, classname, "player");
if (!pl) break;
if (pl != self && // players can't block themselves
vlen(other.origin - pl.origin) < 192 && // within 192u
!EntitiesTouching(pl,self) && // not already aboard
normalize(other.origin - pl.origin) * pl.velocity > -100 ) // not moving away
{
oself = self;
self = other;
if (visible(pl)) // visible to the first player
{
self = oself;
return TRUE;
}
self = oself;
}
cl++;
}
return FALSE;
}
void() plat_center_touch =
{
if (!CheckValidTouch()) return;
if (self.enemy.state == STATE_BOTTOM)
{
if (plat_can_go())
SUB_CallAsSelf(plat_go_up, self.enemy);
}
else if (self.enemy.state == STATE_TOP)
self.enemy.nextthink = max(self.enemy.nextthink, self.enemy.ltime + 1); // delay going down
}
/*
void() plat_outside_touch =
{
if (!CheckValidTouch()) return;
//dprint ("plat_outside_touch\n");
self = self.enemy;
if (self.state == STATE_TOP)
plat_go_down ();
}
*/
void() plat_trigger_use =
{
if (self.think)
return; // already activated
plat_go_down();
}
void() plat_crush =
{
//dprint ("plat_crush\n");
if (self.dmg)
T_Damage (other, self, self, self.dmg, DMGTYPE_CRUSH);
if (self.state == STATE_UP)
plat_go_down ();
else if (self.state == STATE_DOWN)
plat_go_up ();
else
dprint("plat_crush: bad self.state\n");
}
void(entity p) plat_force =
{
if (p.customflags & CFL_LOCKED) return;
if (p.state == STATE_TOP || p.state == STATE_UP)
SUB_CallAsSelf(plat_go_down, p);
else
SUB_CallAsSelf(plat_go_up, p);
}
void() plat_use =
{
self.use = SUB_Null;
if (self.state != STATE_UP)
dprint("plat_use: not in up state\n");
plat_go_down();
}
void(float unlock) plat_lock =
{
if (unlock)
{
self.trigger_field.touch = plat_center_touch;
if (self.targetname != string_null)
self.use = plat_use;
self.customflags = not(self.customflags, CFL_LOCKED);
}
else
{
self.trigger_field.touch = SUB_Null;
self.use = SUB_Null;
self.customflags |= CFL_LOCKED;
}
}
void() plat_finalize =
{
plat_spawn_inside_trigger (); // the "start moving" trigger
// delayed to finalize() bc if the plat spawns before the trigger this will fail
// also delayed so all targeters can spawn:
if (self.targetname != string_null && !door_getslocked(self))
{
setorigin (self, self.pos1);
self.state = STATE_UP;
self.use = plat_use;
}
else
{
setorigin (self, self.pos2);
self.state = STATE_BOTTOM;
}
}
/*QUAKED func_plat (0 .5 .8) ? PLAT_LOW_TRIGGER
Plats are always drawn in the extended position, so they will light correctly.
If the plat is the target of another trigger or button, it will start out disabled in the top position until it is triggered, when it will lower and become a normal plat.
If the plat targets a trigger once/multiple/multiple_box, it will override the plat's default activation zone (consuming the trigger).
"PLAT_LOW_TRIGGER" activation zone will only be at the bottom of the movement course, instead of the whole vertical
"speed" default 150
"lip" implicitly determine the distance the plat moves
"height" explicitly determine the distance the plat moves
"pos1"&"pos2" directly override top and bottom positions - plat can be built anywhere else in the map
"wait" time to pause at apex in seconds, default 3
"sounds"
1: base fast
2: chain slow (default if 0)
-1: silent
Alt Target Pattern: 'target' upon rising, 'target2' upon reaching top, 'target3' upon descending, 'target4' upon reaching bottom.
*/
/*FGD
@SolidClass base(Appearflags, Targetname, Func, Target, AltTarget) = func_plat : "Elevator platform.
Plats are always drawn in the extended position, so they will light correctly.
If the plat is the target of another trigger or button, it will start out disabled in the top position until it is triggered, when it will lower and become a normal plat.
If the plat targets a trigger once/multiple/multiple_box, it will override the plat's default activation zone (consuming the trigger).
Movement distance can be defined with 'height' or 'lip'. By instead setting 'pos1' & 'pos2' you can directly override the top and bottom positions, allowing the plat to be built anywhere else in the map. This is useful for building a plat where it will be lit the best.
The 'low trigger volume' spawnflag will put the activation zone only at the bottom of the movement course, instead of the whole vertical.
Alt Target Pattern: 'target' upon rising, 'target2' upon reaching top, 'target3' upon descending, 'target4' upon reaching bottom."
[
spawnflags(Flags) =
[
1 : "Low trigger volume" : 0
]
target(target_destination) : "Custom activation trigger"
speed(integer) : "Speed" : 150
height(integer) : "Travel altitude (can be negative)" : 0
lip(integer) : "Lip remaining at bottom of move" : 8
dmg(integer) : "Punishment for banging your head" : 1
wait(string) : "Apex pause time" : "3"
pos1(string) : "Override top position (x y z)"
pos2(string) : "Override bottom position (x y z)"
sounds(choices) : "Sound" : 2 =
[
-1: "Silent"
1: "Base fast"
2: "Chain Slow"
]
]
*/
void() func_plat =
{
if (!SUB_ShouldSpawn()) return;
precache_model_safe(self.model);
if (self.sounds == 0)
self.sounds = 2;
// FIXME load generic plat sound
if (self.sounds == -1)
{
if (!self.noise)
self.noise = ("misc/null.wav");
if (!self.noise1)
self.noise1 = ("misc/null.wav");
precache_sound_safe(self.noise);
precache_sound_safe(self.noise1);
}
if (self.sounds == 1)
{
precache_sound_safe ("plats/plat1.wav");
precache_sound_safe ("plats/plat2.wav");
self.noise = "plats/plat1.wav";
self.noise1 = "plats/plat2.wav";
}
if (self.sounds == 2)
{
precache_sound_safe ("plats/medplat1.wav");
precache_sound_safe ("plats/medplat2.wav");
self.noise = "plats/medplat1.wav";
self.noise1 = "plats/medplat2.wav";
}
self.mangle = self.angles;
self.angles = '0 0 0';
// self.classname = "plat";
self.solid = SOLID_BSP;
self.movetype = MOVETYPE_PUSH;
setorigin (self, self.origin);
setmodel (self, self.model);
setsize (self, self.mins, self.maxs);
if (!self.speed)
self.speed = 150;
if (!self.wait)
self.wait = 3;
self.dmg = zeroconvertdefault(self.dmg, 1);
if (!self.height)
{
if (self.distance)
self.height = self.distance;
else
{
if (!self.lip) self.lip = 8;
self.height = self.size_z - self.lip;
}
}
if (!self.pos1 && !self.pos2)
{
// pos1 is the top position, pos2 is the bottom
self.pos1 = self.origin;
self.pos2 = self.origin;
if (self.height)
self.pos2_z = self.origin_z - self.height;
}
self.blocked = plat_crush;
self.use = plat_trigger_use;
self.lock = plat_lock;
self.think = plat_finalize;
self.nextthink = self.ltime + 0.1;
}
//============================================================================
const float TRAIN_INHERIT = 1;
const float TRAIN_TOGGLE = 2;
const float TRAIN_SMOOTHSPEED = 4;
void() train_sounds =
{
if (self.sounds == 0)
{
if (!self.noise)
self.noise = ("misc/null.wav");
if (!self.noise1)
self.noise1 = ("misc/null.wav");
precache_sound_safe(self.noise);
precache_sound_safe(self.noise1);
}
if (self.sounds == 1)
{
self.noise = ("plats/train2.wav");
precache_sound_safe ("plats/train2.wav");
self.noise1 = ("plats/train1.wav");
precache_sound_safe ("plats/train1.wav");
}
if (self.sounds == 2)
{
precache_sound_safe ("plats/plat1.wav");
precache_sound_safe ("plats/plat2.wav");
self.noise1 = "plats/plat1.wav";
self.noise = "plats/plat2.wav";
}
}
/*FGD
@baseclass = TrainSounds [
sounds(choices) : "Sound" : 1 =
[
0: "Silent/Override"
1: "Ratchet Metal"
2: "Base Lift"
]
]
@baseclass base(Appearflags, Targetname, TrainSounds, Func, AltTarget) = Train [
speed(integer) : "Speed (units per second)" : 64
target(target_source) : "Target to start at"
dmg(integer) : "Damage on block" : 2
noise(string) : "Override stop sound"
noise1(string) : "Override move sound"
pausetime(string) : "Default wait time" : "0.1"
]
*/
void() flytrain_ghost_die =
{
if (self.owner.th_melee)
SUB_CallAsSelf(self.owner.th_melee, self.owner);
else
remove(self.owner);
remove(self);
}
void() flytrain_ghost_resume =
{
if (self.state == STATE_OFF) // already deactivated
return;
if (self.pos2)
// we were stopped along a bezier curve, resume with saved values
SUB_CalcMoveCurveSeg();
else
SUB_CalcMove (self.enemy.origin - self.movedir, self.speed, self.th_stand);
}
void() flytrain_ghost_blocked =
{
if (self.state == STATE_OFF) // already deactivated
return;
self.velocity = VEC_ORIGIN;
self.think = flytrain_ghost_resume;
self.nextthink = localtime(self) + 0.05;
}
// if the flytrain is blocked, it has to halt its buddy's movement and schedule it to restart immediately
void() flytrain_blocked =
{
if (self.buddy.state == STATE_ON)
SUB_CallAsSelf(flytrain_ghost_blocked, self.buddy);
if (time < self.attack_finished)
return;
self.attack_finished = time + self.dmgtime;
T_Damage (other, self, self, self.dmg, DMGTYPE_CRUSH);
}
void() flytrain_killed =
{
if (self.customflags & CFL_LOCKED) return;
activator = damage_attacker;
self.health = self.max_health;
SUB_CallAsSelf(train_use, self.buddy);
}
void() flytrain_think =
{
vector ang, delta, wishvel;
float d, t;
self.takedamage = self.buddy.takedamage;
// if the ghost train hits a speed -1 teleport corner we have to teleport with it, not zoom to it
if (self.buddy.teleport_time)
{
self.buddy.teleport_time = 0;
setorigin(self, self.buddy.origin - self.movedir);
self.velocity = self.buddy.velocity;
}
else
{
// rosette movement looks more orbital than the original bounce of random offsets
t = localtime(self) + self.lip;
ang_y = (sin(self.dest_x * t) + cos(self.dest_y * t)) * 90 + t;
d = cos(t * self.dest_z);
ang_z = d * 180;
makevectors(ang);
self.pos1 = v_forward * self.width * d;
self.pos1_z = v_right_z * self.height;
delta = (self.buddy.origin + self.pos1) - self.origin - self.movedir;
wishvel = self.buddy.velocity + delta;
self.velocity = (self.velocity * 4 + wishvel) * 0.2;
}
self.nextthink = localtime(self) + 0.05;
}
void() flytrain_init =
{
setorigin (self, self.buddy.origin - self.movedir);
self.think = flytrain_think;
flytrain_think();
}
void() flytrain_setup =
{
// spawn a nonsolid point ent to follow our path sensibly and
// handle all train-like logic, bc it's a func_train
// we shadow it at all times with floaty drifty movement to keep
// that logic separate from train behavior and allow us to sludge
// the velocity over a few frames for rubber-bandy motion without
// colliding with state changes
self.buddy = spawn();
self.buddy.spawnflags = self.spawnflags | TRAIN_INHERIT | TRAIN_SMOOTHSPEED; // flytrains always inherit speed
self.buddy.speed = self.speed;
self.dmg = zeroconvertdefault(self.dmg, 2);
if (!self.dmgtime)
self.dmgtime = 0.5;
self.buddy.pausetime = self.pausetime;
self.buddy.health = self.health;
self.buddy.sounds = self.sounds;
self.buddy.solid = -1;
if (!self.target)
{
dprint3("flytrain without a target at ", vtos(self.origin + self.movedir), " will hover in place\n");
self.buddy.enemy = spawn();
setorigin(self.buddy.enemy, self.origin + self.movedir);
self.buddy.enemy.classname = "path_corner";
self.buddy.enemy.wait = -1;
}
SUB_CopyTargets(self.buddy);
self.buddy.targetname = self.targetname;
self.buddy.owner = self;
SUB_CallAsSelf(func_train_point, self.buddy);
self.buddy.classname = "func_flytrain_ghost";
self.buddy.th_stand = train_wait;
self.buddy.th_melee = flytrain_ghost_die;
self.width = zeroconvertdefault(self.width, 8);
self.height = zeroconvertdefault(self.height, 8);
self.max_health = 0;
self.blocked = flytrain_blocked;
self.solid = zeroconvertdefault(self.solid, SOLID_BSP);
if (!self.solid)
self.movetype = MOVETYPE_NOCLIP;
else
{
self.movetype = MOVETYPE_PUSH;
if (self.health)
{
self.max_health = self.health;
self.th_die = flytrain_killed;
self.takedamage = DAMAGE_YES;
}
}
self.dest_x = 3 + random();
self.dest_y = 1 + random();
self.dest_z = 4 + random();
if (self.speed2 <= 0) self.speed2 = 10;
self.dest *= self.speed2;
self.lip = random() * 20;
self.think = flytrain_init; // wait for buddy to call train_find
self.nextthink = localtime(self) + 0.25; // magic amount of time :|
}
/*QUAKED func_flytrain (0 .5 .8) ? - TOGGLE
Acts as a func_train with PATH_SPEED and SMOOTH_SPEED set, with additional random motion and and gentle smoothing at stops, starts, and hard corners.
"width" Horizontal drift range, default 8 (-1 for 0)
"height" Vertical drift range, default 8 (-1 for 0)
"lip" Length of 'leash', default 64 (increase if train jumps around at high speeds)
"sounds"
0) none, or, set your own with 'noise' (stop sound) and 'noise1' (move sound)
1) ratchet metal
2) base plat
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination
*/
/*FGD
@baseclass base(Train) = Flytrain [
width(string) : "Horizontal drift range" : "8"
height(string) : "Vertical drift range" : "8"
]
@SolidClass base(Flytrain) = func_flytrain :
"Acts as a func_train with PATH_SPEED and SMOOTH_SPEED set, with additional random motion and and gentle smoothing at stops, starts, and hard corners. Will fire all targets of a pathcorner on arrival, but does not normally fire its own targets.
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination"
[
width(string) : "Horizontal drift range" : "8"
height(string) : "Vertical drift range" : "8"
]
*/
void() func_flytrain =
{
if (!SUB_ShouldSpawn()) return;
dprint("in flytrain\n");
precache_model_safe(self.model);
setmodel (self, self.model);
setsize (self, self.mins , self.maxs);
self.movedir = (self.mins + self.maxs) * 0.5;
flytrain_setup();
}
/*QUAKED func_flytrain_point (0 .5 .8) (-8 -8 -8) (8 8 8) - TOGGLE
Acts as a func_train with PATH_SPEED and SMOOTH_SPEED set, with additional random motion and and gentle smoothing at stops, starts, and hard corners.
"model" model to use
"width" Horizontal drift range, default 8 (-1 for 0)
"height" Vertical drift range, default 8 (-1 for 0)
"lip" Length of 'leash', default 64 (increase if train jumps around at high speeds)
"sounds"
0) none, or, set your own with 'noise' (stop sound) and 'noise1' (move sound)
1) ratchet metal
2) base plat
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination
*/
/*FGD
@PointClass base(Flytrain) size(16 16 16) = func_flytrain_point :
"Acts as a func_train with PATH_SPEED and SMOOTH_SPEED set, with additional random motion and and gentle smoothing at stops, starts, and hard corners. Will fire all targets of a pathcorner on arrival, but does not normally fire its own targets.
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination"
[
model(string) : "Model to use"
]
*/
void() func_flytrain_point =
{
if (!SUB_ShouldSpawn()) return;
precache_model_safe(self.model);
setmodel (self, self.model);
setsize (self, self.mins , self.maxs);
self.classname = "func_flytrain";
self.movedir = '0 0 0';
flytrain_setup();
}
//============================================================================
void() train_blocked =
{
if (time < self.attack_finished)
return;
self.attack_finished = time + self.dmgtime;
T_Damage (other, self, self, self.dmg, DMGTYPE_CRUSH);
}
void() train_killed =
{
if (self.customflags & CFL_LOCKED) return;
activator = damage_attacker;
self.health = self.max_health;
train_use();
}
void(float unlock) train_lock =
{
if (unlock)
{
self.customflags = not(self.customflags, CFL_LOCKED);
if (self.max_health)
{
self.health = self.max_health;
self.takedamage = DAMAGE_YES;
}
}
else
{
self.customflags |= CFL_LOCKED;
self.takedamage = DAMAGE_NO;
}
}
void() train_off =
{
self.state = STATE_OFF;
if (self.customflags & CFL_LOCKED) return;
if (self.max_health)
{
self.health = self.max_health;
self.takedamage = DAMAGE_YES;
}
}
void() train_on =
{
self.state = STATE_ON;
if (self.max_health && !(self.spawnflags & TRAIN_TOGGLE))
self.takedamage = DAMAGE_NO;
}
void() train_use =
{
self.aiment = activator; // .enemy is used so we store activating player here
if ((self.spawnflags & TRAIN_TOGGLE) && (self.origin + self.movedir) != self.enemy.origin)
{
if (self.state == STATE_ON)
{
train_off();
self.velocity = VEC_ORIGIN;
self.nextthink = 0;
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
}
else
{
train_on();
sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
if (self.pos2)
// we were stopped along a bezier curve, resume with saved values
SUB_CalcMoveCurveSeg();
else
SUB_CalcMove (self.enemy.origin - self.movedir, self.speed, self.th_stand);
}
return;
}
if (self.state == STATE_ON) // already activated
return;
train_next();
}
void() train_wait = // arrival at a pathcorner
{
entity corner = self.enemy;
if (corner.wait)
self.wait = corner.wait;
else
self.wait = self.pausetime;
// if a player is riding the train, treat them as activator
activator = self.aiment;
if (activator.classname != "player")
{
activator = get_closest_client();
self.aiment = activator;
}
SUB_UseTargetsAlt(target2);
if (self.wait == -1)
{
train_off();
self.use = train_use;
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
}
else if (self.wait > 0)
{
train_off(); // allow triggering while waiting
self.think = train_next;
self.nextthink = localtime(self) + self.wait;
if (self.wait > 0.1)
sound (self, CHAN_VOICE, self.noise, 1, ATTN_NORM);
}
else // self.wait is 0 or a garbage value
{
train_next();
}
// fire pathcorners' targets on arrival
SUB_UseEntTargets(corner);
// fire them after sorting corner wait stuff, in case the corner triggers
// the train itself (useful for wait-locking a pathcorner with a relay)
}
void() train_next = // departure for next pathcorner
{
entity corner, ctrl;
float dspeed, segs;
corner = findunlockedtarget(self.enemy, world);
if (!corner)
{
dprint("train_next: no next target\n");
// .th_melee is a train's "expire at end of path" function, because .th_die
// has to be reserved for shootable trains to work with T_Damage()/Killed()
if (self.th_melee)
self.th_melee();
else
remove(self);
SUB_UseTargetsAlt(target4);
return;
}
self.oldenemy = self.enemy;
if (corner.spawnflags & 16)
{
ctrl = corner;
corner = findunlockedtarget(ctrl, world);
if (!corner)
{
dprint("train_next: no next target after curve point\n");
if (self.th_melee)
self.th_melee();
else
remove(self);
SUB_UseTargetsAlt(target4);
return;
}
}
self.enemy = corner;
SUB_UseTargetsAlt(target3);
train_on();
if (self.oldenemy.speed == -1)
{
setorigin(self, corner.origin - self.movedir);
self.teleport_time = time;
self.th_stand();
return;
}
else if (self.oldenemy.speed > 0 && self.spawnflags & TRAIN_INHERIT)
self.speed = self.oldenemy.speed;
sound (self, CHAN_VOICE, self.noise1, 1, ATTN_NORM);
if (ctrl)
{
if ((self.spawnflags & TRAIN_INHERIT) && (self.spawnflags & TRAIN_SMOOTHSPEED) && corner.speed > 0)
dspeed = corner.speed;
else
dspeed = self.speed;
if (ctrl.count)
segs = ctrl.count;
else
// chop the curve into roughly 200ms segments
segs = ceil(5 * bez_lenApprox(self.origin, ctrl.origin, corner.origin) / ((self.speed + dspeed) / 2));
SUB_CalcMoveCurve(corner.origin - self.movedir, ctrl.origin - self.movedir, segs, self.speed, dspeed, self.th_stand);
return;
}
if ((self.spawnflags & TRAIN_INHERIT) && (self.spawnflags & TRAIN_SMOOTHSPEED) && self.enemy.speed > 0)
{
// 'curved' motion in a straight line, for the speed stepping
vector travel = (corner.origin - self.movedir) - self.origin;
segs = max( 2, floor( vlen(travel) / 64 ) ); // pick an intelligent segment count
SUB_CalcMoveCurve(corner.origin - self.movedir, self.origin + travel * 0.5, segs, self.speed, self.enemy.speed, self.th_stand);
}
else
SUB_CalcMove (corner.origin - self.movedir, self.speed, self.th_stand);
}
void() func_train_find =
{
if (!self.enemy)
self.enemy = findunlockedtarget(self, world);
//self.target = self.enemy.target;
setorigin (self, self.enemy.origin - self.movedir);
if ((self.spawnflags & TRAIN_INHERIT) && self.enemy.speed > 0)
self.speed = self.enemy.speed;
if (self.targetname == string_null)
{ // not triggered, so start immediately
train_wait(); // still go through wait in case we start at a wait -1 corner
}
}
void() func_train_setup =
{
if (!self.speed)
self.speed = 100;
if (!self.target && !self.enemy)
objerror("func_train without a target");
self.dmg = zeroconvertdefault(self.dmg, 2);
if (!self.dmgtime)
self.dmgtime = 0.5;
self.pausetime = zeroconvertdefault(self.pausetime, 0.1);
self.wait = 0; // this is american mcgee's fault
train_sounds();
// self.cnt = 1;
self.solid = zeroconvertdefault(self.solid, SOLID_BSP);
if (!self.solid)
self.movetype = MOVETYPE_NOCLIP;
else
self.movetype = MOVETYPE_PUSH;
self.blocked = train_blocked;
self.use = train_use;
self.lock = train_lock;
self.classname = "train";
self.max_health = 0;
if (self.health)
{
self.max_health = self.health;
self.th_die = train_killed;
self.takedamage = DAMAGE_YES;
}
train_off();
// start trains on the second frame, to make sure their targets have had
// a chance to spawn
self.think = func_train_find;
self.nextthink = localtime(self) + 0.1;
}
/*QUAKED func_train (0 .5 .8) ? PATH_SPEED TOGGLE SMOOTHSPEED
Trains are moving platforms that players can ride. Its origin is the min corner of the train.
The train spawns at the first target it is pointing at. If the train is the target of a button or trigger, it will not begin moving until activated.
A train will fire all targets of a pathcorner on arrival.
Keys:
"speed" default 100
"dmg" default 2
"sounds"
0) none, or, set your own with 'noise' (stop sound) and 'noise1' (move sound)
1) ratchet metal
2) base plat
"pausetime" pausetime at a pathcorner that doesn't specify a wait, default 0.1, -1 for continuous motion
"health" allow the train to be shot to trigger it whenever it could normally be triggered (toggle spawnflag applies)
Spawnflags:
PATH_SPEED: train will inherit 'speed' value from path_corners as it reaches them
If a path_corner's speed is -1, the func_train's move when LEAVING that corner will be to snap instantly to the next corner.
TOGGLE: allow starting/stopping motion anywhere on its path (default is to ignore triggerings when in motion)
SMOOTH_SPEED: if PATH_SPEED, train will smoothly blend to its destination's 'speed' as it travels to it
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination
*/
/*FGD
@SolidClass base(Train) = func_train : "Moving platform that players can ride.
Its origin is the min corner of the train.
The train spawns at the first target it is pointing at. If the train is the target of a button or trigger, it will not begin moving until activated.
Will fire all targets of a pathcorner on arrival, but does not normally fire its own targets.
If 'Speed from path' is set, the train will inherit the 'speed' value from path_corners as it reaches them. If 'blend speed smoothly' is also set, the train will instead smoothly blend to its destination's 'speed' as it travels to it.
If a path_corner's speed is -1, the func_train's move when LEAVING that corner will be to snap instantly to the next corner.
The 'Toggle' spawnflag allows starting and stopping the motion anywhere on the train's path (default is to ignore triggerings when in motion).
Setting 'health' will allow the train to be shot to trigger it whenever it could normally be triggered (toggle spawnflag applies).
Alt Target Pattern: 'target' selects path start, 'target2' on each pathcorner arrival, 'target3' on each departure, 'target4' on termination"
[
spawnflags(Flags) = [
1 : "Speed from path" : 0
2 : "Toggle" : 0
4 : "Blend speed smoothly" : 0
]
health(integer) : "Health (shootable if > 0)"