-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathseg.pl
231 lines (199 loc) · 5.5 KB
/
seg.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
:- module(
seg, [
seg/1,
segArgs/2,
segStart/2, segStartX/2, segStartY/2,
segEnd/2, segEndX/2, segEndY/2,
segStartEnd/3,
segEtiqs/2,
segThickness/2,
segStartEndThickness/4,
segLength/2,
segHV/5,
segTop/3,
segBottom/3,
segLeft/3,
segRight/3,
segHeight/2,
segWidth/2
]).
:- use_module(library(clpBNR)).
segArgs(seg(Start, End, Etiqs, Thickness), [Start, End, Etiqs, Thickness]).
segStart(Seg, Start) :-
segArgs(Seg, [Start | _]).
segStartX(Seg, X) :-
segStart(Seg, point(X, _)).
segStartY(Seg, Y) :-
segStart(Seg, point(_, Y)).
segEnd(Seg, End) :-
segArgs(Seg, [_, End | _]).
segEndX(Seg, X) :-
segEnd(Seg, point(X, _)).
segEndY(Seg, Y) :-
segEnd(Seg, point(_, Y)).
segStartEnd(Seg, Start, End) :-
segArgs(Seg, [Start, End | _]).
segEtiqs(Seg, Etiqs) :-
segArgs(Seg, [_, _, Etiqs | _]).
segThickness(Seg, Thickness) :-
segArgs(Seg, [_, _, _, Thickness]).
segStartEndThickness(Seg, Start, End, Thickness) :-
segArgs(Seg, [Start, End, _, Thickness | _]).
segInterpolate(Seg, Coeff, point(X, Y)) :-
segStart(Seg, point(StartX, StartY)),
segEnd(Seg, point(EndX, EndY)),
{
X == StartX * (1 - Coeff) + EndX * Coeff,
Y == StartY * (1 - Coeff) + EndY * Coeff
}.
segLength(Seg, L) :-
segVec(Seg, Vec),
vecLength(Vec, L).
segVec(Seg, vec(X, Y)) :-
segStart(Seg, point(StartX, StartY)),
segEnd(Seg, point(EndX, EndY)),
{
X == EndX - StartX,
Y == EndY - StartY
}.
vecLength(vec(X, Y), L) :-
{ L == sqrt(X ** 2 + Y ** 2) }.
vecNormalize(vec(X, Y), vec(XOut, YOut)) :-
vecLength(vec(X, Y), L),
{
XOut == X / L,
YOut == Y / L
},
vecLength(vec(XOut, YOut), 1).
vecRotate(vec(X, Y), Angle, vec(XOut, YOut)) :-
{
XOut == X * cos(Angle) - Y * sin(Angle),
YOut == X * sin(Angle) + Y * cos(Angle),
X == XOut * cos(-Angle) - YOut * sin(-Angle),
Y == XOut * sin(-Angle) + YOut * cos(-Angle)
}.
segNormal(Seg, Normal) :-
segVec(Seg, Vec),
vecNormalize(Vec, VecNorm),
vecRotate(VecNorm, -pi/2, Normal).
segCoeffOffset(Seg, Coeff, point(X, Y), point(XOut, YOut)) :-
segNormal(Seg, vec(XNorm, YNorm)),
segThickness(Seg, Thickness),
{
Coeff2 == (Coeff - 0.5) * Thickness,
XOut == X + XNorm * Coeff2,
YOut == Y + YNorm * Coeff2
}.
segHDirCoeff(left, 0).
segHDirCoeff(mid, 0.5).
segHDirCoeff(right, 1).
segVDirCoeff(top, 0).
segVDirCoeff(mid, 0.5).
segVDirCoeff(bottom, 1).
segHV(Dir, H, V, Seg, Point) :-
segHDirCoeff(H, HCoeff),
segVDirCoeff(V, VCoeff),
segHVCoeff(Dir, HCoeff, VCoeff, Seg, Point).
segHVCoeff(v, H, V, Seg, Point) :-
segInterpolate(Seg, V, VPoint),
segCoeffOffset(Seg, H, VPoint, Point).
segHVCoeff(h, H, V, Seg, Point) :-
segInterpolate(Seg, H, HPoint),
segCoeffOffset(Seg, 1-V, HPoint, Point).
segTop(v, Seg, Top) :-
segStartY(Seg, Top).
segBottom(v, Seg, Bottom) :-
segEndY(Seg, Bottom).
segLeft(v, Seg, Left) :-
segStartX(Seg, Left).
segRight(v, Seg, Right) :-
segEndX(Seg, Right).
segHeight(Seg, Height) :-
segStartY(Seg, Y1),
segEndY(Seg, Y2),
{ Height == abs(Y2 - Y1) }.
segWidth(Seg, Width) :-
segStartX(Seg, X1),
segEndX(Seg, X2),
{ Width == X2 - X1 }.
seg(Seg) :-
segArgs(Seg, [point(X1, Y1), point(X2, Y2), _, Thickness]),
[X1, Y1, X2, Y2, Thickness]::real,
{ (X1 =< X2) or (Y1 =< Y2) }.
:- begin_tests(seg).
seg1(Seg) :-
{ Thickness == sqrt(2) },
segArgs(Seg, [point(0, 0), point(5, 5), [], Thickness]).
test('segInterpolate_0') :-
seg1(Seg),
segInterpolate(Seg, 0, P),
segStart(Seg, P).
test('segInterpolate_0.5') :-
seg1(Seg),
segInterpolate(Seg, 0.5, point(X, Y)),
{
X == 2.5,
Y == 2.5
}.
test('segInterpolate_1') :-
seg1(Seg),
segInterpolate(Seg, 1, P),
segEnd(Seg, P).
test('segVec') :-
seg1(Seg),
segVec(Seg, vec(5, 5)).
test('vecLength') :-
seg1(Seg),
segVec(Seg, Vec),
vecLength(Vec, L),
{ L == sqrt(25 + 25) }.
test('vecNormalize') :-
seg1(Seg),
segVec(Seg, Vec),
vecNormalize(Vec, VecNorm),
vecLength(VecNorm, 1).
test_vecRotate_Gen(0, 5, 5).
test_vecRotate_Gen(pi/4, 0, sqrt(50)).
test_vecRotate_Gen(-pi/2, 5, -5).
test_vecRotate_Gen(R, _, _) :-
length(L, 100),
maplist(random, L),
maplist([X, Y]>>(Y is ((X * 2) - 1) * pi), L, Rs),
member(R, Rs).
test('vecRotate', [forall(test_vecRotate_Gen(R, X, Y))]) :-
seg1(Seg),
segVec(Seg, Vec),
vecRotate(Vec, R, vec(X, Y)).
test('segNormal') :-
seg1(Seg),
segNormal(Seg, vec(X, Y)),
{
L == 1 / sqrt(2),
X == L,
Y == -L
}.
test('segCoeffOffset') :-
seg1(Seg),
segCoeffOffset(Seg, 0, point(0, 0), point(-0.5, 0.5)).
test_segHV_Gen(h , left , bottom , -0.5 , 0.5).
test_segHV_Gen(h , left , mid , 0 , 0).
test_segHV_Gen(h , left , top , 0.5 , -0.5).
test_segHV_Gen(h , mid , bottom , 2 , 3).
test_segHV_Gen(h , mid , mid , 2.5 , 2.5).
test_segHV_Gen(h , mid , top , 3 , 2).
test_segHV_Gen(h , right , bottom , 4.5 , 5.5).
test_segHV_Gen(h , right , mid , 5 , 5).
test_segHV_Gen(h , right , top , 5.5 , 4.5).
test_segHV_Gen(v , left , bottom , 4.5 , 5.5).
test_segHV_Gen(v , left , mid , 2 , 3).
test_segHV_Gen(v , left , top , -0.5 , 0.5).
test_segHV_Gen(v , mid , bottom , 5 , 5).
test_segHV_Gen(v , mid , mid , 2.5 , 2.5).
test_segHV_Gen(v , mid , top , 0 , 0).
test_segHV_Gen(v , right , bottom , 5.5 , 4.5).
test_segHV_Gen(v , right , mid , 3 , 2).
test_segHV_Gen(v , right , top , 0.5 , -0.5).
test('segHV_v_left_top', [forall(test_segHV_Gen(Dir, H, V, X, Y))]) :-
seg1(Seg),
segHV(Dir, H, V, Seg, point(X, Y)).
:- end_tests(seg).