-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathomo.v
2094 lines (1943 loc) · 97.2 KB
/
omo.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
From gpfsl.examples Require Import sflib.
From iris.algebra Require Import auth gset gmap agree.
From iris.algebra Require Import lib.mono_list.
From iris.proofmode Require Import tactics.
From gpfsl.base_logic Require Import meta_data.
From gpfsl.examples.algebra Require Import mono_list_list.
From gpfsl.logic Require Import logatom atomics invariants.
From gpfsl.logic Require Import repeat_loop new_delete.
From gpfsl.examples Require Import map_seq loc_helper.
From stdpp Require Import namespaces.
From gpfsl.logic Require Import logatom.
From gpfsl.examples.omo Require Export omo_event omo_history.
Require Import iris.prelude.options.
Notation omoT := (list (event_id * list event_id))%type.
Notation lhb := hb_ord.
(** Pure definitions and lemmas for OMO **)
Section omo.
Context {eventT absStateT : Type}.
Implicit Types
(omo : omoT)
(st : absStateT).
Local Open Scope nat_scope.
(* Typeclass for state transition system *)
Class Interpretable eventT absStateT : Type :=
{
(* Initial State *)
init : absStateT;
(* Given an event and previous abstract state, interpreted result is new abstract state *)
step : event_id → omo_event eventT → absStateT → absStateT → Prop
}.
Inductive interp `{Interpretable eventT absStateT} : list (event_id * omo_event eventT) → absStateT → absStateT → Prop :=
| interp_nil : ∀ (st : absStateT), interp [] st st
| interp_snoc : ∀ e eV eeVs st1 st2 st3, interp eeVs st1 st2 → step e eV st2 st3 → interp (eeVs ++ [(e, eV)]) st1 st3
.
Notation history := (history eventT).
(** Index to an event in [omo]. [eidx] *)
Inductive event_idx : Set :=
| ro_event (gen i' : nat) (* [i']-th read-only operation of generation [gen] *)
| wr_event (gen : nat) (* the write event of generation [gen] *)
.
Definition gen_of eidx :=
match eidx with
| ro_event gen _ => gen
| wr_event gen => gen
end.
Definition lookup_omo omo eidx : option event_id :=
match eidx with
| ro_event gen i => omo.*2 !! gen ≫= (!!) i
| wr_event gen => omo.*1 !! gen
end.
(** "Lexicographic" order of [eidx] *)
Inductive eidx_le : ∀ (eidx1 eidx2 : event_idx), Prop :=
| eidx_le_r_r_1 gen1 i1' gen2 i2'
(LTgen : gen1 < gen2)
: eidx_le (ro_event gen1 i1') (ro_event gen2 i2')
| eidx_le_r_r_2 gen i1' i2'
(LEi' : i1' ≤ i2')
: eidx_le (ro_event gen i1') (ro_event gen i2')
| eidx_le_r_w gen1 i1' gen2
(LTgen : gen1 < gen2)
: eidx_le (ro_event gen1 i1') (wr_event gen2)
| eidx_le_w_r gen1 gen2 i2'
(LTgen : gen1 ≤ gen2)
: eidx_le (wr_event gen1) (ro_event gen2 i2')
| eidx_le_w_w gen1 gen2
(LEgen : gen1 ≤ gen2)
: eidx_le (wr_event gen1) (wr_event gen2)
.
(** local happens-before implies omo-before. *)
Definition lhb_omo (E : history) omo :=
∀ eidx1 eidx2 e1 e2 eV2
(omo_eidx1 : lookup_omo omo eidx1 = Some e1)
(omo_eidx2 : lookup_omo omo eidx2 = Some e2)
(EV2 : E !! e2 = Some eV2)
(IN_EVIEW : e1 ∈ eV2.(eview)),
eidx_le eidx1 eidx2.
(** Linearization of [omo]. Defined as flattening of omo into an array of event id *)
Definition lin_of_omo omo :=
concat ((λ '(e, es), e :: es) <$> omo).
(** Insert (append) read-only operation to the generation [gen] of [omo]. *)
Definition omo_insert_r omo gen e := alter (λ '(e', es'), (e', es'++[e])) gen omo.
(** Insert a new write operation at [gen]th generation *)
Definition omo_insert_w omo gen e es := take gen omo ++ (e, es) :: drop gen omo.
(** Insert a new write operation at the back *)
Definition omo_append_w omo e es := omo ++ [(e, es)].
(** Collects only write events of OMO.
This is widely used in the invariants of libraries. *)
Definition omo_write_op omo := omo.*1.
(** Collects only read-only events of OMO *)
Definition omo_read_op omo := omo.*2.
(* No [Inj] instance because it's partial *)
Definition omo_inj omo :=
∀ eidx1 eidx2 e
(OMO_LOOKUP1 : lookup_omo omo eidx1 = Some e)
(OMO_LOOKUP2 : lookup_omo omo eidx2 = Some e),
eidx1 = eidx2.
(* Prefix relation of two `OMO`'s *)
Definition omo_prefix omo1 omo2 :=
omo_read_op omo1 `prefixes_of` omo_read_op omo2 ∧
omo_write_op omo1 ⊑ omo_write_op omo2.
(** Convert an [eidx] into an index in [lin]. *)
Definition eidx_to_lin_idx omo eidx :=
match eidx with
| ro_event gen i' => length (concat ((λ '(e, es), e :: es) <$> take gen omo)) + S i'
| wr_event gen => length (concat ((λ '(e, es), e :: es) <$> take gen omo))
end.
Inductive interp_omo `{Interpretable eventT absStateT} : history → omoT → absStateT → list absStateT → Prop :=
| interp_omo_nil : ∀ E st, interp_omo E [] st []
| interp_omo_snoc :
∀ E e es eV omo st1 st2 st3 stlist,
E !! e = Some eV ∧
interp_omo E omo st1 stlist ∧
last (st1 :: stlist) = Some st2 ∧
step e eV st2 st3 ∧
Forall (λ e', ∃ eV', E !! e' = Some eV' ∧ step e' eV' st3 st3 ∧ e < e') es →
interp_omo E (omo ++ [(e, es)]) st1 (stlist ++ [st3])
.
Definition perm_omo (E : history) omo : Prop :=
lin_of_omo omo ≡ₚ seq 0 (length E).
(* Definition of linearizability in OMO version *)
Inductive Linearizability_omo (E : history) omo stlist `{Interpretable eventT absStateT} : Prop :=
| Linearizability_omo_intro
(INTERP_OMO : interp_omo E omo init stlist)
(LHB_OMO : lhb_omo E omo)
(PERM_OMO : perm_omo E omo)
.
Definition eid_to_event_valid (E : history) (eeVs : list (event_id * omo_event eventT)) : Prop :=
Forall (λ '(e, eV), E !! e = Some eV) eeVs.
(* Definition of linearizability (in linearizability history specification) *)
Inductive Linearizability E `{Interpretable eventT absStateT} : Prop :=
| Linearizability_intro xo lin st
(XO : xo.*1 = seq 0 (length E)) (* xo (execution order): list (event_id * omo_event) *)
(EEVS_VALID_XO : eid_to_event_valid E xo) (* Checks whether pairing between event_id and omo_event is valid *)
(LIN_PERM : lin ≡ₚ xo) (* lin: permutation of xo *)
(LHB_LIN : lhb E lin.*1) (* linearization order satisfies happens-before order *)
(INTERP_LIN : interp lin init st) (* linearization order is interpretable *)
.
Section omo_lemmas.
#[global] Instance eidx_eqdec : EqDecision event_idx.
Proof. solve_decision. Qed.
Lemma interp_omo_length E omo st stlist `{Interpretable eventT absStateT}
(INTERP_OMO : interp_omo E omo st stlist) :
length omo = length stlist.
Proof.
generalize dependent stlist. induction omo using rev_ind; intros.
- inversion INTERP_OMO; [done|]. apply (f_equal length) in H0. rewrite app_length /= in H0. lia.
- inversion INTERP_OMO; [done|]. destruct H2 as [_ [H2 _]].
apply app_inj_2 in H0 as [EQ _]; [|done]. subst omo0.
specialize (IHomo _ H2). rewrite !app_length /=. lia.
Qed.
Lemma interp_app eeVs1 eeVs2 st1 st2 `{Interpretable eventT absStateT} :
interp (eeVs1 ++ eeVs2) st1 st2 ↔
∃ st3, interp eeVs1 st1 st3 ∧ interp eeVs2 st3 st2.
Proof.
split; intros.
- revert st2 H0. induction eeVs2 using rev_ind; intros.
+ exists st2. simplify_list_eq. split; [done|]. apply interp_nil.
+ replace (eeVs1 ++ eeVs2 ++ [x]) with ((eeVs1 ++ eeVs2) ++ [x]) in H0; [|by simplify_list_eq].
inversion H0.
{ apply (f_equal length) in H2. rewrite app_length /= in H2. lia. }
apply app_inj_2 in H1 as [-> EQ]; [|done]. inversion EQ. subst x st0 st4. clear EQ.
specialize (IHeeVs2 _ H2) as [st4 [INTERP1 INTERP2]].
exists st4. split; [done|]. eapply interp_snoc; try done.
- revert st2 H0. induction eeVs2 using rev_ind; intros.
+ destruct H0 as [st3 [INTERP1 INTERP2]].
inversion INTERP2; last first.
{ apply (f_equal length) in H0. rewrite app_length /= in H0. lia. }
subst st st2. simplify_list_eq. done.
+ destruct H0 as [st3 [INTERP1 INTERP2]].
inversion INTERP2.
{ apply (f_equal length) in H1. rewrite app_length /= in H1. lia. }
apply app_inj_2 in H0 as [-> EQ]; [|done]. inversion EQ. subst st0 st5 x. clear EQ.
replace (eeVs1 ++ eeVs2 ++ [(e, eV)]) with ((eeVs1 ++ eeVs2) ++ [(e, eV)]); [|by simplify_list_eq].
eapply interp_snoc; try done. apply IHeeVs2. by eexists.
Qed.
Lemma interp_omo_app E omo1 omo2 st1 stlist1 stlist2 `{Interpretable eventT absStateT}
(EQlen : length omo1 = length stlist1) :
interp_omo E (omo1 ++ omo2) st1 (stlist1 ++ stlist2) ↔
∃ st2, interp_omo E omo1 st1 stlist1 ∧ interp_omo E omo2 st2 stlist2 ∧ last (st1 :: stlist1) = Some st2.
Proof.
split; intros.
- generalize dependent stlist2. induction omo2 using rev_ind; intros.
+ apply interp_omo_length in H0 as EQlen'.
rewrite !app_length EQlen /= Nat.add_0_r in EQlen'. destruct stlist2; last first.
{ simpl in EQlen'. clear -EQlen'. lia. }
simplify_list_eq.
have [st3 Hst3] : is_Some (last (st1 :: stlist1)) by rewrite last_is_Some.
exists st3. split_and!; try done. apply interp_omo_nil.
+ apply interp_omo_length in H0 as EQlen'.
rewrite !app_length EQlen /= in EQlen'.
destruct stlist2 using rev_ind; [simpl in *;lia|]. clear IHstlist2.
have EQlen2 : length omo2 = length stlist2.
{ rewrite app_length /= in EQlen'. lia. }
replace (omo1 ++ omo2 ++ [x]) with ((omo1 ++ omo2) ++ [x]) in H0; [|by simplify_list_eq].
replace (stlist1 ++ stlist2 ++ [x0]) with ((stlist1 ++ stlist2) ++ [x0]) in H0; [|by simplify_list_eq].
inversion H0.
{ apply (f_equal length) in H3. rewrite app_length /= in H3. lia. }
apply app_inj_2 in H1 as [-> EQ1]; [|done]. apply app_inj_2 in H3 as [-> EQ2]; [|done].
inversion EQ1. inversion EQ2. subst E0 st0 x x0. clear EQ1 EQ2.
destruct H5 as (H1 & H2 & H3 & H4 & H5).
specialize (IHomo2 _ H2) as (st5 & INTERP_OMO1 & INTERP_OMO2 & LAST).
exists st5. split_and!; try done. eapply interp_omo_snoc. split_and!; try done.
rewrite last_cons. rewrite last_cons last_app in H3.
destruct (last stlist2) eqn:Heq; [done|].
rewrite last_cons in LAST. destruct (last stlist1) eqn:Heq';
by rewrite -H3 -LAST.
- generalize dependent stlist2. induction omo2 using rev_ind; intros.
+ destruct H0 as (st3 & INTERP_OMO1 & INTERP_OMO2 & LAST).
inversion INTERP_OMO2; last first.
{ apply (f_equal length) in H0. rewrite app_length /= in H0. lia. }
subst E0 st stlist2. simplify_list_eq. done.
+ destruct H0 as (st3 & INTERP_OMO1 & INTERP_OMO2 & LAST).
inversion INTERP_OMO2.
{ apply (f_equal length) in H2. rewrite app_length /= in H2. lia. }
apply app_inj_2 in H0 as [-> EQ]; [|done]. inversion EQ. subst E0 st0 stlist2 x. rename stlist into stlist2. clear EQ.
destruct H2 as (H1 & H2 & H3 & H4 & H5).
have COND : ∃ st', interp_omo E omo1 st1 stlist1 ∧ interp_omo E omo2 st' stlist2 ∧ last (st1 :: stlist1) = Some st'.
{ exists st3. split_and!; try done. }
specialize (IHomo2 _ COND).
replace (omo1 ++ omo2 ++ [(e, es)]) with ((omo1 ++ omo2) ++ [(e, es)]); [|by simplify_list_eq].
replace (stlist1 ++ stlist2 ++ [st4]) with ((stlist1 ++ stlist2) ++ [st4]); [|by simplify_list_eq].
eapply interp_omo_snoc. split_and!; try done.
rewrite last_cons last_app. rewrite !last_cons in H3,LAST.
destruct (last stlist2) eqn:Heq1; [done|].
destruct (last stlist1) eqn:Heq2;
by rewrite LAST H3.
Qed.
Lemma interp_app_inv eeVs1 eeVs2 st1 st2 `{Interpretable eventT absStateT} :
interp (eeVs1 ++ eeVs2) st1 st2 →
∃ st3, interp eeVs1 st1 st3 ∧ interp eeVs2 st3 st2.
Proof. by apply interp_app. Qed.
Lemma lookup_omo_ro_event omo gen i :
lookup_omo omo (ro_event gen i) = omo_read_op omo !! gen ≫= (!!) i.
Proof. done. Qed.
Lemma lookup_omo_inv_r omo gen i e
(LOOKUP : lookup_omo omo (ro_event gen i) = Some e) :
∃ es,
omo_read_op omo !! gen = Some es ∧
es !! i = Some e.
Proof.
rewrite lookup_omo_ro_event in LOOKUP.
destruct (omo_read_op omo !! gen) eqn:Heq; [|done].
simpl in LOOKUP. by exists l.
Qed.
Lemma lookup_omo_wr_event omo gen :
lookup_omo omo (wr_event gen) = omo_write_op omo !! gen.
Proof. done. Qed.
Lemma interp_omo_take E omo st stlist i `{Interpretable eventT absStateT}
(INTERP_OMO : interp_omo E omo st stlist) :
interp_omo E (take i omo) st (take i stlist).
Proof.
destruct (le_lt_dec (length omo) i) as [LE|LT].
{ have EQlen : length omo = length stlist by eapply interp_omo_length.
rewrite take_ge; [|done]. rewrite take_ge; [|lia]. done. }
generalize dependent stlist. induction omo using rev_ind; intros; [simpl in *; lia|].
inversion INTERP_OMO.
{ apply (f_equal length) in H2. rewrite app_length /= in H2. lia. }
apply app_inj_2 in H0 as [EQ1 EQ2]; [|done].
inversion EQ2. subst x omo0 st1 stlist E0. clear EQ2. rename stlist0 into stlist.
destruct (decide (i = length omo)) as [->|NEQ].
{ have EQlen : length (omo ++ [(e, es)]) = length (stlist ++ [st3]) by eapply interp_omo_length.
rewrite take_app. rewrite !app_length /= in EQlen. replace (length omo) with (length stlist) by lia.
rewrite take_app. by destruct H2 as [_ [? _]]. }
rewrite app_length /= in LT.
have LT' : i < length omo by lia.
destruct H2 as [_ [H2 _]]. specialize (IHomo LT' _ H2).
rewrite take_app_le; [|lia].
have EQlen : length (omo ++ [(e, es)]) = length (stlist ++ [st3]) by eapply interp_omo_length.
rewrite !app_length /= in EQlen.
rewrite take_app_le; [|lia]. done.
Qed.
Lemma lookup_omo_event_valid E omo stlist eidx e `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist)
(LOOKUP : lookup_omo omo eidx = Some e) :
is_Some (E !! e).
Proof.
destruct OMO_GOOD. destruct eidx.
- specialize (interp_omo_take _ _ _ _ (S gen) INTERP_OMO) as INTERP_OMO'.
rewrite lookup_omo_ro_event /omo_read_op list_lookup_fmap in LOOKUP.
destruct (omo !! gen) eqn:Heq; [|done]. destruct p as [e' es']. simpl in LOOKUP.
rewrite (take_S_r _ _ (e', es')) in INTERP_OMO'; [|done].
inversion INTERP_OMO'.
{ apply (f_equal length) in H2. rewrite app_length /= in H2. lia. }
apply app_inj_2 in H0 as [-> EQ]; [|done]. inversion EQ. subst E0 st1 e0 es. clear EQ H2.
destruct H4 as (_ & _ & _ & _ & H1).
rewrite Forall_lookup in H1. specialize (H1 _ _ LOOKUP) as [eV' [H1 _]]. done.
- specialize (interp_omo_take _ _ _ _ (S gen) INTERP_OMO) as INTERP_OMO'.
rewrite lookup_omo_wr_event /omo_write_op list_lookup_fmap in LOOKUP.
destruct (omo !! gen) eqn:Heq; [|done]. destruct p as [e' es']. simpl in LOOKUP. inversion LOOKUP. subst e'.
rewrite (take_S_r _ _ (e, es')) in INTERP_OMO'; [|done].
inversion INTERP_OMO'.
{ apply (f_equal length) in H2. rewrite app_length /= in H2. lia. }
apply app_inj_2 in H0 as [-> EQ]; [|done]. inversion EQ. subst E0 st1 e0 es. clear EQ H2.
by destruct H4 as [H1 _].
Qed.
Lemma omo_same omo omo' :
omo = omo' ↔
omo_write_op omo = omo_write_op omo' ∧
omo_read_op omo = omo_read_op omo'.
Proof.
split; intros; [subst omo; done|].
destruct H as [H1 H2]. generalize dependent omo'. induction omo; intros.
- by destruct omo'.
- destruct omo'; try done.
inversion H1. inversion H2.
specialize (IHomo _ H3 H5). subst omo. destruct a, p. simpl in H0, H4.
subst e l. done.
Qed.
Lemma list_lookup_omo_destruct omo gen info :
omo !! gen = Some info ↔
omo_write_op omo !! gen = Some info.1 ∧
omo_read_op omo !! gen = Some info.2.
Proof.
split; intros.
- by split; rewrite list_lookup_fmap H.
- destruct H as [H1 H2]. generalize dependent info. generalize dependent gen. induction omo; intros.
+ done.
+ destruct gen.
* simpl in H1, H2. simpl. destruct a, info. inversion H1. inversion H2. done.
* simpl in H1, H2. simpl. by specialize (IHomo _ _ H1 H2).
Qed.
Lemma list_lookup_omo_destruct' omo gen e es :
omo !! gen = Some (e, es) ↔
omo_write_op omo !! gen = Some e ∧
omo_read_op omo !! gen = Some es.
Proof. apply list_lookup_omo_destruct. Qed.
Lemma list_lookup_omo_from_write_op omo gen e :
omo_write_op omo !! gen = Some e →
∃ es, omo !! gen = Some (e, es).
Proof.
rewrite /omo_write_op. intros.
have [x Hx] : is_Some (omo !! gen).
{ rewrite lookup_lt_is_Some. apply lookup_lt_Some in H. by rewrite !fmap_length in H. }
destruct x as [e' es].
rewrite !list_lookup_fmap Hx in H. inversion H. subst e'.
by exists es.
Qed.
Lemma list_lookup_omo_from_read_op omo gen es :
omo_read_op omo !! gen = Some es →
∃ e, omo !! gen = Some (e, es).
Proof.
rewrite /omo_read_op. intros. apply lookup_lt_Some in H as H'.
rewrite fmap_length in H'. apply lookup_lt_is_Some in H' as [ees Hees].
destruct ees as [e es'].
rewrite list_lookup_fmap Hees in H. inversion H. subst es'.
by eexists.
Qed.
Lemma list_lookup_omo_write_op_agree omo gen e e' es
(LOOKUP1 : omo !! gen = Some (e, es))
(LOOKUP2 : omo_write_op omo !! gen = Some e') :
e = e'.
Proof.
rewrite /omo_write_op list_lookup_fmap LOOKUP1 in LOOKUP2.
inversion LOOKUP2. done.
Qed.
Lemma list_lookup_omo_read_op_agree omo gen e es es'
(LOOKUP1 : omo !! gen = Some (e, es))
(LOOKUP2 : omo_read_op omo !! gen = Some es') :
es = es'.
Proof.
rewrite /omo_read_op list_lookup_fmap LOOKUP1 in LOOKUP2.
inversion LOOKUP2. done.
Qed.
Lemma omo_write_op_lt_is_Some omo gen :
is_Some (omo_write_op omo !! gen) ↔ gen < length omo.
Proof. by rewrite /omo_write_op !list_lookup_fmap !fmap_is_Some lookup_lt_is_Some. Qed.
Lemma omo_write_op_lt_Some omo gen e :
omo_write_op omo !! gen = Some e → gen < length omo.
Proof. by rewrite -omo_write_op_lt_is_Some. Qed.
Lemma omo_read_op_lt_is_Some omo gen :
is_Some (omo_read_op omo !! gen) ↔ gen < length omo.
Proof. by rewrite /omo_read_op !list_lookup_fmap !fmap_is_Some lookup_lt_is_Some. Qed.
Lemma omo_read_op_lt_Some omo gen es :
omo_read_op omo !! gen = Some es → gen < length omo.
Proof. by rewrite -omo_read_op_lt_is_Some. Qed.
Lemma lookup_omo_lt_is_Some omo eidx :
is_Some (lookup_omo omo eidx) → gen_of eidx < length omo.
Proof.
destruct eidx; intros.
- simpl in H. destruct (omo !! gen) eqn:Heq.
+ apply lookup_lt_Some in Heq. done.
+ rewrite list_lookup_fmap Heq /= in H. by inversion H.
- rewrite /= lookup_lt_is_Some fmap_length in H. done.
Qed.
Lemma lookup_omo_lt_Some omo eidx e :
lookup_omo omo eidx = Some e → gen_of eidx < length omo.
Proof. intros. by apply lookup_omo_lt_is_Some. Qed.
Lemma omo_write_op_length omo :
length omo = length (omo_write_op omo).
Proof. by rewrite /omo_write_op !fmap_length. Qed.
Lemma omo_read_op_length omo :
length omo = length (omo_read_op omo).
Proof. by rewrite /omo_read_op !fmap_length. Qed.
Lemma omo_stlist_length E omo stlist `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist) :
length omo = length stlist.
Proof.
destruct OMO_GOOD. clear LHB_OMO PERM_OMO.
generalize dependent stlist. induction omo using rev_ind; intros.
- inversion INTERP_OMO.
+ done.
+ apply (f_equal length) in H0. rewrite app_length /= in H0. lia.
- inversion INTERP_OMO.
+ done.
+ rewrite !app_length /=.
destruct H2 as [_ [H2 _]].
apply app_inj_2 in H0 as [-> _]; [|done].
specialize (IHomo _ H2). rewrite IHomo. done.
Qed.
Lemma lookup_omo_mono omo1 omo2 eidx e
(LOOKUP : lookup_omo omo1 eidx = Some e)
(PREFIX : omo_prefix omo1 omo2) :
lookup_omo omo2 eidx = Some e.
Proof.
destruct eidx.
- destruct PREFIX as [H1 H2].
destruct (omo_read_op omo1 !! gen) eqn:Heq1; destruct (omo_read_op omo2 !! gen) eqn:Heq2;
specialize (H1 gen) as H3; rewrite Heq1 Heq2 /= in H3; try done.
+ rewrite lookup_omo_ro_event Heq1 /= in LOOKUP.
rewrite lookup_omo_ro_event Heq2 /=.
by eapply prefix_lookup_Some.
+ rewrite lookup_omo_ro_event Heq1 /= in LOOKUP. done.
+ rewrite lookup_omo_ro_event Heq1 /= in LOOKUP. done.
- destruct PREFIX as [H1 H2].
rewrite lookup_omo_wr_event in LOOKUP. rewrite lookup_omo_wr_event.
by eapply prefix_lookup_Some.
Qed.
Lemma omo_prefix_refl omo :
omo_prefix omo omo.
Proof. done. Qed.
Lemma omo_prefix_trans omo1 omo2 omo3
(PREFIX1 : omo_prefix omo1 omo2)
(PREFIX2 : omo_prefix omo2 omo3) :
omo_prefix omo1 omo3.
Proof.
destruct PREFIX1 as [SubR1 SubW1].
destruct PREFIX2 as [SubR2 SubW2].
split.
- by transitivity (omo_read_op omo2).
- by transitivity (omo_write_op omo2).
Qed.
Global Instance omo_prefix_Reflexive : Reflexive omo_prefix := omo_prefix_refl.
Global Instance omo_prefix_Transitive : Transitive omo_prefix := omo_prefix_trans.
Lemma omo_write_op_take omo gen :
omo_write_op (take gen omo) = take gen (omo_write_op omo).
Proof. by rewrite /omo_write_op !fmap_take. Qed.
Lemma omo_write_op_drop omo gen :
omo_write_op (drop gen omo) = drop gen (omo_write_op omo).
Proof. by rewrite /omo_write_op !fmap_drop. Qed.
Lemma omo_read_op_take omo gen :
omo_read_op (take gen omo) = take gen (omo_read_op omo).
Proof. by rewrite /omo_read_op !fmap_take. Qed.
Lemma omo_read_op_drop omo gen :
omo_read_op (drop gen omo) = drop gen (omo_read_op omo).
Proof. by rewrite /omo_read_op !fmap_drop. Qed.
Lemma lookup_omo_take omo gen eidx
(LT : gen_of eidx < gen) :
lookup_omo (take gen omo) eidx = lookup_omo omo eidx.
Proof. by destruct eidx; simpl; rewrite fmap_take lookup_take. Qed.
Lemma lookup_omo_drop omo gen eidx :
lookup_omo (drop gen omo) eidx
= match eidx with
| wr_event gen' => lookup_omo omo (wr_event (gen + gen'))
| ro_event gen' idx => lookup_omo omo (ro_event (gen + gen') idx)
end.
Proof. by destruct eidx; simpl; rewrite fmap_drop lookup_drop. Qed.
Lemma omo_prefix_take omo gen :
omo_prefix (take gen omo) omo.
Proof.
split.
- rewrite /prefixes /map_included /map_relation. intros.
destruct (omo_read_op (take gen omo) !! i) eqn:Heq.
+ apply lookup_lt_Some in Heq as LT. rewrite -omo_read_op_length take_length in LT.
rewrite /omo_read_op fmap_take lookup_take in Heq; [|lia]. rewrite Heq /=. done.
+ simpl. by destruct (omo_read_op omo !! i).
- rewrite /omo_write_op fmap_take. apply prefix_take.
Qed.
Lemma lin_of_omo_empty :
lin_of_omo [] = [].
Proof. done. Qed.
Lemma length_concat_fmap_take_plus_S (f : _ → list event_id) gen1' omo x N
(GEN1 : omo !! gen1' = Some x) :
length (concat (f <$> take (gen1' + S N) omo))
= length (concat (f <$> take gen1' omo)) + (length (f x) + length (concat (f <$> take N (drop (S gen1') omo)))).
Proof.
apply lookup_lt_Some in GEN1 as LEgen1'.
rewrite -{1}(take_drop gen1' omo).
rewrite take_add_app; last first. { rewrite take_length. lia. }
rewrite fmap_app concat_app app_length.
rewrite (drop_S _ _ _ GEN1). rewrite firstn_cons fmap_cons /=.
rewrite app_length. done.
Qed.
Lemma eidx_to_lin_idx_inj omo eidx1 eidx2 e
(OMO_LOOKUP1 : lookup_omo omo eidx1 = Some e)
(OMO_LOOKUP2 : lookup_omo omo eidx2 = Some e)
(EQlin : eidx_to_lin_idx omo eidx1 = eidx_to_lin_idx omo eidx2) :
eidx1 = eidx2.
Proof.
unfold eidx_to_lin_idx in *.
set (f := λ '(e0, es), e0 :: es) in *.
destruct eidx1 as [gen1 i1|gen1], eidx2 as [gen2 i2|gen2].
- case (decide (gen1 = gen2)) as [->|NEgen].
{ have EQ : i1 = i2 by lia. subst i1. done. }
exfalso.
wlog: gen1 gen2 i1 i2 OMO_LOOKUP1 OMO_LOOKUP2 EQlin NEgen / gen1 < gen2.
{ destruct (le_lt_dec gen1 gen2) as [LE|LT].
- intros. apply (H gen1 gen2 i1 i2); try done. lia.
- intros. apply (H gen2 gen1 i2 i1); try done. }
intros LTgen.
have [N EQ] : ∃ N, gen2 = gen1 + (S N) by exists (gen2 - gen1 - 1); lia. subst gen2.
have {}EQlin : length (concat (f <$> take gen1 omo)) + i1 = length (concat (f <$> take (gen1 + S N) omo)) + i2 by lia.
destruct (omo !! gen1) eqn:Heq; last first.
{ rewrite lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP1. done. }
destruct p as [e1 es1].
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin.
assert (i1 = S (length es1 + length (concat (f <$> take N (drop (S gen1) omo)))) + i2) as ->; try lia.
rewrite lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP1.
apply lookup_lt_Some in OMO_LOOKUP1. lia.
- exfalso. destruct (le_lt_dec gen1 gen2) as [LE|LT].
+ have LT : gen1 < gen2 by destruct (decide (gen1 = gen2)) as [<-|NE]; lia.
destruct (omo !! gen1) eqn:Heq; [|by rewrite lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP1].
destruct p as [e1 es1].
have [N EQ] : ∃ N, gen2 = gen1 + (S N) by exists (gen2 - gen1 - 1); lia. subst gen2.
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin.
have EQ : i1 = length es1 + length (concat (f <$> take N (drop (S gen1) omo))) by lia.
rewrite EQ lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP1.
apply lookup_lt_Some in OMO_LOOKUP1. lia.
+ have [N EQ] : ∃ N, gen1 = gen2 + (S N) by exists (gen1 - gen2 - 1); lia. subst gen1.
destruct (omo !! gen2) eqn:Heq; last first.
{ rewrite lookup_omo_wr_event /omo_write_op list_lookup_fmap Heq /= in OMO_LOOKUP2. done. }
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin. lia.
- exfalso. destruct (le_lt_dec gen1 gen2) as [LE|LT].
+ have LT : gen1 < gen2 by destruct (decide (gen1 = gen2)) as [<-|NE]; lia.
have [N EQ] : ∃ N, gen2 = gen1 + (S N) by exists (gen2 - gen1 - 1); lia. subst gen2.
destruct (omo !! gen1) eqn:Heq; last first.
{ rewrite lookup_omo_wr_event /omo_write_op list_lookup_fmap Heq /= in OMO_LOOKUP1. done. }
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin. lia.
+ have [N EQ] : ∃ N, gen1 = gen2 + (S N) by exists (gen1 - gen2 - 1); lia. subst gen1.
destruct (omo !! gen2) eqn:Heq; last first.
{ rewrite lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP2. done. }
destruct p as [e2 es2].
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin.
have EQ : i2 = length es2 + length (concat (f <$> take N (drop (S gen2) omo))) by lia.
rewrite EQ lookup_omo_ro_event /omo_read_op list_lookup_fmap Heq /= in OMO_LOOKUP2.
apply lookup_lt_Some in OMO_LOOKUP2. lia.
- destruct (decide (gen1 = gen2)) as [->|NE]; [done|]. exfalso.
wlog: gen1 gen2 OMO_LOOKUP1 OMO_LOOKUP2 EQlin NE / gen1 < gen2.
{ destruct (le_lt_dec gen1 gen2) as [LE|LT].
- have LT : gen1 < gen2 by lia. intros. by apply (H gen1 gen2).
- intros. by apply (H gen2 gen1). }
intros LT.
have [N EQ] : ∃ N, gen2 = gen1 + (S N) by exists (gen2 - gen1 - 1); lia. subst gen2.
destruct (omo !! gen1) eqn:Heq; last first.
{ rewrite lookup_omo_wr_event /omo_write_op list_lookup_fmap Heq /= in OMO_LOOKUP1. done. }
destruct p as [e1 es1].
erewrite length_concat_fmap_take_plus_S in EQlin; [|done]. simpl in EQlin. lia.
Qed.
Lemma lin_of_omo_take_drop omo gen :
lin_of_omo omo = lin_of_omo (take gen omo) ++ lin_of_omo (drop gen omo).
Proof.
destruct (le_lt_dec (length omo) gen) as [Hgen|Hgen].
- rewrite take_ge; [|done].
rewrite drop_ge; [|done].
by rewrite lin_of_omo_empty app_nil_r.
- by rewrite /lin_of_omo -concat_app -fmap_app take_drop.
Qed.
Lemma omo_take_drop_lin_singleton omo gen e es
(LOOKUP : omo !! gen = Some (e, es)) :
lin_of_omo (drop gen (take (S gen) omo)) = e :: es.
Proof.
erewrite take_S_r; [|done].
have Hgen : gen = length (take gen omo).
{ rewrite take_length. apply lookup_lt_Some in LOOKUP. lia. }
by rewrite {1}Hgen drop_app /lin_of_omo /= app_nil_r.
Qed.
Lemma lin_of_omo_take_S_r omo gen e es
(LOOKUP : omo !! gen = Some (e, es)) :
lin_of_omo (take (S gen) omo) = lin_of_omo (take gen omo) ++ (e :: es).
Proof.
rewrite /lin_of_omo. erewrite take_S_r; [|done]. simplify_list_eq.
by rewrite concat_app /= app_nil_r.
Qed.
Lemma lin_of_omo_append_w omo e es :
lin_of_omo (omo_append_w omo e es) = lin_of_omo omo ++ e :: es.
Proof.
rewrite /lin_of_omo /omo_append_w. simplify_list_eq. by rewrite concat_app /= app_nil_r.
Qed.
Lemma lin_of_omo_insert_w omo gen e es :
lin_of_omo (omo_insert_w omo gen e es) = lin_of_omo (take gen omo) ++ e :: es ++ lin_of_omo (drop gen omo).
Proof.
rewrite /lin_of_omo /omo_insert_w /=.
list_simplifier.
rewrite concat_app /=.
list_simplifier.
done.
Qed.
Lemma lookup_omo_app omo omo' eidx e
(OMO_LOOKUP : lookup_omo omo eidx = Some e) :
lookup_omo (omo ++ omo') eidx = Some e.
Proof.
destruct eidx.
- rewrite lookup_omo_ro_event /omo_read_op fmap_app. rewrite lookup_omo_ro_event in OMO_LOOKUP.
destruct (omo_read_op omo !! gen) eqn:Heq; [|done].
rewrite lookup_app_l; [|by apply lookup_lt_Some in Heq].
rewrite Heq. done.
- rewrite lookup_omo_wr_event /omo_write_op fmap_app. rewrite lookup_omo_wr_event in OMO_LOOKUP.
destruct (omo_write_op omo !! gen) eqn:Heq; [|done].
rewrite lookup_app_l; [|by apply lookup_lt_Some in Heq].
rewrite Heq. done.
Qed.
Lemma eidx_to_lin_idx_omo_app omo eidx e e' es'
(OMO_LOOKUP : lookup_omo omo eidx = Some e) :
eidx_to_lin_idx omo eidx = eidx_to_lin_idx (omo_append_w omo e' es') eidx.
Proof.
unfold eidx_to_lin_idx. destruct eidx.
- rewrite /omo_append_w take_app_le; [done|].
rewrite lookup_omo_ro_event in OMO_LOOKUP. destruct (omo_read_op omo !! gen) eqn:Heq; [|done].
apply lookup_lt_Some in Heq. rewrite -omo_read_op_length in Heq. lia.
- rewrite /omo_append_w take_app_le; [done|].
rewrite lookup_omo_wr_event in OMO_LOOKUP. destruct (omo_write_op omo !! gen) eqn:Heq; [|done].
apply lookup_lt_Some in Heq. rewrite -omo_write_op_length in Heq. lia.
Qed.
Lemma lin_of_omo_lookup_lookup_omo omo i e
(NODUP : NoDup (lin_of_omo omo))
(LIN_I : lin_of_omo omo !! i = Some e) :
∃ eidx,
i = eidx_to_lin_idx omo eidx ∧
lookup_omo omo eidx = Some e.
Proof.
revert i e NODUP LIN_I.
induction omo using rev_ind; intros; [done|].
destruct x as [e' es'].
have H : omo_append_w omo e' es' = omo ++ [(e', es')] by done.
rewrite -H in NODUP, LIN_I.
rewrite ->lin_of_omo_append_w,NoDup_app in NODUP. des.
rewrite lin_of_omo_append_w in LIN_I.
set len := length (lin_of_omo omo).
have Hi : i < len ∨ i = len ∨ i > len by lia. des.
- (* use [i] in IH to get a [eidx] and use it *)
rewrite lookup_app_l in LIN_I; [|done].
specialize (IHomo _ _ NODUP LIN_I). des.
exists eidx. split.
+ erewrite eidx_to_lin_idx_omo_app in IHomo; last done.
rewrite -H. done.
+ by eapply lookup_omo_app in IHomo0.
- rewrite list_lookup_middle in LIN_I; [|done]. simplify_eq.
exists (wr_event (length omo)). list_simplifier. split.
+ subst len. done.
+ by rewrite -!(fmap_length fst) lookup_app_1_eq.
- rewrite ->lookup_app_r,lookup_cons in LIN_I; [|lia].
case Esub: (i - len) => [|i']; [lia|]. rewrite -/len Esub in LIN_I.
have {Esub}Hi : i = len + S i' by lia. subst.
subst len. unfold lin_of_omo in *. exists (ro_event (length omo) i'). split.
+ rewrite /eidx_to_lin_idx. rewrite take_app_le; [|lia]. rewrite take_ge; [|lia]. done.
+ rewrite -H lookup_omo_ro_event /omo_append_w /omo_read_op fmap_app.
replace (length omo) with (length omo.*2); [|by rewrite fmap_length].
rewrite lookup_app_1_eq. done.
Qed.
Lemma lookup_omo_lin_of_omo_lookup omo eidx e
(OMO_LOOKUP : lookup_omo omo eidx = Some e) :
lin_of_omo omo !! (eidx_to_lin_idx omo eidx) = Some e.
Proof.
unfold lin_of_omo, eidx_to_lin_idx.
set (f := λ '(e0, es), e0 :: es) in *.
destruct eidx as [gen' i'|gen']; simpl in *.
- rewrite -{2}(take_drop gen' omo) fmap_app concat_app.
rewrite lookup_app_r; [|lia].
replace (length (concat (f <$> take gen' omo)) + S i' - length (concat (f <$> take gen' omo))) with (S i') by lia.
destruct (omo !! gen') eqn:Heq; last first.
{ rewrite list_lookup_fmap Heq /= in OMO_LOOKUP. done. }
destruct p as [e' es'].
rewrite (drop_S _ (e', es')); [|done]. simpl. rewrite lookup_app_l.
+ by rewrite list_lookup_fmap Heq /= in OMO_LOOKUP.
+ rewrite list_lookup_fmap Heq /= in OMO_LOOKUP. by apply lookup_lt_Some in OMO_LOOKUP.
- rewrite -{2}(take_drop gen' omo) fmap_app concat_app.
rewrite lookup_app_r; [|lia].
replace (length (concat (f <$> take gen' omo)) - length (concat (f <$> take gen' omo))) with 0 by lia.
destruct (omo !! gen') eqn:Heq; last first.
{ rewrite list_lookup_fmap Heq /= in OMO_LOOKUP. done. }
destruct p as [e' es'].
rewrite (drop_S _ (e', es')); [|done]. simpl.
by rewrite list_lookup_fmap Heq /= in OMO_LOOKUP.
Qed.
Lemma event_in_omo (E : history) omo e
(LIN_PERM : lin_of_omo omo ≡ₚ seq 0 (length E))
(IS : is_Some (E !! e)) :
∃ eidx, lookup_omo omo eidx = Some e.
Proof.
have NODUP : NoDup (lin_of_omo omo) by by eapply ord_nodup.
move: IS => /lookup_lt_is_Some /lookup_xo => XO_LOOKUP.
apply Permutation_sym,Permutation_inj in LIN_PERM as [_ (f & _ & LIN_PERM)].
specialize (LIN_PERM e). rewrite LIN_PERM in XO_LOOKUP.
specialize (lin_of_omo_lookup_lookup_omo _ _ _ NODUP XO_LOOKUP). i. des.
by exists eidx.
Qed.
Lemma logview_in_omo (E : history) omo (M : eView)
(LIN_PERM : lin_of_omo omo ≡ₚ seq 0 (length E))
(SubME : set_in_bound M E) :
set_Forall (λ e, ∃ eidx, lookup_omo omo eidx = Some e) M.
Proof. intros ??. eapply event_in_omo; [done|]. by apply SubME. Qed.
Lemma longer_take i1 i2 (lss : list (list event_id)) (LE: i1 ≤ i2):
length (concat (take i1 lss))
≤ length (concat (take i2 lss)).
Proof.
apply prefix_length.
revert lss i2 LE. induction i1; intros; simpl.
{ apply prefix_nil. }
destruct i2; first lia. destruct lss; first done; simpl.
apply prefix_app, IHi1; lia.
Qed.
Lemma lin_idx_r_i'_mono omo gen i1' i2' (LEi' : i1' ≤ i2') :
eidx_to_lin_idx omo (ro_event gen i1') ≤ eidx_to_lin_idx omo (ro_event gen i2').
Proof.
unfold eidx_to_lin_idx.
destruct gen; lia.
Qed.
Lemma lin_idx_w_gen_mono omo gen1' gen2' (LEgen : gen1' ≤ gen2') :
eidx_to_lin_idx omo (wr_event gen1') ≤ eidx_to_lin_idx omo (wr_event gen2').
Proof.
simpl. do 2 rewrite fmap_take.
by apply longer_take.
Qed.
Lemma lin_idx_r_w_gen_mono omo gen1 i1' gen2
(OMO_LOOKUP1 : is_Some (lookup_omo omo (ro_event gen1 i1')))
(LTgen : gen1 < gen2) :
eidx_to_lin_idx omo (ro_event gen1 i1') < eidx_to_lin_idx omo (wr_event gen2).
Proof.
inversion OMO_LOOKUP1 as [e LOOKUP].
apply lookup_omo_inv_r in LOOKUP as [es [LOOKUP1 LOOKUP2]].
apply lookup_lt_Some in LOOKUP2; clear e.
eapply Nat.lt_le_trans; last first.
{ apply lin_idx_w_gen_mono. instantiate (1 := S gen1); lia. }
unfold eidx_to_lin_idx.
destruct (omo !! gen1) eqn:Heq; last first.
{ rewrite /omo_read_op list_lookup_fmap Heq /= in LOOKUP1. done. }
destruct p as [e1 es1]. rewrite (take_S_r _ _ (e1,es1)); [|done].
rewrite fmap_app concat_app app_length. rewrite app_length /=.
rewrite list_lookup_fmap Heq /= in LOOKUP1. inversion LOOKUP1. lia.
Qed.
Lemma lin_idx_w_r_gen_mono omo gen1 gen2 i2' (LEgen : gen1 ≤ gen2) :
eidx_to_lin_idx omo (wr_event gen1) < eidx_to_lin_idx omo (ro_event gen2 i2').
Proof.
unfold eidx_to_lin_idx. do 2 rewrite fmap_take. eapply Nat.le_lt_trans.
- apply longer_take. done.
- lia.
Qed.
Lemma lin_idx_r_gen_mono omo gen1 gen2 i1' i2'
(OMO_LOOKUP1 : is_Some (lookup_omo omo (ro_event gen1 i1')))
(LTgen : gen1 < gen2) :
eidx_to_lin_idx omo (ro_event gen1 i1') < eidx_to_lin_idx omo (ro_event gen2 i2').
Proof.
eapply Nat.lt_le_trans.
- by apply lin_idx_r_w_gen_mono.
- simpl; lia.
Qed.
Lemma omo_extract_eeVs E omo stlist es `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist)
(EIDS_VALID : Forall (λ e, e < length E) es) :
∃ eeVs,
eeVs.*1 = es ∧
eid_to_event_valid E eeVs.
Proof.
induction es.
- exists []. split; try done. unfold eid_to_event_valid. by rewrite Forall_nil.
- rewrite Forall_cons in EIDS_VALID. destruct EIDS_VALID as [H1 H2].
specialize (IHes H2) as [eeVs [EQ VALID]].
rewrite -lookup_lt_is_Some in H1. destruct H1 as [eV Ha].
exists ((a, eV) :: eeVs). split.
+ rewrite fmap_cons. rewrite EQ. done.
+ unfold eid_to_event_valid. rewrite Forall_cons. done.
Qed.
Lemma omo_write_op_to_eeVs E omo stlist `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist) :
∃ eeVs,
eeVs.*1 = omo_write_op omo ∧
eid_to_event_valid E eeVs.
Proof.
eapply omo_extract_eeVs; [done|].
rewrite Forall_lookup. intros. rewrite -lookup_lt_is_Some.
eapply lookup_omo_event_valid; [done|].
rewrite -lookup_omo_wr_event in H0. done.
Qed.
Lemma lin_of_omo_to_eeVs E omo stlist `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist) :
∃ eeVs,
eeVs.*1 = lin_of_omo omo ∧
eid_to_event_valid E eeVs.
Proof.
eapply omo_extract_eeVs; [done|].
rewrite Forall_lookup. intros. rewrite -lookup_lt_is_Some.
apply lin_of_omo_lookup_lookup_omo in H0 as [eidx [_ H']].
- by eapply lookup_omo_event_valid.
- destruct OMO_GOOD. by eapply ord_nodup.
Qed.
Lemma omo_xo_to_eeVs E omo stlist `{Interpretable eventT absStateT}
(OMO_GOOD : Linearizability_omo E omo stlist) :
∃ eeVs,
eeVs.*1 = seq 0 (length E) ∧
eid_to_event_valid E eeVs.
Proof.
eapply omo_extract_eeVs; [done|].
rewrite Forall_lookup. intros.
rewrite lookup_seq in H0. lia.
Qed.
Lemma eid_to_event_valid_agree_from_eid E eeVs eeVs'
(EEVS_VALID_1 : eid_to_event_valid E eeVs)
(EEVS_VALID_2 : eid_to_event_valid E eeVs')
(EID_MATCH : eeVs.*1 = eeVs'.*1) :
eeVs = eeVs'.
Proof.
generalize dependent eeVs'. induction eeVs; intros.
- by destruct eeVs'.
- destruct eeVs'; try done.
rewrite !fmap_cons in EID_MATCH. inversion EID_MATCH.
destruct a, p. simpl in H0. subst e0.
have [VALID VALID'] : eid_to_event_valid E eeVs ∧ eid_to_event_valid E eeVs'.
{ unfold eid_to_event_valid in *. rewrite !Forall_cons in EEVS_VALID_1, EEVS_VALID_2. by destruct EEVS_VALID_1, EEVS_VALID_2. }
rewrite /eid_to_event_valid !Forall_cons in EEVS_VALID_1, EEVS_VALID_2.
destruct EEVS_VALID_1 as [H2 _]. destruct EEVS_VALID_2 as [H3 _].
rewrite H2 in H3. inversion H3. subst o0.
specialize (IHeeVs VALID _ VALID' H1). subst eeVs'. done.
Qed.
Lemma eid_to_event_valid_mono_history E E' eeVs
(SubE : E ⊑ E')
(EEVS_VALID : eid_to_event_valid E eeVs) :
eid_to_event_valid E' eeVs.
Proof.
unfold eid_to_event_valid in *. rewrite Forall_lookup. intros. destruct x as [e eV].
rewrite Forall_lookup in EEVS_VALID. specialize (EEVS_VALID _ _ H). simpl in EEVS_VALID.
eapply prefix_lookup_Some; try done.
Qed.
Lemma eid_to_event_valid_mono_history_rev E E' eeVs
(SubE : E' ⊑ E)
(EEVS_VALID : eid_to_event_valid E eeVs)
(EID_VALID : Forall (λ e, is_Some (E' !! e)) eeVs.*1) :
eid_to_event_valid E' eeVs.
Proof.
unfold eid_to_event_valid in *. rewrite Forall_lookup. intros. destruct x as [e eV].
rewrite Forall_lookup in EID_VALID.
have LOOKUP : eeVs.*1 !! i = Some e by rewrite list_lookup_fmap H.
specialize (EID_VALID _ _ LOOKUP).
rewrite Forall_lookup in EEVS_VALID.
specialize (EEVS_VALID _ _ H). simpl in EEVS_VALID.
eapply prefix_lookup_inv; try done.
Qed.
Lemma eid_to_event_valid_mono_eeVs E eeVs eeVs'
(SubEEVS : eeVs ⊑ eeVs')
(EEVS_VALID : eid_to_event_valid E eeVs') :
eid_to_event_valid E eeVs.
Proof.
unfold eid_to_event_valid in *. rewrite Forall_lookup. intros. destruct x as [e eV].
apply (prefix_lookup_Some _ eeVs') in H; [|done].
rewrite Forall_lookup in EEVS_VALID. specialize (EEVS_VALID _ _ H). done.
Qed.
Lemma eid_to_event_valid_eeVs_app E eeVs eeVs'
(EEVS_VALID_1 : eid_to_event_valid E eeVs)
(EEVS_VALID_2 : eid_to_event_valid E eeVs') :
eid_to_event_valid E (eeVs ++ eeVs').
Proof. by unfold eid_to_event_valid in *; rewrite Forall_app. Qed.
Lemma eid_to_event_valid_perm E eeVs eeVs'
(PERM : eeVs ≡ₚ eeVs')
(EEVS_VALID : eid_to_event_valid E eeVs) :
eid_to_event_valid E eeVs'.
Proof.
unfold eid_to_event_valid in *. rewrite Forall_lookup. intros.
destruct x as [e eV]. symmetry in PERM.
apply elem_of_list_lookup_2 in H.
eapply Permutation_in in PERM; last first.
{ rewrite elem_of_list_In in H. done. }
rewrite -elem_of_list_In in PERM.
apply elem_of_list_lookup_1 in PERM as [i' LOOKUP].
rewrite Forall_lookup in EEVS_VALID. by specialize (EEVS_VALID _ _ LOOKUP).
Qed.
Lemma eid_to_event_valid_perm_from_eid E eeVs eeVs'
(EEVS_VALID_1 : eid_to_event_valid E eeVs)
(EEVS_VALID_2 : eid_to_event_valid E eeVs')
(PERM : eeVs.*1 ≡ₚ eeVs'.*1) :
eeVs ≡ₚ eeVs'.
Proof.
generalize dependent eeVs'. induction eeVs; intros.
- destruct eeVs'; try done. apply Permutation_length in PERM. simpl in PERM. lia.
- destruct a as [e eV]. rewrite fmap_cons in PERM.
apply (elem_of_Permutation_proper e) in PERM as ELEM.
have [eeVs'' PERM'] : ∃ eeVs'', eeVs' ≡ₚ (e, eV) :: eeVs''.
{ simpl in ELEM.
have ELEM' : e ∈ e :: eeVs.*1 by apply elem_of_list_here.
rewrite ELEM in ELEM'. apply elem_of_list_lookup_1 in ELEM' as [i Hi].
apply list_lookup_fmap_inv in Hi as [[e' eV'] [EQ Hi]]. simpl in EQ. subst e'.
have EQ : eV = eV'.
{ unfold eid_to_event_valid in *. rewrite !Forall_lookup in EEVS_VALID_1, EEVS_VALID_2.
have LOOKUP : ((e, eV) :: eeVs) !! 0 = Some (e, eV) by done.
specialize (EEVS_VALID_1 _ _ LOOKUP). specialize (EEVS_VALID_2 _ _ Hi). simpl in *.
rewrite EEVS_VALID_2 in EEVS_VALID_1. inversion EEVS_VALID_1. done. }
subst eV'. apply elem_of_list_lookup_2 in Hi. rewrite elem_of_Permutation in Hi. done. }
have PERM'' : eeVs'.*1 ≡ₚ ((e, eV) :: eeVs'').*1 by eapply fmap_Permutation. rewrite fmap_cons /= in PERM''.
have H1 : e :: eeVs.*1 ≡ₚ e :: eeVs''.*1 by eapply Permutation_trans.
apply cons_Permutation_inj_r in H1 as H2.
have EEVS_VALID_1' : eid_to_event_valid E eeVs.
{ unfold eid_to_event_valid in *. rewrite Forall_cons in EEVS_VALID_1. by destruct EEVS_VALID_1 as [_ ?]. }
have EEVS_VALID_2' : eid_to_event_valid E eeVs''.
{ unfold eid_to_event_valid in *. rewrite Forall_lookup. intros. destruct x as [e' eV'].
have IN : (e', eV') ∈ ((e, eV) :: eeVs'').
{ apply (elem_of_list_lookup_2 _ (S i)). simpl. done. }