build.gradle

plugins {
    id 'java'
    id 'application'
}

group = 'com.github.krystianmuchla'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation 'org.xerial:sqlite-jdbc:3.46.1.3'
    implementation 'ch.qos.logback:logback-classic:1.5.15'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
    testImplementation 'org.assertj:assertj-core:3.27.2'
}

application {
    def localPath = projectDir.toPath().resolve('home-local')
    def databaseLocation = localPath.resolve('home.db').toString()
    def driveLocation = localPath.resolve('drive').toString()
    applicationDefaultJvmArgs = [
        '-Dhttp.port=8080',
        "-Ddatabase.url=jdbc:sqlite:$databaseLocation",
        "-Ddrive.location=$driveLocation"
    ]
    mainClass = 'com.github.krystianmuchla.home.App'
}

jar {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    manifest {
        attributes(
            'Main-Class': 'com.github.krystianmuchla.home.App'
        )
    }
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

test {
    useJUnitPlatform()
}