Fix Issue 15104 - Fiber context switch in finally blocks breaks EH

This is a backport of dlang#1397.

Author: dnadlinger

src/core/thread.d

@@ -113,6 +113,17 @@ private
     //
     extern (C) void  rt_moduleTlsCtor();
     extern (C) void  rt_moduleTlsDtor();
+
+    /**
+     * Hook for whatever EH implementation is used to save/restore some data
+     * per stack.
+     *
+     * Params:
+     *     newContext = The return value of the prior call to this function
+     *         where the stack was last swapped out, or null when a fiber stack
+     *         is switched in for the first time.
+     */
+    extern(C) void* _d_eh_swapContext(void* newContext) nothrow;
 }
 
 
@@ -1478,6 +1489,7 @@ private:
     }
     body
     {
+        m_curr.ehContext = _d_eh_swapContext(c.ehContext);
         c.within = m_curr;
         m_curr = c;
     }
@@ -1492,6 +1504,7 @@ private:
     {
         Context* c = m_curr;
         m_curr = c.within;
+        c.ehContext = _d_eh_swapContext(m_curr.ehContext);
         c.within = null;
     }
 
@@ -1511,6 +1524,12 @@ private:
     {
         void*           bstack,
                         tstack;
+
+        /// Slot for the EH implementation to keep some state for each stack
+        /// (will be necessary for exception chaining, etc.). Opaque as far as
+        /// we are concerned here.
+        void*           ehContext;
+
         Context*        within;
         Context*        next,
                         prev;
@@ -5326,6 +5345,43 @@ version (Win32) {
     }
 }
 
+// Test exception chaining when switching contexts in finally blocks.
+unittest
+{
+    static void throwAndYield(string msg) {
+      try {
+        throw new Exception(msg);
+      } finally {
+        Fiber.yield();
+      }
+    }
+
+    static void fiber(string name) {
+      try {
+        try {
+          throwAndYield(name ~ ".1");
+        } finally {
+          throwAndYield(name ~ ".2");
+        }
+      } catch (Exception e) {
+        assert(e.msg == name ~ ".1");
+        assert(e.next);
+        assert(e.next.msg == name ~ ".2");
+        assert(!e.next.next);
+      }
+    }
+
+    auto first = new Fiber(() => fiber("first"));
+    auto second = new Fiber(() => fiber("second"));
+    first.call();
+    second.call();
+    first.call();
+    second.call();
+    first.call();
+    second.call();
+    assert(first.state == Fiber.State.TERM);
+    assert(second.state == Fiber.State.TERM);
+}
 
 // Test Fiber resetting
 unittest

src/ldc/eh/common.d

@@ -327,6 +327,15 @@ struct ActiveCleanupBlock {
 /// currently done.
 ActiveCleanupBlock* innermostCleanupBlock = null;
 
+/// innermostCleanupBlock is per-stack, not per-thread, and as such needs to be
+/// swapped out on fiber context switches.
+extern(C) void* _d_eh_swapContext(void* newContext) nothrow
+{
+    auto old = innermostCleanupBlock;
+    innermostCleanupBlock = cast(ActiveCleanupBlock*)newContext;
+    return old;
+}
+
 /// During the search phase of unwinding, points to the currently active cleanup
 /// block (i.e. somewhere in the innermostCleanupBlock linked list, but possibly
 /// not at the beginning if the search for the catch block has already continued

src/rt/deh_win32.d

@@ -372,11 +372,22 @@ enum int STATUS_DIGITAL_MARS_D_EXCEPTION = MAKE_EXCEPTION_CODE!(3,'D',1);
  * are shorter than D exceptions, for example.
  * (3) System exceptions don't have any space for a pointer to a D object.
  * So we cannot store the collision information in the exception record.
- * (4) it's important that this list is thread-local.
+ * (4) it's important that this list is fiber-local.
  */
 
 EXCEPTION_RECORD * inflightExceptionList = null;
 
+/***********************************
+ * Switch out inflightExceptionList on fiber context switches.
+ */
+extern(C) void* _d_eh_swapContext(void* newContext) nothrow
+{
+    auto old = inflightExceptionList;
+    inflightExceptionList = cast(EXCEPTION_RECORD*)newContext;
+    return old;
+}
+
+
 /***********************************
  * Find the first non-collateral exception in the list. If the last
  * entry in the list has the EXCEPTION_COLLATERAL bit set, it means

src/rt/deh_win64_posix.d

@@ -90,6 +90,15 @@ private
     }
 
     InFlight* __inflight = null;
+
+    /// __inflight is per-stack, not per-thread, and as such needs to be
+    /// swapped out on fiber context switches.
+    extern(C) void* _d_eh_swapContext(void* newContext) nothrow
+    {
+        auto old = __inflight;
+        __inflight = cast(InFlight*)newContext;
+        return old;
+    }
 }
 
 void terminate()