ESP32 + RFM95/96/SX127x: Can't pass begin() no matter what...

[cagroh]

Hi!
I don't consider myself a newbie anymore ;) and yes, I've read all troubleshooting info available on the Wiki.
But still, I'm facing a very strange problem.
After having successfully run the "SX127x_settings.ino" example, I decided to give "SX127x_pingpong.ino" a try.
Problem is, I can't get thru begin(). And, most weird of all, going back to "SX127x_settings.ino" doesn't work anymore either.
Have tried different hardwares, both MCUs and radios, even brand new ones, no hope!
Here's my hardware config:

• Two ESP32-WROOM-32D dev board with 38 pins (also tried with two brand new ESP32 30-pin dev modules)
• Two RFM92 915 MHz LoRa transceivers (also tried with two NiceRF SX1276-V2)

The wiring:

LoRa Pin	ESP32 Pin	Wire color
GND	GND	Black
VIN	3V3	Red
MISO	GPIO19	White
MOSI	GPIO23	White with brown stripe
SCK	GPIO18	Green
NSS	GPIO16	Gray
NRST	GPIO17	Orange
DIO0	GPIO4	Brown
DIO1	GPIO5	Light brown

Due to the non-standard SPI pinout, I also added the recommended SPI customization, as you can see on the code:

/*
   RadioLib SX127x Ping-Pong Example

   For default module settings, see the wiki page
   https://github.com/jgromes/RadioLib/wiki/Default-configuration#sx127xrfm9x---lora-modem

   For full API reference, see the GitHub Pages
   https://jgromes.github.io/RadioLib/
*/

// include the library
#include <RadioLib.h>
#include <SPI.h>

#define RADIOLIB_DEBUG_BASIC        (1)
#define RADIOLIB_DEBUG_PROTOCOL     (1)
#define RADIOLIB_DEBUG_SPI          (1)

// uncomment the following only on one
// of the nodes to initiate the pings
//#define INITIATING_NODE

// SX1276 has the following connections:
// NSS pin:   10
// DIO0 pin:  2
// NRST pin:  9
// DIO1 pin:  3

static const uint8_t LoRa_DIO0 =  4; // Busy
static const uint8_t LoRa_DIO1 =  5;
static const uint8_t LoRa_NSS  = 16;
static const uint8_t LoRa_NRST = 17;
static const uint8_t LoRa_SCK  = 18;
static const uint8_t LoRa_MISO = 19;
static const uint8_t LoRa_MOSI = 23;

SPIClass spi(VSPI);
SPISettings spiSettings(4e6, MSBFIRST, SPI_MODE0);


// SX1276 radio = new Module(10, 2, 9, 3);
SX1276 radio = new Module(LoRa_NSS, LoRa_DIO1, LoRa_NRST, LoRa_DIO0, spi, spiSettings);

// or using RadioShield
// https://github.com/jgromes/RadioShield
//SX1276 radio = RadioShield.ModuleA;

// save transmission states between loops
int transmissionState = RADIOLIB_ERR_NONE;

// flag to indicate transmission or reception state
bool transmitFlag = false;

// flag to indicate that a packet was sent or received
volatile bool operationDone = false;

// this function is called when a complete packet
// is transmitted or received by the module
// IMPORTANT: this function MUST be 'void' type
//            and MUST NOT have any arguments!
#if defined(ESP8266) || defined(ESP32)
  ICACHE_RAM_ATTR
#endif
void setFlag(void) {
  // we sent or received  packet, set the flag
  operationDone = true;
}

void setup() {
  Serial.begin(115200);

  spi.begin(LoRa_SCK, LoRa_MISO, LoRa_MOSI, LoRa_NSS);
  spi.setFrequency(4e6); // 4MHz (ESP32 max SPI clock is 10MHz)
  Serial.printf("SPI.begin(SCK=%d, MISO=%d, MOSI=%d, CS=%d)@4MHz\r\n", LoRa_SCK, LoRa_MISO, LoRa_MOSI, LoRa_NSS);

  // initialize SX1276 with default settings
  Serial.print(F("[SX1276] Initializing ... "));
  int state = radio.begin(915.0, 125.0, 9, 7, 0x47, 10, 8, false);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }

  // set the function that will be called
  // when new packet is received
  radio.setDio0Action(setFlag, RISING);

  #if defined(INITIATING_NODE)
    // send the first packet on this node
    Serial.print(F("[SX1276] Sending first packet ... "));
    transmissionState = radio.startTransmit("Hello World!");
    transmitFlag = true;
  #else
    // start listening for LoRa packets on this node
    Serial.print(F("[SX1276] Starting to listen ... "));
    state = radio.startReceive();
    if (state == RADIOLIB_ERR_NONE) {
      Serial.println(F("success!"));
    } else {
      Serial.print(F("failed, code "));
      Serial.println(state);
      while (true) { delay(10); }
    }
  #endif
}

void loop() {
  // check if the previous operation finished
  if(operationDone) {
    // reset flag
    operationDone = false;
    if(transmitFlag) {
      // the previous operation was transmission, listen for response
      // print the result
      if (transmissionState == RADIOLIB_ERR_NONE) {
        // packet was successfully sent
        Serial.println(F("transmission finished!"));

      } else {
        Serial.print(F("failed, code "));
        Serial.println(transmissionState);

      }

      // listen for response
      radio.startReceive();
      transmitFlag = false;

    } else {
      // the previous operation was reception
      // print data and send another packet
      String str;
      int state = radio.readData(str);

      if (state == RADIOLIB_ERR_NONE) {
        // packet was successfully received
        Serial.println(F("[SX1276] Received packet!"));

        // print data of the packet
        Serial.print(F("[SX1276] Data:\t\t"));
        Serial.println(str);

        // print RSSI (Received Signal Strength Indicator)
        Serial.print(F("[SX1276] RSSI:\t\t"));
        Serial.print(radio.getRSSI());
        Serial.println(F(" dBm"));

        // print SNR (Signal-to-Noise Ratio)
        Serial.print(F("[SX1276] SNR:\t\t"));
        Serial.print(radio.getSNR());
        Serial.println(F(" dB"));

      }

      // wait a second before transmitting again
      delay(1000);

      // send another one
      Serial.print(F("[SX1276] Sending another packet ... "));
      transmissionState = radio.startTransmit("Hello World!");
      transmitFlag = true;
    }
  }
}

Everytime I upload the code or perform a board reset, the program restarts but aborts with error code -2 or -16:

ets Jul 29 2019 12:21:46
rst:0x1 (POWERON_RESET),boot:0x12 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:1
load:0x3fff0030,len:4832
load:0x40078000,len:16460
load:0x40080400,len:4
load:0x40080404,len:3504
entry 0x400805cc
SPI.begin(SCK=18, MISO=19, MOSI=23, CS=16)@4MHz
[SX1276] Initializing ... failed, code -2
ets Jul 29 2019 12:21:46

rst:0x1 (POWERON_RESET),boot:0x12 (SPI_FAST_FLASH_BOOT)
configsip: 0, SPIWP:0xee
clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00
mode:DIO, clock div:1
load:0x3fff0030,len:4832
load:0x40078000,len:16460
load:0x40080400,len:4
load:0x40080404,len:3504
entry 0x400805cc
SPI.begin(SCK=18, MISO=19, MOSI=23, CS=16)@4MHz
[SX1276] Initializing ... failed, code -16

I've of course checked and rechecked all connections and wirings, having even replaced some, but to no avail. Also enabled debug mode but nothing relevant was revealed.
What confuses me most is that it worked with the first test I made (file "SX127x_settings.ino"), and simply applying another program seems to have rendered some intermittence.
I appreciate any help.
Cesar

[jgromes]

Couple of things:

1. You can't enable debug by just putting the macros in your script. You have to define them either in the library, or somewhere in the build environment. It will be probably easiest for you to do this in src/BuildOptUser.h. Examine the debug output, if you do it correctly there is always some extra output.
2. Your DIO0 and DIO1 is swapped, but that shouldn't cause issues with SPI. Still, this feels very much like a hardware issue.
3. The effort with the capacitors on VCC is appreciated, but on those leads through a breadboard, you have them connected via so much inductance, I can assure you they do nothing. Though this is likely unrelated to your problem.

[cagroh]

Hi Jan!
Thank you for your reply. It turns out that the problem seems to be the breadboard itself.
I eliminated it and jumped the radio and the ESP32 directly using jumpers tested for low-resistance and it worked like a sharp.
Though the program, even saved with two versions, one for ping and other for pong, isn't "pingponging" ;). (Yes, I took the comment on INITIATING_NODE out on one of them).
I'm going to perform other tests to see where I can get.
Thank you!
Cesar

[cagroh]

Ooops! Also noted the inversion on DIO0 and DIO1 you mentioned.
Now everything works just fine!
Thanks!