build.gradle

plugins {
    id 'java'
    id 'eclipse'
    id 'maven-publish'
    id 'signing'
    id 'antlr'
}

repositories {
    mavenCentral()
}

dependencies {
    antlr 'org.antlr:antlr4:4.7.1'
    implementation 'org.antlr:antlr4-runtime:4.7.1'
    implementation 'org.postgresql:postgresql:42.2.5'
    testImplementation 'junit:junit:4.12'
    testImplementation 'org.testcontainers:postgresql:1.9.1'
    testImplementation 'org.testcontainers:mssqlserver:1.11.2'
    testImplementation 'com.microsoft.sqlserver:mssql-jdbc:7.3.0.jre11-preview'
    testCompile 'com.zaxxer:HikariCP:2.7.8'
    testCompile 'org.mybatis:mybatis:3.4.1'
    testRuntimeOnly "ch.qos.logback:logback-classic:1.3.0-alpha4"
}
jar {
    from ("LICENSE.md") {
        into "META-INF/"
    }
}
task sourceJar(type: Jar) {
    classifier "sources"
    from sourceSets.main.allJava
    from ("LICENSE.md") {
        into "META-INF/"
    }
}

test {
    if (project.hasProperty('maxParallelForks')) {
        maxParallelForks = project.maxParallelForks as int
    } else {
        maxParallelForks = 3
    }
    if (project.hasProperty('forkEvery'))
        forkEvery = project.forkEvery as int
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier "javadoc"
    from javadoc.destinationDir
}

artifacts {
    archives jar
    archives sourceJar
    archives javadocJar
}
generateGrammarSource {
    maxHeapSize = "64m"
    outputDirectory = file("${project.buildDir}/generated-src/antlr/main/mssqlpgbridge/parser");
    arguments += ['-package' , 'mssqlpgbridge.parser', '-no-listener', '-visitor']
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId 'io.github.kislaykishore'
            artifactId 'mssqlpgbridge'
            version '0.0.5'
        pom {
            name = 'MSSQL-PostgreSQL bridge driver'
            description = 'PostgreSQL driver which converts MSSQL compatible queries to PostgreSQL compatible'
            url = 'https://github.com/kislaykishore/mssqlpgbridge'
            licenses {
                license {
                    name = 'BSD-2-Clause'
                    url = 'https://jdbc.postgresql.org/about/license.html'
                }
                license {
                    name = 'The MIT License (MIT).'
                }
            }
            developers {
                developer {
                    id = 'kislaykishore'
                    name = 'Kislay Kishore'
                    email = 'kislay.kishore2003@gmail.com'
                }
            }
            scm {
                url = 'https://github.com/kislaykishore/mssqlpgbridge'
                connection = 'scm:git:git://github.com/kislaykishore/mssqlpgbridge.git'
                developerConnection = 'scm:git:ssh://git@github.com:kislaykishore/mssqlpgbridge.git'
            }
            }
            
            from components.java
            afterEvaluate {
	            pom.withXml {
	                def pomFile = file("${project.buildDir}/generated-pom.xml")
	                writeTo(pomFile)
	                def pomAscFile = signing.sign(pomFile).signatureFiles[0]
	                artifact(pomAscFile) {
	                    classifier = null
	                    extension = 'pom.asc'
	                }
	            }
	
	            artifact(sourceJar) {
	                classifier = 'sources'
	            }
	            artifact(javadocJar) {
	                classifier = 'javadoc'
	            }
	            
	            project.tasks.signArchives.signatureFiles.each {
	                artifact(it) {
	                    def matcher = it.file =~ /-(sources|javadoc)\.jar\.asc$/
	                    if (matcher.find()) {
	                        classifier = matcher.group(1)
	                    } else {
	                        classifier = null
	                    }
	                    extension = 'jar.asc'
	                }
	            }
            }
        }
    }
    repositories {
        maven {
            def releaseRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
            def snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots'
            url = project.hasProperty('release') ? releaseRepoUrl : snapshotsRepoUrl
            if (project.hasProperty('sonatypeUsername')) {
	            credentials {
	                username sonatypeUsername?:""
	                password sonatypePassword?:""
	            }
            }
        }
    }
}

signing {
    sign configurations.archives
}

model {
    tasks.generatePomFileForMavenJavaPublication {
        destination = file("$buildDir/generated-pom.xml")
    }
    tasks.publishMavenJavaPublicationToMavenLocal {
        dependsOn project.tasks.signArchives
    }
    tasks.publishMavenJavaPublicationToMavenRepository {
        dependsOn project.tasks.signArchives
    }
}