build.gradle

plugins {
  id 'java'
  id 'org.springframework.boot' version '3.4.1'
  id 'io.spring.dependency-management' version '1.1.7'
  id 'checkstyle'
}

group = 'dev.maizy'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
  compileOnly {
    extendsFrom annotationProcessor
  }
}

repositories {
  mavenCentral()
}

ext {
  set('testcontainersVersion', '1.19.4')
  set('immutablesVersion', '2.10.1')
  set('dockerImageVersion', '0.0.1-preview3')
}

dependencies {
  implementation 'org.springframework.boot:spring-boot-starter-web'
  implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
  implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
  implementation 'org.springframework.boot:spring-boot-starter-security'
  implementation 'org.springframework.session:spring-session-data-redis'
  implementation 'org.springframework.boot:spring-boot-starter-data-redis'
  implementation 'org.springframework.boot:spring-boot-starter-websocket'
  implementation 'org.springframework.boot:spring-boot-starter-actuator'

  implementation 'org.webjars:bootstrap:5.3.3'
  implementation 'org.webjars.npm:bootstrap-icons:1.11.3'

  annotationProcessor "org.springframework.boot:spring-boot-configuration-processor"

  annotationProcessor "org.immutables:value:${immutablesVersion}"
  compileOnly "org.immutables:value:${immutablesVersion}"
  testCompileOnly "org.immutables:value:${immutablesVersion}"

  implementation 'org.liquibase:liquibase-core'
  implementation 'org.postgresql:postgresql'
  implementation 'io.hypersistence:hypersistence-utils-hibernate-63:3.9.0'
  implementation 'dev.maizy:gibberish:1.0.0'

  runtimeOnly 'io.micrometer:micrometer-registry-prometheus'

  developmentOnly 'org.springframework.boot:spring-boot-devtools'
  testImplementation 'org.springframework.boot:spring-boot-starter-webflux'
  testImplementation 'org.springframework.boot:spring-boot-starter-test'
  testImplementation 'org.testcontainers:junit-jupiter'
  testImplementation 'org.testcontainers:postgresql'
  testImplementation 'com.redis.testcontainers:testcontainers-redis-junit-jupiter:1.4.6'
  testImplementation 'org.jsoup:jsoup:1.18.3'
}

dependencyManagement {
  imports {
    mavenBom "org.testcontainers:testcontainers-bom:${testcontainersVersion}"
  }
}

bootRun {
    systemProperty 'spring.config.additional-location', "$projectDir/dev/config/"
    systemProperty 'spring.profiles.active', 'default,dev'
}

tasks.named('bootBuildImage') {
	imageName = "ghcr.io/maizy/${project.name}:$dockerImageVersion"
  environment['BP_JVM_TYPE'] = 'JDK'
  buildpacks = [
      'gcr.io/paketo-buildpacks/ca-certificates:latest',
      'gcr.io/paketo-buildpacks/amazon-corretto:latest',
      'gcr.io/paketo-buildpacks/syft:latest',
      'gcr.io/paketo-buildpacks/executable-jar:latest',
      'gcr.io/paketo-buildpacks/dist-zip:latest',
      'gcr.io/paketo-buildpacks/spring-boot:latest',
  ]
}

tasks.named('test') {
  useJUnitPlatform()
}

tasks.withType(Checkstyle).configureEach {
  reports {
    xml.required = false
    html.required = false
  }
}